Як я можу контролювати гучність системи на OS X за допомогою клавіатури без засобів управління медіа?

Я використовую клавіатуру ПК на Mac OS. Я можу використовувати меню для управління гучністю, але чи є комбінації клавіш, які я можу використовувати, щоб змінити гучність системи?

Або, можливо, простий скрипт чи рішення, яке я можу встановити, щоб можна було встановити гучність за допомогою клавіатури.

Ви можете придбати про-версію Sizzling Keys . Це preference paneте, що дозволяє визначати користувацьку комбінацію клавіш для зміни обсягу системи, серед багатьох інших речей.

Крім того, ви можете змінити об'єм системи за допомогою AppleScript.

Відкрийте редактор AppleScript і введіть

set volume output volume 100

Гучність знаходиться в масштабі від 0 до 100. Ви можете або встановити абсолютне значення (наприклад, 100 для повного обсягу), або створити сценарії, які збільшуються / зменшуються, наприклад, такі:

set vol to output volume of (get volume settings)
if vol > 90 then # 100 max
    set volume output volume 100
else
    set volume output volume (vol + 10)
end if

Для зменшення гучності:

set vol to output volume of (get volume settings)
if vol < 10 then # 0 is min
    set volume output volume 0
else
    set volume output volume (vol - 10)
end if

Якщо ви хочете повторити звук зворотного зв’язку, який зазвичай виникає при зміні гучності, ви можете додати до сценарію таке:

    do shell script "afplay /System/Library/Sounds/Pop.aiff"

Ви можете зберігати такі сценарії як додатки або інтегрувати їх у меню Сервіси, використовуючи Автоматизатор як послугу без вводу. Ви можете визначити комбінації клавіш для служб у налаштуваннях системи »Клавіатура» Комбінації клавіш »Послуги

Karabiner (раніше KeyRemap4MacBook) може перезавантажувати функціональні клавіші для управління гучністю, і до цього часу для мене працює безперебійно. На панелі управління знайдіть "F9 для відключення звуку" тощо.

Я упакував набір служб і інструкцій AppleScript, які дозволяють керувати гучністю системи та iTunes, а також відтворювати / призупиняти & наступний / попередній на будь-якій клавіатурі Lion.

http://gskinner.com/blog/archives/2011/10/media-keys-in-osx-for-any-keyboard.html

Стара тема, але те, як я її вирішив, здійснюється через яблучний рядок на одному рядку, заснований на інших відповідях

Збільшити обсяг на 10%

osascript -e 'set volume output volume ((output volume of (get volume settings)) + 10)'

Зменшити обсяг на 10%

osascript -e 'set volume output volume ((output volume of (get volume settings)) - 10)'

Насправді я написав публікацію в блозі про її використання за допомогою програми Альфред: http://arif.im/system-volume-control-using-alfred/

Клавіші F1 до F12 на клавіатурі ПК повинні робити те саме. Я припускаю, що у вас не було проблем із заміною клавіші "Windows" на ⌘ . Якщо клавіші від F1 до F12 не працюють, перейдіть до системних уподобань, клавіатури та миші, клавіатури та зробіть звідти вибір, чи використовувати клавіші F безпосередньо, чи за допомогою клавіші fn. З повагою Павло

Ось моє повне рішення для ярликів для збільшення, зменшення та відключення гучності. Я використовую програму Spark для прив'язки комбінацій клавіш до цих скриптів ( http://www.macupdate.com/app/mac/14352/spark ). Сценарії перевіряють поточний стан відключення звуку та обробляють його, щоб уникнути дивних проблем, які можуть виникнути, якщо ви належним чином не контролюєте його.

Обсяг:

set vol to output muted of (get volume settings)
if (vol = true) then
    set volume without output muted
end if
set vol to output volume of (get volume settings)
if vol > 95 then
    set volume output volume 100
else
    set volume output volume (vol + 5)
end if

do shell script "afplay /System/Library/Sounds/Pop.aiff"

Зменшення гучності:

set vol to output muted of (get volume settings)
if (vol = true) then
    error number -128
else
    set vol to output volume of (get volume settings)
    if vol < 5 then # 0 is min
        set volume with output muted
    else
        set volume output volume (vol - 5)
    end if

    do shell script "afplay /System/Library/Sounds/Pop.aiff"

end if

Вимкнути звук / Увімкнути звук:

set vol to output muted of (get volume settings)
if (vol = true) then
    set volume without output muted
else
    set volume with output muted
end if