Вибачте, недостатня відповідь для коментарів. (Адміністратори, сміливо виріжте це на коментар вище.) Відповідь користувача "danicotra", починаючи з "Я також використовую VBA / макрос на основі події Worksheet_Change, але мій підхід ..." із
"спочатку видалити фільтр
", потім застосувати його знову
правильне рішення при використанні Excel 2007+. Однак .AutoFilter.ApplyFilter недійсний у XL03 і раніше, тому я показую спосіб нижче.
Я прошу, щоб справжні експерти та гуру читали код, бо я впевнений, що це матеріал верхньої полиці. Можливо, незрозуміле число голосів на цю відповідь можна змінити, коли люди побачать, що добре робиться нижче.
danicotra використав спрощений приклад. Насправді ви можете це зробити більш загально. Припустимо з ActiveSheet для наступного (або якогось іншого об'єкта аркуша):
Збережіть діапазон автофільтра. У ньому є стовпці .AutoFilter.Filters.Count та (.AutoFilter.Range.Count / .AutoFilter.Filters.Count) рядки, збережені в rngAutofilter
Зберіть в масиві myAutofilters кожне з 4 властивостей кожного з елементів .AutoFilter.Filters.Count автофільтра, обережно, щоб уникнути "помилок, визначених додатком", коли .On або .Operator помилковий. (myAutofilters буде переведено на кількість рядків і стовпців на кроці 1)
Вимкніть фільтр, але збережіть спадні файли за допомогою .ShowAllData
Для кожного елемента фільтра, який був .За збереженим масивом, скиньте 3 з 4 властивостей кожного з елементів .AutoFilter.Filters.Count автофільтра. Знову подбайте про те, щоб уникнути "помилок, визначених додатком", коли .Operator помилковий, тому для кожного елемента "i",
rngAutofilter.AutoFilter Field: = i, Criteria1: = myAutofilters (i, 2)
або
rngAutofilter.AutoFilter Field: = i, Критерії1: = myAutofilters (i, 2), Оператор: = myAutofilters (i, 3), Критерії2: = myAutofilters (i, 4)
Тепер автофільтр буде відновлено в тому ж діапазоні, що був до початку вашого коду, але оновлення автофільтра оновлено для зміни даних.
Public myAutofilters As Variant, rngAutofilter As Range 'Public
Sub SaveAndRestoreAutofilters()
'This will update the autofilter display to recognize data changes by turning autofilter off and then on, preserving all characteristics
'Note, XL2007 and later have .autofilter.applyfilter, but not the invaluable XL03 and earlier
Dim i As Long, iNumAutofilters As Long, iNumActiveAutofilters As Long
iNumActiveAutofilters = SaveAutoFilterInfo(iNumAutofilters) 'NOTE! Use CALL or assignment to prevent parentheses from forcing ByVal !
If iNumActiveAutofilters < 1 Then
Application.StatusBar = "0 ACTIVE filters;" & iNumAutofilters & " autofilters"
Exit Sub
End If
ActiveSheet.ShowAllData
Rem Here optionally do stuff which can include changing data or toggling autofilter columns
For i = 1 To iNumAutofilters
If myAutofilters(i, 1) Then
If myAutofilters(i, 3) <> 0 Then 'then .Operator is something, so set it and Criteria2, else just Criteria1
rngAutofilter.AutoFilter Field:=i, Criteria1:=myAutofilters(i, 2), Operator:=myAutofilters(i, 3), Criteria2:=myAutofilters(i, 4) ', On:=true by rule
Else
rngAutofilter.AutoFilter Field:=i, Criteria1:=myAutofilters(i, 2) ', On:=true by rule (it's R/O anyway)
End If
Rem Selection.AutoFilter Field:=i 'How you'd "turn off" only a single column's autofiltering. FYI .On is R/O!
End If
'activesheet.autofiltermode=false 'just FYI, how you comprehensively turn off filtering on a sheet (erasing the dropdowns and criteria and filter range!)
Next i
End Sub
Function SaveAutoFilterInfo(iNumAutofilters As Long) As Long
Dim i As Long, iRowsAutofiltered As Long
SaveAutoFilterInfo = 0 'counts the number that are .On, and returns the total
iNumAutofilters = ActiveSheet.AutoFilter.Range.Columns.Count
If ActiveSheet.AutoFilter.Filters.Count <> iNumAutofilters Then MsgBox "I can't explain this. All bets are off. Aborting.": Exit function
ReDim myAutofilters(1 To iNumAutofilters, 4)
For i = 1 To iNumAutofilters
myAutofilters(i, 1) = ActiveSheet.AutoFilter.Filters(i).On
If myAutofilters(i, 1) Then
SaveAutoFilterInfo = SaveAutoFilterInfo + 1
myAutofilters(i, 2) = ActiveSheet.AutoFilter.Filters(i).Criteria1
myAutofilters(i, 3) = ActiveSheet.AutoFilter.Filters(i).Operator
If myAutofilters(i, 3) <> 0 Then 'then is either xlAnd, xlOr, etc., and there's a second criteria
myAutofilters(i, 4) = ActiveSheet.AutoFilter.Filters(i).Criteria2
End If
End If
Next i
iRowsAutofiltered = ActiveSheet.AutoFilter.Range.Count / ActiveSheet.AutoFilter.Range.Columns.Count
Set rngAutofilter = Cells(ActiveSheet.AutoFilter.Range.Row, ActiveSheet.AutoFilter.Range.Column).Resize(iRowsAutofiltered, iNumAutofilters)
End Function