Вимкнути автоматичне оновлення для всіх типів вмісту (ToC) у звичайному шаблоні (Word 2010+)

Іноді мені хочеться "почати з нуля", замінивши будь-який поточний файл Word Normal на нову копію, а потім налаштувати його з моїми кращими параметрами.

Файл Normal має всі стилі вмісту (ToC) стилів, встановлених на автоматичне оновлення.

Як найкраще я можу сказати, єдиним способом вимкнути цю установку є один за одним, а це передбачає кілька кроків (клацніть стиль, натисніть кнопку Змінити, включіть автоматичне оновлення, натисніть кнопку ОК, повторіть).

Чи є простий спосіб зробити зміну всіх стилів ToC одночасно; наприклад, автоматичні оновлення:

• Вимкнути для всіх стилів ToC одночасно? або
• Бути збереженим і повторно використаним таким чином, щоб не пошкодити мету "почати чистий"? (Імпортування з файлу dotm, dotx або dot все буде перевищувати ціль, але, можливо, щось зберігається в бібліотеці чи іншому файлі?)

Навколишнє середовище: декілька ПК з різними версіями MS Office на кожному.

Примітка. Параметр автоматичного оновлення для стилів ToC має довгу історію. Здається, що "завжди було так".

Параметр Автоматичне оновлення - це стандартний параметр для всіх стилів рівнів TOC. Хтось у вашій організації не зробив цього, саме так Microsoft встановив їх у звичайному шаблоні Word.

Неможливо одночасно змінити налаштування на всіх цих стилях. Хоча ви можете скористатися функцією Органайзер, доступною на вкладці "Розробник" кнопки "Шаблон документа", щоб замінити групи стилів, які вже були змінені в документі. Процес для цього буде:

1. Створіть документ і в ньому змініть дев'ять стилів змісту
2. Візьміть цей документ до кожної машини і відкрийте її
3. Використовуйте функцію Органайзер Word, щоб скопіювати дев'ять змінених стилів змісту до шаблону Normal цього комп'ютера.

Інший метод, який можна використовувати, - це макрос, який можна запустити на кожному комп'ютері. Нижче наведено макрос, який можна використовувати.

Sub UpdateTemplateStyles()
Dim sty As word.Style
Dim odocStyles As word.Styles
Dim oTemplate As word.Document

On Error GoTo errHandler
Set oTemplate = ActiveDocument.attachedTemplate.OpenAsDocument
Set odocStyles = oTemplate.Styles
For Each sty In odocStyles
    Select Case sty.Type
        Case wdStyleTypeParagraph
            Select Case sty.NameLocal
                Case "TOC 1", "TOC 2", "TOC 3", "TOC 4", _
                    "TOC 5", "TOC 6", "TOC 7", "TOC 8", "TOC 9"
                    sty.AutomaticallyUpdate = False
            End Select
    End Select
Next sty
oTemplate.SaveAs2 FileName:=oTemplate.FullName, AddToRecentFiles:=False
DoEvents
oTemplate.Close
Exit Sub

errHandler:
MsgBox Err.Description, vbExclamation, "UpdateTemplateStyles"
End Sub