ліки від трекболу без колеса прокрутки?

Я думаю придбати трекбол, і мій варіант - мармуровий мармур Logitech. Але потім я виявив, що немає колеса прокрутки. Як ти вирішуєш це? Чи я точно хочу придбати трекбол зі колесом прокрутки? Я багато прокручую, використовуючи facebook.

Я не хочу натискати вказівним і середнім пальцями, тому деякі миші трекбола не працюватимуть для мене, як колесо Trackman.

Якщо ви перебуваєте в Windows, я б запропонував спробувати AutoHotKey, інші користувачі вже вирішили прокручувати Мармурову мишу (я використав сценарій внизу):

http://www.autohotkey.com/board/topic/4677-wheel-button-emulation-script/

Рішення Logitech, яке постачається зі своїми драйверами, є дивним: ви клацніть один раз, щоб увімкнути чотиристоронню прокрутку, і знову натисніть, щоб відключити її. Ви не можете утримувати та прокручувати те, що я був після. Я завершив видалення їх програмного забезпечення.

У мене такий же трекбол і рішення дуже елегантне: при натисканні на обрану кнопку сам м'яч стає колесом прокрутки. Я вибрав велику праву кнопку, яку натискаю мізинцем.

Це дуже зручно, а для звикання потрібно лише кілька днів.

Ви швидко переконаєтесь, що будь-яке колесо прокрутки (на миші чи трекболі) є чимось непридатним. Повірте, воно того варте ;-)

Переваги:

• 2D прокрутка замість 1D
• швидше і точніше прокручування, ніж колесо
• зручніше для тривалого прокручування (завдяки інерції кулі). Ідеально підходить для вашого прикладу у Facebook.

Я вже не можу жити без цього.

Налаштувати, що під будь-якою ОС Linux не важко. Потрібно лише створити файл /etc/X11/xorg.conf (див. Мою конфігурацію тут: Налаштування трекболу під Linux без редагування Xorg.conf )

Детальніше можна ознайомитись тут: https://help.ubuntu.com/community/Logitech_Marblemouse_USB

У Windows у мене немає досвіду, але я думаю, що інструмент налаштування постачається разом із трекболом.

Ви можете спробувати колесо прокрутки з мармуровою мишкою, розроблене спеціально для цієї миші:

Marble Mouse Wheel Wheel, або просто Marble Scroll, це невелика програма, призначена для імітації колеса прокрутки на будь-якому трекболі чи миші без жодного. Він був спеціально розроблений для мармурової миші Logitech, але може працювати з будь-якою стандартною мишею або трекболом. Він розроблений для Windows 2000 і новіших версій.

Мармурова прокрутка - це заміна функцій автоматичного прокрутки Logitech та універсальної прокрутки; ні належним чином не імітуйте справжнє колесо прокрутки, і обидва мають обмеження та недоліки.

Marble Scroll працює з будь-якою мишею або трекболом і не вимагає встановлення драйверів SetPoint або MouseWare Logitech.

Особливості

• Додайте колесо прокрутки до будь-якої миші з більш ніж двома кнопками
• Сумісність із більшістю програм, які підтримують колесо прокрутки (для будь-якого типу введення)
• Регульоване прискорення
• Регульована відстань прокрутки (за "крок" - див. Нижче)
• Покрокове прокручування, щоб імітувати справжнє колесо миші
• Швидкий перемикач режиму вліво / вправо
• Швидке включення / відключення натисканням на піктограму лотка
• Невеликий і легкий на ресурсах системи

Веб-сайт продукту, здається, наразі не працює, але ось копія тексту сайту на Archive.org .

Посилання для завантаження тут .

Існує проста альтернатива 100 + C ++, яка досить схожа на рішення AutoHotKey, тобто

• надсилання вертикальних / горизонтальних коліс прокрутки, переміщуючи трекбол, утримуючи одну з кнопок X і
• середнім клацанням при натисканні та відпусканні кнопки X без переміщення трекболу.

