Створіть символічне посилання в Mac OS X Finder

Чи є такий спосіб отримати такий же функціонал, що і команда unix ln -sв Mac OS X Finder (OS 10.5)? Я хочу мати можливість створювати символічні посилання під час роботи у вікнах Finder, не відкриваючи Термінал.

Зауважте, що Make Aliasкоманда в Finder - це не те, що я хочу, тому що цими псевдонімами не можна переміщатися в Терміналі (але по створених посиланнях ln -sможна переходити і терміналом, і Finder).

Як щодо створення символічних посилань у Finder через AppleScript ?

Ось найбільш релевантний сценарій за цим посиланням:

on run
    open {choose file with prompt "Choose a file to create a symbolic link:" without invisibles}
end run

on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files)
            if posix_path ends with "/" then set posix_path to text 1 thru -2 of posix_path
            do shell script "ln -s " & quoted form of posix_path & " " & quoted form of (posix_path & ".sym")
        end try
    end repeat
end open

Просто вставте його в редактор AppleScript і збережіть його як додаток . Потім ви можете перетягнути його на панель інструментів пошуку або зв’язати його на доці .

SymbolicLinker зробить саме те, що ви шукаєте, і це безкоштовно.

Яблукопис за посиланням, наданим користувачем nuc, відповів на моє запитання. Ось відтворений яблучний сценарій у випадку, якщо посилання зникне.

Я віддав перевагу сценарію, наданому коментатором jonn8n, який також був відтворений як стаття Macworld .

on run
    open {choose file with prompt ¬
        "Choose a file to create a symbolic link:" without invisibles}
end run
on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files)
            if posix_path ends with "/" then set posix_path to ¬
                text 1 thru -2 of posix_path
            do shell script "ln -s " & quoted form of posix_path ¬
                & " " & quoted form of (posix_path & ".sym")
        end try
    end repeat
end open

Я зберег це як додаток за допомогою редактора сценаріїв і перетягнув програму на бічну панель Finder, щоб тепер я міг створювати символічні посилання, перетягуючи файли або папки на піктограму програми.

Шлях Finder додає це до вашого Finder і додає набагато більше функцій.

Використовуйте Automator.app для створення сервісу, який виконує скрипт bash. Це простіше, ніж AppleScript, і надійніше, ніж установка стороннього програмного забезпечення.

for f in "$@"
do
    ln -s "$f" "$f.symlink"
done

Потім ви можете отримати доступ до команди Make Symbolic Link у меню Сервіси :

Результат:

Можливим вдосконаленням цього сценарію буде зміна обробника запуску для використання поточно вибраних файлів із Finder:

on run
    tell application "Finder" to set sel to selection
    open sel
end run
on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files as alias)
            if posix_path ends with "/" then set posix_path to ¬
                text 1 thru -2 of posix_path
            try
                do shell script "ln -s " & quoted form of posix_path ¬
                    & " " & quoted form of (posix_path & ".sym")
            on error
                try
                    do shell script "ln -s " & quoted form of posix_path ¬
                        & " " & quoted form of (posix_path & ".sym") with administrator privileges

                end try
            end try
        end try
    end repeat
end open

Ви також можете редагувати [додаток] /Contents/Info.plist, щоб додати

<key>LSUIElement</key>
<true/>

Незадовго до останнього </dict>. Це означає, що додаток запускається у фоновому режимі, і не виходить на передню частину, коли ви натискаєте на нього.

Крім того, у Snow Leopard, де SymbolicLinker не працює, ви можете створити Сервіс з Automator, щоб виконати або команду Terminal, або AppleScript для створення символічного посилання.

Ще один AS:

tell application "Finder"
    repeat with f in (get selection)
        set p to POSIX path of (f as text)
        set p2 to POSIX path of (desktop as text) & name of f
        do shell script "ln -s " & quoted form of p & " " & quoted form of p2
    end repeat
end tell

Спробуйте подивитися тут: http://www.techiecorner.com/528/how-to-create-shortcut-in-mac-os-x/

Це вбудовано в OSX вже в тому випадку, якщо ви натискаєте клавішу управління при натисканні на щось.