Отримати назву поточної папки за допомогою команди DOS?

Чи можливо отримати ім'я поточної папки (не поточний шлях до каталогу) за допомогою команди DOS? Якщо так, то як?

Найближче мені це було, але це не робить:

for /f "delims=\" %%a in ("%CD%") do set CURR=%%a
echo.DIR: %CURR%

зауважте: вищевказана спроба була спробою токенізувати рядок і отримати останній жетон, встановлений як змінну CURR.

Найкоротшим способом я знайшов:

for %I in (.) do echo %~nxI

або в сценарії .bat:

for %%I in (.) do echo %%~nxI

або в .bat із значенням Get в змінній.

for %%I in (.) do set CurrDirName=%%~nxI
echo %CurrDirName%

Пояснення: http://www.robvanderwoude.com/ntfor.php

nx означає лише ім'я файлу та розширення

Якщо ви хочете знати поточне розташування пакетного файлу (і якщо ваша Windows не дуже давня версія), введіть for /?у вікні "DOS box" вікно. Прокрути вниз. Прочитайте.

Ви дізнаєтеся, що тепер ви можете читати (з в пакетному файлі) цих змінних:

%0      - as the name how this batchfile was called
%~d0    - as the drive letter where this batchfile is located ('\\' in case of share)
%~p0    - as path (without the drive letter) where this batchfile is located
%~n0    - as filename (without suffix) of this batchfile
%~x0    - as filename's suffix (without filename) of this batchfile
%~a0    - as this batchfile's file attributes
%~t0    - as this batchfile's date+time
%~z0    - as this batchfile's filesize
%~dpnx0 - as this batchfile's fully qualified path+filename
[... and then some more ...]

Це працює в багатьох випадках. Припустимо, пакетний файл називається mytest.bat. Ви можете називати це різними способами:

1. ..\..\to\mytest.bat ............................... (відносний шлях)
2. d:\path\to\mytest.bat........................... (повний шлях)
3. \\fileserver\sharename\mytest.bat... (шлях на віддалену частку)

... і ви завжди отримаєте правильне значення у своїх змінних.

Мені особисто подобалася відповідь Томса, поки вона не боролася з крапками в іменах реж. Це дало мені підказку:

for /f "delims=\" %%a in ("%cd%") do echo topmost dir: %%~nxa

Відповідь Тома хороша, але якщо у вас є ім'я каталогу з періодом у ньому (тобто wxwidgets-2.9.4), ви отримаєте лише повне ім’я. Таким чином, це виведе wxwidgets-2.9 ​​замість цього, тому що .4 трактується як розширення (Так, навіть якщо це ім'я каталогу!).

Щоб отримати повне ім'я виводу, потрібно додати до розширення до кінця:

FOR %I IN (.) DO Echo %~nI%~xI

і в пакетному режимі файлів:

FOR %%I IN (.) DO Echo %%~nI%%~xI

Або звичайно, замість цього встановіть змінну в пакетному файлі:

FOR %%I IN (.) DO SET CurrentD=%%~nI%%~xI

Інший спосіб:

set "MyPath=%~dpnx0" & call set "MyPath=%%MyPath:\%~nx0=%%" 
echo MyPath=%MyPath%  

він працює з "." і пробіли в імені шляху

Що це робить?

1. помістіть ціле ім'я файлу (driveletter-path-filename-extension) у MyPathVar

2. видалити ім'я файлу та розширення з MyPathvar

Він також працює з UNC Paths. Якщо вам потрібен зворотний проміжок в кінці Шляху. Видаліть команду \after MyPathу другому наборі, наприклад.

set "MyPath=%%MyPath:%~nx0=%%"

Ви можете отримати поточний dir в змінну. Одноколісний:

set a=%cd%

Перевірте

echo %a%

просто простий

for %%d in ("%CD%") do echo %%~nxd

або

set "sPath=."
for %%d in ("%sPath%") do set "sDirName=%%~nxd"

Будьте уважні до нахилу в кінці шляху, він не повинен бути зворотним нахилом кінця шляху.

Моя відповідь у цій темі робить це в 3 простих рядки:

@echo off
SET "CDIR=%~dp0"
:: for loop requires removing trailing backslash from %~dp0 output
SET "CDIR=%CDIR:~0,-1%"
FOR %%i IN ("%CDIR%") DO SET "PARENTFOLDERNAME=%%~nxi"
ECHO Parent folder: %PARENTFOLDERNAME%
ECHO Full path: %~dp0
pause>nul

Це працює для мене з пакетного файлу. Він повертає поточну назву робочого каталогу.

pushd %1 & for %%i in (.) do @echo %%~ni