Як зробити так, щоб нагадування календаря Outlook залишалися на вершині в Windows 7

Я тільки починаю використовувати Windows 7 і хочу знати, як зробити так, щоб мої нагадування Outlook спливали і показували себе на чільному місці. Вони відкриваються непомітно, як лише чергове вікно в стеку Outlook на панелі завдань. Як результат, я продовжую їх не помічати, оскільки вони спливають позаду всього іншого.

Як зробити їх менш легкими для перегляду?

(Зрозуміло, що зазвичай не хочеться неприємних програм, які висувають себе на перший план. Але є кілька місць, де така поведінка бажана, і нагадування календаря Outlook - одне з них.)

У мене була така ж проблема з Outlook 2010. Використовуйте вказані нижче дії, це працює як шарм. Не забудьте включити всі макроси: Центр довіри> Налаштування макросів.

• Створіть цифровий сертифікат на пізніше: натисніть "Пуск" та введіть "сертифікат", виберіть "Цифровий сертифікат для проектів VBA"
• Введіть назву вашого сертифіката. Натисніть кнопку ОК. Відкрийте Outlook і натисніть Alt+, F11щоб запустити редактор VBA.
• У дереві зліва розгорніть «Об’єкти Microsoft Office Outlook» та двічі клацніть на «ThisOutlookSession»

• Вставте цей код:

  Private Declare PtrSafe Function FindWindowA Lib "user32" _
  (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
  
  Private Declare PtrSafe Function SetWindowPos Lib "user32" ( _
  ByVal hwnd As Long, ByVal hWndInsertAfter As Long, _
  ByVal X As Long, ByVal Y As Long, ByVal cx As Long, _
  ByVal cy As Long, ByVal wFlags As Long) As Long
  
  Private Const SWP_NOSIZE = &H1
  Private Const SWP_NOMOVE = &H2
  Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
  Private Const HWND_TOPMOST = -1
  
  Private Sub Application_Reminder(ByVal Item As Object)
  Dim ReminderWindowHWnd As Variant
  On Error Resume Next
  ReminderWindowHWnd = FindWindowA(vbNullString, "1 Reminder")
  SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
  
  End Sub
  

• Підпишіть макрос, щоб він запустився: Інструменти> Цифровий підпис ... та виберіть створений раніше сертифікат

• Закрийте вікно VBA
• Увімкніть усі макроси у файлі> Параметри> Центр довіри> Налаштування центру довіри> Налаштування макросу

AutoHotKey також може бути використаний для вирішення цього питання. Цей сценарій буде ставити вікно нагадування зверху без крадіжок фокусу (тестовано з Win10 / Outlook 2013)

TrayTip Script, Looking for Reminder window to put on top, , 16
SetTitleMatchMode  2 ; windows contains
loop {
  WinWait, Reminder(s), 
  WinSet, AlwaysOnTop, on, Reminder(s)
  WinRestore, Reminder(s)
  TrayTip Outlook Reminder, You have an outlook reminder open, , 16
  WinWaitClose, Reminder(s), ,30
}

Сценарій AHK - укладений EXE

Найкраща відповідь, яку я знайшов, тут: Як отримати нагадування про зустріч Outlook, щоб знову з’являтися перед іншими вікнами, використовуючи просту VBA.

Це тягне за собою додавання декількох рядків простого коду VBA до "ThisOutlookSession". Тепер воно щоразу вискакує вікно. Значно краще.

• Створіть цифровий сертифікат на потім
• Натисніть "Пуск" та введіть "сертифікат", виберіть "Цифровий сертифікат для проектів VBA"
• Введіть назву для вашого сертифіката
• Зроблено
• Відкрийте Outlook і натисніть Alt + F11, щоб запустити редактор VBA.
• У дереві зліва розгорніть «Об’єкти Microsoft Office Outlook» та двічі клацніть на «ThisOutlookSession»

• Вставте цей код, модифікуючи текст у лапках відповідно до ваших уподобань. Залиште цитати в.

  Private Sub Application_Reminder(ByVal Item As Object)
  
  
      If TypeOf Item Is AppointmentItem Then
      MsgBox "Message text", vbSystemModal, "Message title"
      End If
  
  
  End Sub
  

• Підпишіть макрос, щоб він запустився, перейшовши до Інструменти> Цифровий підпис… та обравши створений раніше сертифікат

• Закрийте вікно VBA

Станом на версію 1803 (лютий 2018 року) тепер доступна опція "Показати нагадування поверх інших вікон". Здається, це за умовчанням не ввімкнено.

Немає способу. Наша компанія намагалася передати це безпосередньо в Microsoft. Одне, що люди роблять тут, - це присвоїти йому більш неприємний звук, щоб допомогти його помітити. Але Microsoft сказала нам, що це задумано.

Те саме, що передня частина Гуллу вище, але зі зміною, щоб вмістити різні назви вікна:

Private Declare PtrSafe Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long

Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
Private Const HWND_TOPMOST = -1

'// TO ACCOUNT FOR WINDOW TITLE CHANGING WITH NOTIFICATION COUNT:
Private Sub Application_Reminder(ByVal Item As Object)
    Dim ReminderWindowHWnd As Variant
    'On Error Resume Next
    On Error GoTo err
    'Loop 25 times as FindWindowA needs exact title which varies according to number of reminder items...
    Dim iReminderCount As Integer
    For iReminderCount = 1 To 25
        'Try two syntaxes...
        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Reminder"): SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Reminder(s)"): SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
    Next