https://github.com/Seelge/TrackballScroll

Редагувати: новіші версії надають піктограму systray, працюють у Windows 10 та базуються на C #.

Ось сценарій AutoHotKey, який я використовую. Ви прокручуєте, утримуючи ліву маленьку кнопку і пересуваючи кулю вгору / вниз. Однак натискання лівої невеликої кнопки все ще робить НАЗАД. Він також може прокручувати вліво / вправо, але це було занадто чутливо для мене, тому це коментується тут (блок, який починається з ;timesX := Abs(movedx) / 4).

Я знайшов оригінальну версію за адресою http://www.autohotkey.com/board/topic/30816-simulate-scroll-wheel-using-right-mouse-button/ . Я розмістив там свою версію як іншийperson8923.

$*XButton1::
Hotkey, $*XButton1 Up, XButton1up, off
;KeyWait, XButton1, T0.4
;If ErrorLevel = 1
;{
   Hotkey, $*XButton1 Up, XButton1up, on
   MouseGetPos, ox, oy
   SetTimer, WatchTheMouse, 5
   movedx := 0
   movedy := 0
   pixelsMoved := 0
;   TrayTip, Scrolling started, Emulating scroll wheel
;}
;Else
;   Send {XButton1}
return

XButton1up:
Hotkey, $*XButton1 Up, XButton1up, off
SetTimer, WatchTheMouse, off
;TrayTip
If (pixelsMoved = 0)
{
    ;The mouse was not moved, send the click event
    ; (May want to make it PGUP or something)
    Send {XButton1}
    Send {XButton1Up}
}
return

WatchTheMouse:
MouseGetPos, nx, ny
movedx := movedx+nx-ox
movedy := movedy+ny-oy

pixelsMoved := pixelsMoved + Abs(nx-ox) + Abs(ny-oy)

;timesX := Abs(movedx) / 4
;ControlGetFocus, control, A
;Loop, %timesX%
;{
;    If (movedx > 0)
;    {
;        SendMessage, 0x114, 1, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx - 4
;    }
;    Else
;    {
;        SendMessage, 0x114, 0, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx + 4
;    }
;}

timesY := Abs(movedy) / 4
Loop, %timesY%
{
    If (movedy > 0)
    {
        Click WheelDown
        movedy := movedy - 4
    }
    Else
    {
        Click WheelUp
        movedy := movedy + 4
    }
}   

MouseMove ox, oy
return

Це така ганьба Logitech не реалізував моделювання колеса прокрутки. Їх драйвер обіцяє зробити цю функцію, але вона працює не для всіх додатків, що робить її марною. Вони були такі близькі до створення ідеальної миші! : с

Єдине рішення, яке я знайшов, - це використовувати для нього скрипт AutoHotkey . За допомогою нього ви можете змусити крихітні кнопки ліворуч / праворуч прокручуватися вгору та вниз. Він працює чудово, але це буде справжній клопот, щоб налаштувати його: вам потрібно спочатку вивчити основи AutoHotkey. Якщо ви вирішили це зробити, ось мій сценарій AutoHotkey. Це адаптація оригінального сценарію Джербо . Одне клацання почне прокручуватися у звичайному темпі, але подвійне чи потрійне клацання почне прокручуватися швидше.

; This script remaps the two small buttons on a Logitech Trackman® Marble® Mouse
; to act as scroll up and scroll down

global lastXButton1ClickTime := 0
global nrSubsequentXButton1Clicks := 0

