Імпортуйте .reg файл у профіль користувача за замовчуванням через командний рядок

Моя мета - імпортувати конкретні параметри програми реєстру (наприклад, CCleaner) в профіль користувача за замовчуванням активної системи, щоб переконатися, що нові користувачі отримають заздалегідь задану конфігурацію. Я не хочу створювати нове інсталяційне зображення або використовувати будь-яке комерційне програмне забезпечення сторонніх розробників.

Ось як імпортувати .reg файл до профілю іншого користувача:

runas /u:User "cmd.exe /k reg import C:\Test.reg"

Я адаптував це до:

runas /u:DefaultAccount "cmd.exe /k reg import C:\Test.reg"

Помилка:

1327: Помилка входу в систему: обмеження облікового запису користувача. Можливі причини: пусті паролі заборонені, обмеження на годину входу чи обмеження політики.

Тому я змінив таке значення реєстру на:

[HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Lsa]
"LimitBlankPasswordUse"=dword:00000000

Але все ж є така ж помилка, хоча вона працює з будь-яким іншим Користувачем!

Тож як імпортувати .reg файл у профіль користувача за замовчуванням через командний рядок?

Спочатку потрібно встановити профіль користувача DEFAULT:

reg load HKLM\DEFAULT c:\users\default\ntuser.dat

Тоді ви можете імпортувати або додати свої налаштування до новоствореної гілки HKLM \ DEFAULT: (Це дійсно важливо, щоб ваш шлях reg addне мав проділу \)

REM Advertising ID disabled
reg add "HKLM\DEFAULT\Software\Microsoft\Windows\CurrentVersion\AdvertisingInfo" /v Enabled /t REG_DWORD /d 0 /f

У вашому випадку ви також можете імпортувати .reg файл - але вам потрібно переконатися, що ви редагуєте .reg так, щоб шляхи були правильними для точки монтування:

regedit /s \\test.local\dfs\public\Deployment\Scripts\SetDefaults\Fix_An_app_default_was_reset_HKDU.reg

Коли ви закінчите, демонтуйте вулик реєстру DEFAULT:

reg unload HKLM\DEFAULT

Ось приклад повного сценарію, який я використовую для налаштування новообразованих комп'ютерів Windows 10, тепер, коли параметр "CopyProfile" unattend.xml більше не працює надійно. Я поєдную це з іншими сценаріями, а також з пакетом надання послуг для Windows 10.

@ECHO OFF
REM This script configured the DEFAULT user profile for all new users on the system

reg load HKLM\DEFAULT c:\users\default\ntuser.dat

REM Advertising ID disabled
reg add "HKLM\DEFAULT\Software\Microsoft\Windows\CurrentVersion\AdvertisingInfo" /v Enabled /t REG_DWORD /d 0 /f

REM Enable SmartScreen
reg add "HKLM\DEFAULT\Software\Microsoft\Windows\CurrentVersion\AppHost" /v EnableWebContentEvaluation /t REG_DWORD /d 1 /f

REM Delivery optimization, disabled
reg add "HKLM\DEFAULT\Software\Microsoft\Windows\CurrentVersion\DeliveryOptimization" /v SystemSettingsDownloadMode /t REG_DWORD /d 3 /f

REM Do not hide system tray icons
reg add "HKLM\DEFAULT\Software\Microsoft\Windows\CurrentVersion\Explorer" /v EnableAutoTray /t REG_DWORD /d 0 /f

REM Show known file extensions
reg add "HKLM\DEFAULT\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v HideFileExt /t REG_DWORD /d 0 /f

REM Remove search bar and only show
reg add "HKLM\DEFAULT\SOFTWARE\Microsoft\Windows\CurrentVersion\Search" /v SearchboxTaskbarMode /t REG_DWORD /d 1 /f

REM Disable Game DVR
reg add "HKLM\DEFAULT\System\GameConfigStore" /v GameDVR_Enabled /t REG_DWORD /d 0 /f
reg add "HKLM\DEFAULT\SOFTWARE\Microsoft\Windows\CurrentVersion\GameDVR" /v AppCaptureEnabled /t REG_DWORD /d 0 /f