Exit Sub
err:
    Debug.Print err.Number & " - " & err.Description & " (iReminderCount = " & iReminderCount & ")"
    Resume Next
End Sub

Це мене також клопіло. Після інтенсивного пошуку я знайшов часткову відповідь: http://www.pcreview.co.uk/forums/hidden-outlook-reminders-t3972914.html

Якщо змінити налаштування "Кнопки панелі завдань" у "Властивості панелі завдань і меню" Пуск "на" Ніколи не поєднувати ", то групування відокремлює, а нагадування спливає перед тим, що ви ще відкрили.

Я спробував перевірити це і виявив, що він суперечить; один раз він залишався прихованим за тим, над чим я працював, а в інший раз вискакував спереду. В обох випадках на панелі завдань була піктограма, яка виглядала інакше, ніж сама Outlook, тому, принаймні, був шанс, що я це помітять.

Я використовував Filebox eXtender, і коли з’являється перше нагадування, я відкриваю його та натискаю на нову пінцетну піктограму праворуч у верхній частині панелі підписів. Потім, коли з'являється наступне нагадування, воно виходить на перший план ...

Я знайшов доповнення під назвою ShowReminders ( http://www.sagelamp.com/pages/showreminders.aspx ), яке підводить вікно нагадувань до вершини. Він працює навіть тоді, коли ви мінімізуєте вікно нагадування.

Нарешті я знаходжу просте рішення за допомогою Outlook VBA та простого EXE.

Ось, як ніколи не пропустити зустріч із перспективою.

Чому автономна програма EXE саме для цієї мети? Я мав велике червоне поле вбудоване у VBA, але це рішення було повним проблемою (я вважаю, це тому, що мені потрібно використовувати hwnd та іншу незвичну властивість системи, щоб тримати велике червоне поле зверху). Отже, щоб зробити речі простішими, чому б не базовий EXE, який зробить одне. Ви можете використовувати безкоштовні інструменти від мікрософт (Visual studio Community 2015 безкоштовно).

Це EXE-код. простий віконний додаток з однією формою. Складіть цей код.

Imports System.Timers
Public Class Form1
    Dim tTimer As New Timer
    Public Sub New()
        InitializeComponent()
        Me.StartPosition = Windows.Forms.FormStartPosition.CenterScreen
        Me.TopMost = True
        Me.TopLevel = True
    End Sub
    Private Sub Form1_DoubleClick(sender As Object, e As EventArgs) Handles Me.DoubleClick
        Application.Exit()
    End Sub 
    Private Sub Form1_Shown(sender As Object, e As EventArgs) Handles Me.Shown
        flashingQuick()
    End Sub
    Sub flashingQuick()
        tTimer.Start()
        AddHandler tTimer.Elapsed, New ElapsedEventHandler(AddressOf TimerTick)
    End Sub
    Sub TimerTick(ByVal source As [Object], ByVal e As ElapsedEventArgs)
        Dim theTimer As System.Timers.Timer = DirectCast(source, System.Timers.Timer)
        theTimer.Interval = 500
        theTimer.Enabled = True
        If Me.BackColor = System.Drawing.SystemColors.Control Then
            Me.BackColor = Color.Red
        Else
            Me.BackColor = System.Drawing.SystemColors.Control
        End If
    End Sub
End Class

І це все, що мені потрібно для прогнозу VBA. Помістіть це в ThisOutlookSession

Private Sub Application_Reminder(ByVal Item As Object)
    On Error Resume Next
    If Item.MessageClass <> "IPM.Appointment" Then
      Exit Sub
    End If
    Dim sAPPData As String
    Dim sFileName As String
    sAPPData = Environ("AppData")
    sFileName = "\Microsoft\Windows\Start Menu\Programs\BigRedBox\BigRedBox.exe"
    If Dir(sAPPData & sFileName) <> "" Then
        Call Shell(sAPPData & sFileName)
    End If
End Sub

Це вдосконалена версія відповіді tbone, яка працює на німецьких версіях.

Private Declare PtrSafe Function FindWindowA Lib "user32" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare PtrSafe Function SetWindowPos Lib "user32" (ByVal hwnd As Long, ByVal hWndInsertAfter As Long, ByVal X As Long, ByVal Y As Long, ByVal cx As Long, ByVal cy As Long, ByVal wFlags As Long) As Long
Private Declare PtrSafe Function BringWindowToTop Lib "user32" (ByVal hwnd As Long) As Boolean
Private Declare PtrSafe Function SetForegroundWindow Lib "user32" (ByVal hwnd As Long) As Boolean
Private Declare PtrSafe Function SetFocus Lib "user32" (ByVal hwnd As Long) As Long

Private Const SWP_NOSIZE = &H1
Private Const SWP_NOMOVE = &H2
Private Const FLAGS As Long = SWP_NOMOVE Or SWP_NOSIZE
Private Const HWND_TOPMOST = -1

Private Sub Application_Reminder(ByVal Item As Object)
    Dim ReminderWindowHWnd As Variant
    On Error GoTo err
    'Loop 25 times as FindWindowA needs exact title which varies according to number of reminder items...
    Dim iReminderCount As Integer
    For iReminderCount = 1 To 25
        'Try two syntaxes...

        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Erinnerung")
        SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        BringWindowToTop (ReminderWindowHWnd)
        SetForegroundWindow ReminderWindowHWnd
        SetFocus ReminderWindowHWnd

        ReminderWindowHWnd = FindWindowA(vbNullString, iReminderCount & " Erinnerung(en)")
        SetWindowPos ReminderWindowHWnd, HWND_TOPMOST, 0, 0, 0, 0, FLAGS
        BringWindowToTop ReminderWindowHWnd
        SetForegroundWindow ReminderWindowHWnd
        SetFocus ReminderWindowHWnd
    Next
Exit Sub
err:
    Debug.Print err.Number & " - " & err.Description & " (iReminderCount = " & iReminderCount & ")"
    Resume Next
End Sub

Я додав німецькі заголовки вікон , а також деякі нові функції ( BringWindowToTop, SetForegroundWindowі SetFocus).

Працює на моїй німецькій Windows 10 разом із Outlook 2016.

Я не зумів генерувати новий сертифікат (натискання кнопки «Пуск» та введення «сертифікату» нічого не виявило), а просто вибрав ще один сертифікат у списку при підписанні.