ScrollTheWheel(direction, scrollKey)
{
    now := A_TickCount
    timeSinceLastClick := now - lastXButton1ClickTime 
    lastXButton1ClickTime := now
    if (timeSinceLastClick < 300)
    {
        nrSubsequentXButton1Clicks := nrSubsequentXButton1Clicks + 1
    }
    else
    {
        nrSubsequentXButton1Clicks := 1
    }        

    sleepingFraction := 5

    if (nrSubsequentXButton1Clicks <= 1)
        scrollSpeed := 30
    if (nrSubsequentXButton1Clicks == 2)
        scrollSpeed := 15
    if (nrSubsequentXButton1Clicks >= 3)
        scrollSpeed := 5

    timeSlept := scrollSpeed

    loop 
    {
        if (direction == 1) ; Scroll down
        {
            static downKeyState
            if (scrollKey == 0) 
                GetKeyState, downKeyState, XButton1, P
            else
                GetKeyState, downKeyState, PgDn, P

            if downKeyState = U ; The key has been released, so break out of the loop
               break

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelDown}
                timeSlept = 0                
            }
        }
        else ; Scroll up
        {
            static upKeyState
            if (scrollKey == 0)
                GetKeyState, upKeyState, XButton2, P
            else
                GetKeyState, upKeyState, PgUp, P

            if upKeyState = U ; The key has been released, so break out of the loop
               break            

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelUp}
                timeSlept = 0                
            }
        }   

        Sleep, sleepingFraction
        timeSlept := timeSlept + sleepingFraction
    }    
}

XButton2::
    ScrollTheWheel(0, 0)
    return
XButton1::
    ScrollTheWheel(1, 0)
    return
!PgUp::
    ScrollTheWheel(0, 1)
    return
!PgDn::
    ScrollTheWheel(1, 1)
    return

У мене щойно з'явилася миша з мармуру Logitech, і у мене також була проблема прокрутки. Тому я зробив цей сценарій на AutoHotKey. Ліва кнопка Xbutton дозволяє прокручувати, тобто під час руху вниз ви можете прокручувати вертикально і горизонтально м'яч, а також рухатись вперед та назад у браузері лівою та правою кнопками. Правий Xbutton виконує ті ж дії, що і середня кнопка.

Я на Windows 7.

#SINGLEINSTANCE FORCE  
GLOBAL status := "basic"
GLOBAL cnt_x
GLOBAL cnt_y

XButton2::MButton

$*XButton1::
    status := "scroll"
    cnt_x := 0
    cnt_y := 0
    MOUSEGETPOS, st_x, st_y
    SETTIMER, _scroll, 30
RETURN

$*XButton1 UP::
    status := "basic"
    SETTIMER, _scroll, OFF
RETURN

_scroll:
    MOUSEGETPOS, cur_x, cur_y
    MOUSEMOVE, st_x, st_y

IF(abs(cur_x-st_x) > abs(cur_y-st_y)) {
    cnt_x := cnt_x + (cur_x-st_x)
    ControlGetFocus, control, A 
    IF (cnt_x > 7) {
        cnt := floor(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 0, 0, %control%, A
        }
        cnt_x := cnt_x - 8*floor(cnt_x / 8)
    } ELSE IF (cnt_x < -7) {
        cnt := -ceil(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 1, 0, %control%, A
        }
        cnt_x := cnt_x - 8*ceil(cnt_x / 8)
    }
} ELSE {
    IF (cur_y >= st_y) {
        cnt_y := cnt_y + (cur_y-st_y)**1.2
    } ELSE {
        cnt_y := cnt_y -(st_y-cur_y)**1.2
    }   
    IF (cnt_y > 7) {
        cnt := floor(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelUp
        }
        cnt_y := cnt_y - 8*floor(cnt_y / 8)
    } ELSE IF (cnt_y < -7) {
        cnt := -ceil(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelDown
        }
        cnt_y := cnt_y - 8*ceil(cnt_y / 8)
    }
}   
RETURN

$*LButton::
    IF (status = "basic") {
        CLICK DOWN Left
    } ELSE IF (status = "scroll") {
        SEND {Browser_Back}
    }
RETURN

$*LButton UP::
    IF (status = "basic") {
        CLICK UP Left
    }
