Я шукаю інструмент, щоб дозволити зворотний поступовий пошук за допомогою простого регулярного вираження (або просто декількох збігів). Наприклад, якщо я хочу знайти команду 'foo bar baz', я можу зробити щось на зразок наступного, щоб швидко знайти команду:

CRTL-R (починає пошук) введіть 'foo' (відповідає останній команді за допомогою foo) продовжуйте вводити 'foo | baz' (відповідає останній команді, що містить 'foo' AND 'baz'.

Чи існує щось подібне? Якщо ні, то як би я міг сам займатися його реалізацією?

Спеціальний віджет history-incremental-multi-searchдляzsh

Налаштування

Створіть каталог і включіть його у свій $fpathНаприклад, я створив каталог ~/.zsh/functionsі рядок fpath=($HOME/.zsh/functions $fpath)у своєму .zshrc.

Помістіть наступне у файл, названий history-incremental-multi-searchу цьому каталозі.

emulate -L zsh
setopt extended_glob

local oldbuffer=$BUFFER
local -i oldcursor=$CURSOR

local dir                # search direction
local chars              # input buffer
local -a words           # search terms
local -a found           # all history items that match first term
local -i hindex=$HISTNO  # current 
local -i lmatch          # last matched history item (for prev/next)

if [[ $WIDGET == *forward* ]]; then
    dir=fwd
else
    dir=bck
fi

function find-next {
    # split the input buffer on spaces to get search terms
    words=(${(s: :)chars})

    # if we have at least one search term
    if (( $#words )); then
        # get all keys of history items that match the first
        found=(${(k)history[(R)*$words[1]*]})
        if (( $#found )); then
            # search in widget direction by default
            # but accept exception in $1 for "prev match"
            search-${1:-$dir}
        else
            # no matches
            lmatch=$HISTNO
        fi
    else
        # no search terms
        lmatch=$HISTNO
        BUFFER=$oldbuffer
        CURSOR=$oldcursor
    fi
}

function search-fwd {
    # search forward through matches
    local -i i
    for (( i = $#found; i > 0; i-- )); do
        # but not before hindex as we're searching forward
        if [[ $found[$i] -gt $hindex ]]; then
            set-match $found[$i]
        fi
    done
}

function search-bck {
    # search backward through matches
    local -i i
    for (( i = 1; i <= $#found; i++ )); do
        # but not beyond hindex as we're searching backward
        if [[ $found[$i] -lt $hindex ]]; then
            set-match $found[$i]
        fi
    done
}

function set-match {
    # match history item against all terms and select it if successful
    local match=1
    local -i i
    for (( i = 2; i <= $#words; i++ )); do
        if [[ $history[$1] != *$words[$i]* ]]; then
            match=0
            break
        fi
    done
    if [[ $match -ne 0 ]]; then
        lmatch=$1
        BUFFER=$history[$1]
        CURSOR=$#BUFFER
        break
    fi
}

# display sub prompt
zle -R "${dir}-i-search-multi:"

# handle input keys
while read -k; do
    case $REPLY in
        # next
        $'\C-n' )
            hindex=$lmatch
            find-next
            ;;
        # prev
        $'\C-p' )
            hindex=$lmatch
            if [[ $dir == fwd ]]; then
                find-next bck
            else
                find-next fwd
            fi
            ;;
        # break
        $'\e' | $'\C-g' )
            BUFFER=$oldbuffer
            CURSOR=$oldcursor
            break
            ;;
        # accept
        $'\C-m' | $'\C-j' )
            if [[ $lmatch -eq $HISTNO ]]; then
                BUFFER=$oldbuffer
                CURSOR=$oldcursor
            else
                HISTNO=$lmatch
            fi
            break
            ;;
        # erase char
        $'\C-h' | $'\C-?' )
            chars=$chars[1,-2]
            hindex=$HISTNO
            find-next
            ;;
        # erase word
        $'\C-w' )
            if [[ $chars =~ \  ]]; then
                chars=${chars% *}
            else
                chars=
            fi
            hindex=$HISTNO
            find-next
            ;;
        # kill line
        $'\C-u' )
            chars=
            hindex=$HISTNO
            find-next
            ;;
        # add unhandled chars to buffer
        * )
            chars=${chars}${REPLY}
            hindex=$HISTNO
            find-next
            ;;
    esac

    zle -R "${dir}-i-search-multi: $words"
done

Помістіть це або виберіть його зі свого .zshrc:

autoload -U history-incremental-multi-search

# make new widgets from function
zle -N history-incremental-multi-search-backward history-incremental-multi-search
zle -N history-incremental-multi-search-forward history-incremental-multi-search

# bind the widgets to keys
bindkey '^Xr' history-incremental-multi-search-backward
bindkey '^Xs' history-incremental-multi-search-forward

Використовуйте

Тепер ви повинні мати можливість ініціювати зворотний інкрементальний пошук з Ctrl+X, r, вперед Ctrl+X, s.

Введіть пошукові терміни, розділені пробілом. Для керування ним доступні наступні клавіші:

• ← Backspace: стерти символ

• Ctrl+W: стерти слово

• Ctrl+U: лінія вбивства

• Ctrl+N: наступний матч

• Ctrl+P: попередній матч

• Ctrl+G/ Esc: скасувати пошук

• Enter: прийняти

Таке рішення, ймовірно, може бути досить спрощене. Це більше функціональний доказ концепції, що має багато можливостей для вдосконалення.

Ви можете проглядати свою історію:

history | egrep '(foo|baz)'

Я сподіваюся, що це допомагає.

Надбудова відповіді на @ peth:

Zsh тепер поставляється з history-incremental-pattern-search-backward, вам не потрібно визначати це самостійно. Просто додайте прив'язку ключів. Я вважаю за краще змінювати ^R, додаючи наступний рядок до .zshrc:

bindkey '^R' history-incremental-pattern-search-backward

Тепер ви можете використовувати операторів glob (sic! Not rexex) для пошуку.