Як перевірити, чи знаходиться поточний пакетний файл у певній папці?

Привіт, я доволі новачок для створення пакетних файлів, так що вибачте, якщо це питання здається дурним, але мені дуже потрібна допомога.

Тому мені потрібен мій пакетний скрипт, щоб перевірити, чи знаходиться він у вказаній папці, скажімо, %userprofile%\Desktopнаприклад. Я не хочу, щоб він піклувався про власне ім'я файлу. Я абсолютно не маю ідеї з чого почати. Я знаю, як отримати поточний шлях / ім'я файлу тощо, але це майже все, що я знаю. Як змусити програму порівнювати її поточний шлях з тим, який я хочу побачити, чи він знаходиться? Або є ще один більш ефективний метод?

Я хочу досягти такого:

if this file is in Desktop folder(
    echo It's here
)else(
    echo It's not here
)

Будь-яка допомога вдячна, дякую всім

Не потрібно вибачатися, оскільки поставлене вами питання складніше, ніж ви, напевно, очікуєте.

Рішення

Ось як ви можете перевірити, чи ваш пакетний файл знаходиться в певній папці, у вашому випадку в папці Настільний:

@echo off

:: Normalize this batch script's path
set BATCH_PATH=%~dp0
set BATCH_PATH=%BATCH_PATH:~0,-1%

:: Test for equality
if "%BATCH_PATH%"=="%USERPROFILE%\Desktop" (
    echo This file is on Desktop.
) else (
    echo This file is not on Desktop.
)

Що потрібно відзначити

• Альтернативний спосіб нормалізації шляху (і мій улюблений):

  pushd "%~dp0"
  set BATCH_PATH=%CD%
  popd
  

  • у будь-якому випадку, ви, ймовірно, хочете видалити будь-який трейлінг \, що є однією з речей, які нормалізація робить для вас

• використовуйте %~dp0змінну замість %cd%, тому що остання семантика - це папка, над якою працюють ваші сценарії, а перша - папка, у якій знаходиться ваш скрипт (про що ви і попросили)

  • %0 надає вам місце розташування сценарію
  • додавши dp(тобто %dp0) ви запитуєте диск і шлях, який опускає ім'я файлу та розширення (що щось подібне, example.batі це буде тягарем на наступному кроці - перевірка рівності)
  • додавши, ~ви "вимагаєте видалити будь-яке відкриття або закриття, якщо це необхідно (тобто пробіг, що містить пробіл)

• шляхи загортаються "для запобігання помилок через можливий пробіл у рядку шляху

Не так просто, як можна було б подумати, правда?

Мінімальний робочий приклад з використанням %cd%:

IF %cd%==%userprofile%\Desktop (
    ECHO It's here
) ELSE (
    ECHO It's not here
)

Використання проміжної змінної:

FOR /F "tokens=*" %%a in ('cd') do SET CURRENT_DIR=%%a
IF %CURRENT_DIR%==%userprofile%\Desktop (
    ECHO It's here
) ELSE (
    ECHO It's not here
)

Оскільки ви сказали, що не маєте ідеї з чого почати, ось хороший матеріал для читання: https://en.wikibooks.org/wiki/Windows_Batch_Scripting