RETURN

$*RButton::
    IF (status = "basic") {
        CLICK DOWN Right
    } ELSE IF (status = "scroll") {
        SEND {Browser_Forward}
    }
RETURN

$*RButton UP::
    IF (status = "basic") {
        CLICK UP Right
    }
RETURN

Залежно від вашої ОС, ви, можливо, зможете налаштувати одну з кнопок, щоб увімкнути прокрутку за допомогою переміщення вказівника, коли утримується. Наприклад, наступний сценарій дозволяє це на кнопці 10 моєї миші (кнопка "верхній середній" у Logitech MX310):

#!/bin/sh
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 290 10
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 286 1
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 287 6 7 4 5

Є такі мармурові миші (миші), у яких включено колесо прокрутки. В іншому випадку схоже, що для миші, що не має коліс, потрібна програма або якийсь сценарій, а також використання однієї з кнопок для включення функції прокрутки (що ви зазначили в коментарі до іншої відповіді, як не прийнятне рішення).

Отже "Навіщо винаходити колесо?" - хороша приказка в цьому випадку.

У цих прикладах елемент є фізично встановленим і на вибір можна вибрати багато типів. Нижче наведено два приклади та стилі.

Або щось подібне: Адессо

Два нестандартні варіанти

• Використовуйте Apple Magic Trackpad на додаток до трекболу. (Це моє поточне рішення) http://www.apple.com/magictrackpad/

• Придбайте контролер стрибків та використовуйте його на додаток до трекболу. Махніть рукою перед пристроєм, щоб прокручувати вгору та вниз. https://www.leapmotion.com/product

Кредит зображення http://www5.pcmag.com/media/images/393268-leap-motion-controller.jpg

Просте рішення (і ергономічне, наважусь сказати) рішення - поставити функцію прокрутки на ліву руку.

