Чи можна встановити Internet Explorer як браузер за замовчуванням для запуску з командного рядка?

У мене є веб-додаток, який працює лише під Internet Explorer, але якщо трапиться, що Firefox - це браузер за замовчуванням, він не працює. Користувачі перебувають у доменному середовищі, і хоча я намагаюся запустити наш додаток із групи таким чином:

start "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

програма не запускається, якщо я не змінюю браузер вручну.

Ця команда встановить IE як браузер за замовчуванням:

shmgrate.exe OcinstallreinstallIE

Ця політика повинна зупинити людей, які визначають браузер за замовчуванням.

ви можете спробувати це, воно спрацює

start "" "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

помилка у вашій команді полягала в тому, що startочікується, що перша цитувана рядок буде назвою програми, яку в цьому випадку ви можете залишити порожньою.

для налаштування iexplorer.exeяк веб-браузера за замовчуванням системи ви можете використовувати assocі ftypeкоманди, які пов'язують розширення з типами файлів, а типи файлів - з виконуваними файлами, наприклад:

assoc .html=htmlfile
ftype htmlfile="C:\Program Files\Internet Explorer\iexplore.exe" %1

%1 тут є аргумент - це URL-адреса або файл, який ви можете надіслати програмі як вхід

Windows Vista та новіших версій, IE 7+

Наступний пакетний сценарій імітує клацання Встановити цю програму за замовчуванням з аплету панелі керування програми за замовчуванням. Тестовано з Vista / 7 та IE 7 / IE 11.

@echo off
setlocal enabledelayedexpansion

REM -- check XHTML support (IE 9+)
set xhtml=0
for /f %%G in ('"reg query "HKCR\IE.AssocFile.XHT" /ve 2>&1 | findstr /c:".XHT" "') do set xhtml=1

REM -- reset file extensions
set exts=HTM,HTML
if %xhtml% == 1 (set exts=%exts%,XHT,XHTML)

for %%G in (%exts%) do (
set ext=%%G
set ext=!ext:~0,3!
reg add "HKCU\Software\Classes\.%%G" /ve /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)

set exts=%exts%,MHT,MHTML,URL
set acl=%temp%\acl_%random%%random%.txt

for %%G in (%exts%) do (
set key=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%G\UserChoice
echo !key! [1 7 17]>"%acl%"
regini "%acl%" >nul
set ext=%%G
set ext=!ext:~0,3!
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)
del "%acl%" 2>nul

REM -- reset MIME associations
for %%G in (message/rfc822,text/html) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\MIMEAssociations\%%G\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%G" /f >nul
)

REM -- reset URL protocols
for %%A in (FTP,HTTP,HTTPS) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\%%A\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%A" /f >nul
for %%B in (DefaultIcon,shell) do (
set key=HKCU\Software\Classes\%%A
reg delete "!key!\%%B" /f >nul 2>&1
reg copy "HKCR\IE.%%A\%%B" "!key!\%%B" /s /f >nul
reg add "!key!" /v "EditFlags" /t REG_DWORD /d 2 /f >nul
reg add "!key!" /v "URL Protocol" /t REG_SZ /d "" /f >nul
))

REM -- reset the start menu Internet link (Vista and earlier)
reg add "HKCU\Software\Clients\StartMenuInternet" /ve /t REG_SZ /d "IEXPLORE.EXE" /f

REM -- reset cached icons
if %xhtml% == 1 (
ie4uinit -cleariconcache
) else (
taskkill /im explorer.exe /f >nul
start explorer
)

pause
exit /b

Зауваження

Будь-яка програма веб-браузера може зареєструватися, щоб відобразитись як Інтернет-клієнт у меню "Пуск". Ця видимість у поєднанні з належною реєстрацією для файлів та типів протоколу програми дає статус браузера за замовчуванням. Веб-браузер за замовчуванням використовується для запуску довільних URL-адрес з будь-якої точки системи.

Примітка Існуючі реєстрації [посилання меню пуску] ігноруються в Windows 7 та пізніших версіях. Ця реєстрація застаріла, як і для Windows 7.

_{Джерело: Як зареєструвати Інтернет-браузер або клієнт електронної пошти за допомогою меню "Пуск" Windows}

­­

Ієрархічна структура реєстру для асоціацій файлів та протоколів надає перевагу за замовчуванням для користувача перед типовими на рівні машини.

_{Джерело: Програми за замовчуванням}

Ви можете додати нижче двох рядків у файл bat

reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Check_Associations" /d "yes" /t REG_SZ

reg add "HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\http\UserChoice" /f /v "ProgId" /d "IE.HTTP" /t REG_SZ

Після запуску bat, перезавантажте / вийдіть із системи та увійдіть назад, оскільки вище двох командних рядків призначені для зміни значень реєстру.

Деталі про ознаки можна знайти тут

(Виправлено) - Не можна встановити Internet Explorer як браузер за замовчуванням! http://www.windowstechinfo.com/2016/03/fixed-cant-set-internet-explorer-as-the-default-browser.html

Я не знаю про налаштування браузера за замовчуванням з командного рядка, але ви можете встановити та застосувати його для домену за допомогою групової політики.

Ось що для початку:

http://technet.microsoft.com/en-us/library/hh147307%28WS.10%29.aspx

Просто киньте команду, startщоб отримати командний чи пакетний файл.

"C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

Для Windows 8 (IE 10+) сценарій VBS простий:

Dim URL 
Dim IE 
Set IE = CreateObject("internetexplorer.application")
URL = "res://ieframe.dll/defaultbrowser.htm" 
IE.Visible = True
IE.Navigate URL


 Do While IE.Busy
    WScript.Sleep 100
 Loop

IE.Document.getElementById("changeDefaultButton").Click

Він запустить сторінку IE для зміни IE за замовчуванням та імітує натискання на кнопку для прийняття.