Помилки формули SUMPRODUCT

1

Я хочу, щоб комірка автоматично відображала текст (T1, T2, T3, T4) на основі того, чи є вхід в іншій комірці в таблиці.

=IF(SUMPRODUCT(--(C3=standards!I3:I16))>0,"T1")

відображатиметься лише для однієї категорії, але я не можу отримати формулу для прийому декількох масивів І конкретних входів, коли значення знаходиться в цій категорії.

=IF(SUMPRODUCT(--(C3=standards!I3:I16))>0,"T1")*(--(C3=standards!J3:j16))>0,"T2")

і т. д. Що я роблю неправильно?

microsoft-excel

— Zipperher
джерело

Ваша друга формула буде успішно працювати, коли ви протестуєте C3 у чотирьох різних діапазонах даних. Підтвердьте це, то я покажу вам, які зміни потрібні.

— Раджеш S

1

Використовуйте AGGREGATE, він здійснюватиме пошук у діапазоні та повертає число на основі стовпця, у якому знайдено значення, для функції CHOOSE ():

=CHOOSE(AGGREGATE(15,6,(COLUMN($I$2:$L$16)-COLUMN($I$2)+1)/($I$2:$L$16=C3),1),"T1","T2","T3","T4")

— Скотт Кренер
джерело

0

Ви можете використовувати цю формулу:

=IF(SUMPRODUCT(--(B253=A254:A257))>0,"T1",IF(SUMPRODUCT(--(B253=B254:B257))>0,"T2",IF(SUMPRODUCT(--(B253=C254:C257))>0,"T3",IF(SUMPRODUCT(--(B253=D254:D257))>0,"T4"))))

Примітки:

За необхідності відрегулюйте діапазон даних та посилання на клітинку.
Для будь-якого значення комірки з критеріями від 0 до 15 формула повертає T1 до T4 залежно від стовпця, в якому знаходиться значення.
Якщо значення в комірці критеріїв більше 15, AGGREGATE() формула поверне #Num!помилку, але ця формула дасть FALSE.

— Раджеш S
джерело

Що ви не знайшли в рішенні, щоб його проголосувати ,,, просто напишіть своє занепокоєння, інакше я задам модератору !!

— Раджеш S

Не бачте, що не так у вашій відповіді - оновлено

— Ultrasonic54321

Дякую @ Ultrasonic54321 ,, це спонукало мене до кращого та кращого :-)

— Раджеш S

0

Ця SUMPRODUCT()формула дає номер стовпця (таблиці ваших даних), у якому знаходиться значення C3:

=SUMPRODUCT(1*(C3=standards!I3:L16)*COLUMN(A:D))

і ви можете використовувати це у CHOOSE()формулі, як у відповіді Скотта, або INDEX()якщо ваші тексти довгі або, можливо, потрібно буде змінити.

=CHOOSE(SUMPRODUCT(1*(C3=standards!I3:L16)*COLUMN(A:D)),"T1","T2","T3","T4")

=INDEX(Text_Table,SUMPRODUCT(1*(C3=standards!I3:L16)*COLUMN(A:D)))

Зауважте, що SUMPRODUCT()формула дасть неправильну відповідь, якщо у вашій таблиці даних є кілька випадків значення C3. Існують способи цього, тому будь ласка, коментуйте, чи може бути кілька значень.

Інші відповіді ідентифікують перше виникнення, але вони дадуть правильний текст для стовпця, в якому він знаходиться.

— Bandersnatch
джерело