REM Set Desktop Background
mkdir %SystemRoot%\Web\Wallpaper\TEST
xcopy \\test.local\dfs\public\deployment\Customizations\TEST_Background_HiRes.png %SystemRoot%\Web\Wallpaper\TEST /Q /Y
xcopy \\test.local\dfs\public\deployment\Customizations\test.theme %SystemRoot%\Resources\Themes /Q /Y
REM reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Themes" /v InstallTheme /t REG_SZ /d "C:\Windows\resources\Themes\test.theme" /f
reg add "HKLM\DEFAULT\SOFTWARE\Policies\Microsoft\Windows\Personalization" /v ThemeFile /t REG_SZ /d "C:\Windows\resources\Themes\test.theme" /f

REM Set Start Menu folders
REM reg add "HKLM\DEFAULT\Software\Microsoft\Windows\CurrentVersion\CloudStore\Store\Cache\DefaultAccount\$$windows.data.unifiedtile.startglobalproperties\Current" /v Data /t REG_BINARY /d 02000000bf6447b3e68ad3010000000043420100cb320a07058691cc930524aaa30144c38401669ff79db187cbd1acd4010005bcc9a8a401248cac034489850166a081bacbbdd7a8a482010005ceabd3e90224daf40344c38a016682e58bb1aefdfdbb3c0005afe69e9b0e24de930244d5860166bf9d879bbf8fc6d4370005a08cac800b24d1fe0144b2980166aabdd0e1cceadfb9150005a08ffcc103248ad0034480990166b0b599dccdb097de4d0005c5cbce95042486fb0144f485016680c9ced4afd99ec4b50100c23c0100 /f

REM Fix App Default Reset Warning
regedit /s \\test.local\dfs\public\Deployment\Scripts\SetDefaults\Fix_An_app_default_was_reset_HKDU.reg

REM Disable suggesting apps in start
reg add "HKLM\DEFAULT\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v SystemPaneSuggestionsEnabled /t REG_DWORD /d 0 /f

REM Disable VMWare Tools tray icon
reg add "HKLM\DEFAULT\SOFTWARE\VMWare, Inc.\VMWare Tools" /v ShowTray /t REG_DWORD /d 0 /f

REM Set Google as default search provider in IE
reg add "HKLM\DEFAULT\SOFTWARE\Microsoft\Internet Explorer\SearchScopes" /v DefaultScope /t REG_SZ /d {e913ede7-630e-4d2a-a6af-2b28e7ce735b} /f
reg add "HKLM\DEFAULT\SOFTWARE\Microsoft\Internet Explorer\SearchScopes\{e913ede7-630e-4d2a-a6af-2b28e7ce735b}" /v DisplayName /t REG_SZ /d Google /f
reg add "HKLM\DEFAULT\SOFTWARE\Microsoft\Internet Explorer\SearchScopes\{e913ede7-630e-4d2a-a6af-2b28e7ce735b}" /v FaviconURL /t REG_SZ /d https://www.google.com/favicon.ico /f
reg add "HKLM\DEFAULT\SOFTWARE\Microsoft\Internet Explorer\SearchScopes\{e913ede7-630e-4d2a-a6af-2b28e7ce735b}" /v ShowSearchSuggestions /t REG_DWORD /d 1 /f
reg add "HKLM\DEFAULT\SOFTWARE\Microsoft\Internet Explorer\SearchScopes\{e913ede7-630e-4d2a-a6af-2b28e7ce735b}" /v SuggestionsURL /t REG_SZ /d "https://www.google.com/complete/search?q={searchTerms}&client=ie8&mw={ie:maxWidth}&sh={ie:sectionHeight}&rh={ie:rowHeight}&inputencoding={inputEncoding}&outputencoding={outputEncoding}" /f
reg add "HKLM\DEFAULT\SOFTWARE\Microsoft\Internet Explorer\SearchScopes\{e913ede7-630e-4d2a-a6af-2b28e7ce735b}" /v URL /t REG_SZ /d "https://www.google.com/search?q={searchTerms}&sourceid=ie7&rls=com.microsoft:{language}:{referrer:source}&ie={inputEncoding?}&oe={outputEncoding?}" /f

REM Finished
reg unload HKLM\DEFAULT