Цього можна досягти за допомогою миші лівою рукою / за допомогою клавіатури із вбудованим колесом прокрутки на лівому краю / шляхом призначення функцій прокрутки клавішам програмованої клавіатури з такою програмою, як Mkey ( http: // www.seriosoft.org/en/index.php ).

Чому я вважаю, що це більш ергономічно - адже такий підхід розподіляє напругу рівномірно на обидві руки. (Детальніше про це: http://capsoff.org/checklist ).

Я в Windows7 і використовую оптичний трекбол Kensington Orbit Optical без прокрутки - це трекбол з двома кнопками, без кнопок X, необхідних більшості сценаріїв та програм AHK, на які вказували інші.

Однак MouseImp працює для мене на Windows7. ІТ-конфігурується, але у мене це налаштовано для right-click + rollотримання екрана прокрутки. Це більше схоже на перетягування, тому вказівник рухається, і у вас є одночасно один екран [оновлення: частота прокрутки налаштовується, тому вона може бути більше, ніж "одна сторінка"].

У той же час, Кенсінгтона TrackballWorks був налаштований , щоб дати мені сторінку вниз сувій на left-click + right-click. На жаль, він не може одночасно прокручувати сторінку назад (одну чи іншу).

Це не модуль продукту - це якраз те, що я знайшов працювати з цією моделлю / типом трекболу .

Caveat: ви постійно клацаєте правою та лівою кнопкою миші, і це може призвести до плутанини, а посилання переслідуються / активуються js, коли ви просто хочете зупинити прокрутку . ::: зітхнути :::

Щойно я отримав орбіту бездротового трекболу з Кенсінгтона, це досить дивовижно. У вас є м'яч, у вас обидві кнопки на кожній стороні і у вас є своєрідне коло поза трекболом, що дозволяє прокручувати сторінку вгору або вниз. Це дійсно працює, і я використовую в Windows і Mac OSX.

Насправді я щось зробив для цього, використовуючи AutoHotkey, і подумав, що поділюсь і цим: Емулятор колеса миші

Це імітує прокручування колеса миші, переміщуючи мишу, утримуючи ліву та праву кнопки миші.

Можна також імітувати середній клік, натискаючи одночасно ліву та праву кнопки миші.

Ще одне рішення для Windows 7, яке дозволяє прокручувати всі програми, включаючи Internet Explorer:

1. Встановіть AutoHotKey .
2. Збережіть цей сценарій як scroll.ahkна робочому столі.
3. Клацніть правою кнопкою миші на scroll.ahk.
4. Виберіть Запустити сценарій .
5. Підтвердіть, якщо буде запропоновано.

Це змусить утримувати маленьку праву кнопку прокрутки вертикально під час переміщення трекболу. Маленька ліва кнопка - це кнопка "назад".

Якщо посилання на код Еріка Елмора зникає, ось воно:

;;
;; Emulate_Scrolling_Middle_Button.ahk
;; Author: Erik Elmore <erik@ironsavior.net>
;; Version: 1.1 (Aug 16, 2005)
;;
;; Enables you to use any key with cursor movement
;; to emulate a scrolling middle button.  While
;; the TriggerKey is held down, you may move the
;; mouse cursor up and down to send scroll wheel
;; events.  If the cursor does not move by the
;; time the TriggerKey is released, then a middle
;; button click is generated.  I wrote this for my
;; 4-button Logitech Marble Mouse (trackball),  
;; which has no middle button or scroll wheel.
;;

;; Configuration

;#NoTrayIcon

;; Higher numbers mean less sensitivity
esmb_Threshold = 7

;; This key/Button activates scrolling
esmb_TriggerKey = XButton2

;; End of configuration

#Persistent
CoordMode, Mouse, Screen
Hotkey, %esmb_TriggerKey%, esmb_TriggerKeyDown
HotKey, %esmb_TriggerKey% Up, esmb_TriggerKeyUp
esmb_KeyDown = n
SetTimer, esmb_CheckForScrollEventAndExecute, 10
return

esmb_TriggerKeyDown:
  esmb_Moved = n
  esmb_FirstIteration = y
  esmb_KeyDown = y
  MouseGetPos, esmb_OrigX, esmb_OrigY
  esmb_AccumulatedDistance = 0
return

esmb_TriggerKeyUp:
  esmb_KeyDown = n
  ;; Send a middle-click if we did not scroll
  if esmb_Moved = n
    MouseClick, Middle
return

esmb_CheckForScrollEventAndExecute:
  if esmb_KeyDown = n
    return

  MouseGetPos,, esmb_NewY
  esmb_Distance := esmb_NewY - esmb_OrigY
  if esmb_Distance
    esmb_Moved = y

  esmb_AccumulatedDistance := (esmb_AccumulatedDistance + esmb_Distance)
  esmb_Ticks := (esmb_AccumulatedDistance // esmb_Threshold) ; floor divide
  esmb_AccumulatedDistance := (esmb_AccumulatedDistance - (esmb_Ticks * esmb_Threshold))
  esmb_WheelDirection := "WheelDown"
  if (esmb_Ticks < 0) {
    esmb_WheelDirection := "WheelUp"
    esmb_Ticks := (-1 * esmb_Ticks)
  }

  ;; Do not send clicks on the first iteration
  if esmb_FirstIteration = y
    esmb_FirstIteration = n
  else {
    Loop % esmb_Ticks {
      MouseClick, %esmb_WheelDirection%
    }
  }

  MouseMove,esmb_OrigX,esmb_OrigY,0
return

Ще один користувач Trackman Marble тут.

Я використовую X-Mouse Button Control для емуляції прокрутки. Ця реалізація функцій там не досконала (поки що?), Але вона набагато корисніша, ніж реалізація Logitech у власному програмному забезпеченні SetPoint ™.

Я рекомендую XMBC всім, хто не хоче возитися з AutoHotKey і шукає те, що просто працює.