Поєднайте повторювані рядки та перейдіть до інших комірок до нового стовпця в Excel

У мене є стіл відвідування, який виглядає приблизно так,

  Name | Date      | Time        |
  abc  | 12/3/2018 | 12:36:11 PM |
  abc  | 12/3/2018 | 08:30:11 PM |
  EFG  | 13/3/2018 | 09:35:11 PM |
  EFG  | 13/3/2018 | 06:23:11 PM |
  EFG  | 13/3/2018 |  9:36:11 PM |
  abc  | 14/3/2018 | 11:36:11 PM |
  GHT  | 14/3/2018 |  3:36:11 PM |
  GHT  | 14/3/2018 | 01:36:11 PM |
  abc  | 15/3/2018 | 10:36:11 PM |

Я намагаюся зробити щось подібне: отримати ім’я та дату (якщо обидва дублікати), а якщо ім’я та дата однакові, потрібно перенести різний час до нової комірки.

  Name | Date      | Time        | new cell    | new cell    |
  abc  | 12/3/2018 | 12:36:11 PM | 08:30:11 PM |
  EFG  | 13/3/2018 | 09:35:11 PM | 06:23:11 PM |  9:36:11 PM |
  abc  | 14/3/2018 | 11:36:11 PM |
  GHT  | 14/3/2018 |  3:36:11 PM | 01:36:11 PM |
  abc  | 15/3/2018 | 10:36:11 PM |

Поки я намагався об'єднати два ряди в робочий аркуш excel, де одна клітина має однаковий вміст, але інші клітини мають різний вміст, мають різний вміст, і це єдине рішення, до якого я наблизився.

а також спробував експортувати його в Access і написати запит SQL, щоб отримати вищезазначений результат. Як я можу цього досягти?

— максасела
джерело

Я думаю, що це робота для VBa, але ви спеціально помітили функцію робочого аркуша

— Дейв

Чи існує максимально можлива кількість записів для імені + дати? Чи завжди вони послідовні?

— fixer1234

Запит на владу буде кращим вибором.

— Лі

D2=IF(A3=A2,C3,"") E2=IF(AND(A4=A2,D2<>""),C4,"") F2=IF(AND(A5=A2,E2<>""),C5,"")і так далі ...

— Акіна

@ fixer1234 Як правило, це має бути 2 випадки, Бур колись працівник може випадково покласти пальцем два-три рази. Але якщо це станеться, ми можемо порахувати лише 2 випадки і знехтувати більше записами.

— maxasela

Це не складно зробити з формулами робочого аркуша. Я вважаю , що існуючий «Ім'я», «Дата» і «Time» Стовпці A, Bі C. І я припускаю, що ви хочете спроектувати дані на новий аркуш; тобто у вас є дані у вашій першій ілюстрації на Sheet1, і ви хочете макет другої ілюстрації на Sheet2. Проектування його в інший регіон на тому ж аркуші збігається за винятком деталей формул. У будь-якому випадку, якщо ви хочете замінити вихідні дані, ви можете скопіювати та вставити значення.

Виберіть три стовпці на Sheet1, які ви не використовуєте; скажімо X, Yі Z.

Переконайтеся, що клітинка X1порожня (або введіть 0туди).
У комірці X2введіть =IF(AND(A1=A2,B1=B2),X1,X1+1).
У комірці Y2введіть =MATCH(ROW()-1,X:X,0).
У комірці Z2введіть =COUNTIF(X:X,ROW()-1).
Виберіть X2:Z2та перетягніть / заповніть (принаймні), наскільки у вас є дані.

На Листі2,

Введіть заголовки стовпців за бажанням у рядок 1.
У комірці A2введіть =IFERROR(INDEX(Sheet1!A:A,Sheet1!Y2),"").
У комірці B2введіть =IFERROR(INDEX(Sheet1!B:B,Sheet1!Y2),"").
У комірці C2введіть =IF((COLUMN()-COLUMN($C:$C))<Sheet1!$Z2, INDEX(Sheet1!$C:$C,Sheet1!$Y2+(COLUMN()-COLUMN($C:$C))),"").
Виберіть C2та перетягніть / заповніть праворуч (принаймні) достатньо далеко, щоб охопити ваші дані (тобто максимальну кількість повторюваних рядків для будь-якої пари Ім'я / Дата).
Виберіть заповнені клітинки в рядку 2 (тобто A2через клітинку, яку ви перетягнули на попередньому етапі) та перетягніть / заповніть (принаймні) достатньо далеко, щоб покрити ваші дані (тобто кількість унікальних пар Ім'я / Дата, які ви маєте) .

Voilà

Лист1:

Лист2:

— Скотт
джерело