Як витягти частину рядка в пакетному файлі Windows?

Припустимо, у мене є таке значення, як "Abc_123", яке зберігається у змінній у пакетному (cmd) файлі. Я хочу закінчити змінною, яка містить лише "123". Чи є якийсь вбудований спосіб зробити це?

Я не дуже вибагливий щодо методу чи продуктивності, якщо він вбудований у типову систему Windows (Vista / 2008).

Використовуйте синтаксис підрядків:

C:\Users\John>set string=Abc_123

C:\Users\John>echo %string%
Abc_123

C:\Users\John>echo %string:~4,3%
123

Якщо ви просто хочете, щоб усе було після підкреслення (і не обов'язково знати довжину рядка або місце підкреслення, але ви можете розраховувати на те, що буде лише один підкреслення), спробуйте:

for /f "tokens=2 delims=_" %%a in ("%STRING%") do (
  set AFTER_UNDERSCORE=%%a
)

В основному, ваш рядок буде розділений на лексеми, використовуючи підкреслення як роздільник (delims = _). Лише другий (лексеми = 2) буде переданий (як змінна %% a) до циклу for. Цикл запускається лише один раз, оскільки в цьому випадку ви маєте справу з одним рядком.

Якщо ви хочете зберегти матеріал як до, так і після підкреслення, спробуйте:

for /f "tokens=1,2 delims=_" %%a in ("%STRING%") do (
  set BEFORE_UNDERSCORE=%%a
  set AFTER_UNDERSCORE=%%b
)

Зауважимо, що %% a - змінна для першого маркера розбиття; %% b - змінна для другого маркера розбиття.

Якщо ви виявите, що пакетна мова недостатньо потужна, щоб робити те, що вам завгодно - і, ймовірно, не знадобиться занадто багато часу, щоб дійти до цього пункту - ви можете використовувати Windows PowerShell . Це не встановлено за замовчуванням у всіх версіях Windows, але ви можете завантажити його безкоштовно.

Якщо вам не подобається мова PowerShell, є Perl. Це вам доведеться встановити на всіх системах. Є й інші.

set var1=Abc_123
set var2=%var1:*_=%
echo %var2%