Відповіді:
Відповідь - ні. Як вони могли це зробити? Якщо вони зробили це, а хтось відключив це, вони відрізали б людей від дуже необхідних пунктів меню. Це був би кошмар.
Єдине, що ви можете зробити, це жити з цим або постійно активувати меню, натиснувши Організувати> Макет> Рядок меню.
Я вже використовую AutoHotkey , тому я додав цей рядок до свого сценарію, і це виправило цю дратівливу поведінку майже у всіх програмах:
~LAlt Up:: return
Він не працює в IE, але я все одно не використовую IE. :)
До речі, я також вбив роздратоване меню запуску через:
~LWin Up:: return
~RWin Up:: return
Я знайшов це питання, оскільки у мене нова клавіатура, а іноді випадково натискаю ALTклавішу під час введення електронних листів у Gmail. Фокус втрачається, і будь-який наступний натискання клавіші передається моєму браузеру (що може мати дуже дратує результати іноді).
Найкраще я знайшов рішення, яке є вдосконаленням, але не є ідеальним - із програмою для створення ключів під назвою KeyTweak , яка, наскільки я розумію, змінює реєстр .
У програмі ви позначаєте карту Left Altна Right Altта Right Altдо Left Alt. Це дозволяє Altфункціям все-таки дещо працювати ( Ctrl- Alt- Delete). Однак Alt- Tabчастково зламана (принаймні, на моїй Windows-7). Це дозволяє частково переходити до інших програм, але коли ви відпустите Altключ, "вибір" наступної програми не робиться (однак ви можете зробити це натисканням миші).
Це дуже погано, що Windows не може щось запобігти втраті уваги від помилкових натискань Alt. В Shiftі Ctrlключі не мають такого ефекту, наприклад.
Цей цікавий. Я не знаю жодної програми, крім Autokey. Або просто закінчити написання програми. Але налаштування реєстру немає. Це порушило б TONS програм.
Ця автоматична клавіша працює для мене в Windows 10:
Alt::Return ;Disables the key alt when it's pressed alone
(Відповідь Зенгабора для мене не спрацювала).
Вся слава Рогведдеру
як знайдено десь @MS
HKEY_CURRENT_USER\Control Panel\Accessibility\Keyboard PreferenceOnі встановіть його значення на 1Я шукав рішення тієї самої проблеми: виправлення того, як Windows реагує на "Alt + Shift" (зміна мови введення), але ви вводите помилку та натискаєте Alt, а потім Shift, без перекриття. У цьому випадку Windows трактує одинокий Alt як "меню вибору", одинокий Shift нічого не робить, а будь-які символи, які ви натискаєте після цього, вибираєте та вводите випадкові меню, які ви не збиралися відкривати.
Якщо ви користуєтесь додатком для чату, як-от Skype, і ви є диктором іноземної мови, перемикання з Alt + Shift відбувається досить часто, і ви можете поспішати робити багато дурних речей.
@ user3419297 вказав мені на своє рішення тут, яке я змінив, щоб Alt + Shift відбувався у всіх випадках. Це лише один # Якщо більше, але дуже важливий! Відповідний уривок:
; Disable stand-alone Alt key press: make Alt purely a modifier key.
; The If statement is required to get Alt+Shift work as expected. If it's not
; there, only [Press Alt], [Press Shift], [Release Shift], [Release Alt] would
; trigger the input language change. The other, more common sequence would be
; [Press Alt], [Press Shift], [Release Alt], [Release Shift], but AutoHotKey
; would block it before it reaches Windows if the "#If" isn't there.
#If not GetKeyState("LShift", "P")
~LAlt::
KeyWait, LAlt
return
; Make Alt+Something still work:
~LAlt Up::
Send, {LAlt Up}
return
Мій повний сценарій також включає дві Linuxish функції: Alt + F2 відкриває "швидку команду запуску", а натискання правої клавіші Alt мінімізує поточне активне вікно:
;==============================================================================
; AutoHotKey script for "Linuxifying" Windows 8.
; Based on suggestions on SuperUser (http://superuser.com/questions/1147370)
;
; Written by: Veselin Georgiev
; Date : 2016-11-18
;==============================================================================
; Optional: Make Alt+F2 bring up the "quick launch command" Window.
; In this case, it simulates the Windows logo key press. On Windows 8, the
; cursor would be in the search bar, which nicely emulates launching a
; command.
!F2::
Sleep 200
Send {LWin}
return
; Disable stand-alone Alt key press: make Alt purely a modifier key.
; The If statement is required to get Alt+Shift work as expected. If it's not
; there, only [Press Alt], [Press Shift], [Release Shift], [Release Alt] would
; trigger the input language change. The other, more common sequence would be
; [Press Alt], [Press Shift], [Release Alt], [Release Shift], but AutoHotKey
; would block it before it reaches Windows if the "#If" isn't there.
#If not GetKeyState("LShift", "P")
~LAlt::
KeyWait, LAlt
return
; Make Alt+Something still work:
~LAlt Up::
Send, {LAlt Up}
return
; Optional: Make the right alt key minimize the currently visible window.
~RAlt Up::WinMinimize A
Це працює в моїй системі з автоматичною клавішею:
~LAlt::
KeyWait, LAlt
return
~LAlt Up::
Send, {LAlt Up}
return
Це змушує LAlt поводитися виключно як модифікаційний ключ, не викликаючи жодних дій, якщо його натискати все само собою (наприклад, активація панелі меню поточного активного вікна).
Редагувати:
Спробуйте також це .
Жодне з розміщених тут рішень на базі AHK не працювало для мене. Однак, з деякими хитрощами, я зрозумів, що якщо ви з’єднаєте ALT з будь-якою іншою клавішею до її випуску, вона не буде діяти для виділення меню. Замість того, щоб витрачати функціональну клавішу, я використовував непризначений код сканування, який ніколи не використовується для будь-яких інших цілей.
LAlt::
sendinput, {LAlt down}
sendinput, {SC0E8 down} ;this is the scan code of an unassigned key. As long as you nor the system never use it for anything else, it can be used in THIS way to cancel the menu acceleration.
;tooltip, Lalt is pressed
KeyWait, LAlt
; That line is important, so that ALT does not continuously fire as you are holding it down.
;tooltip, Lalt was released
return
LAlt up::
sendinput, {LAlt up}
sendinput, {SC0E8 up}
;;;Unlike my 2nd keyboard, this method does not use the scan code as a strict "wrapper."
;;tooltip,
return
RAlt::
sendinput, {RAlt down}
sendinput, {SC0E8 down}
;;tooltip, Ralt is pressed
KeyWait, RAlt
;;tooltip, Ralt was released
return
RAlt up::
sendinput, {RAlt up}
sendinput, {SC0E8 up}
;;tooltip,
return
Пояснення відео:
https://www.youtube.com/watch?v=vRld4bVFrpU&lc=UgzMjkQd4rbmvRDqU9h4AaABAg
Посилання на повний сценарій:
https://github.com/TaranVH/2nd-keyboard/blob/master/Taran's%20Windows%20Mods/Alt_menu_acceleration_DISABLER.ahk
Просто розміщуючи рішення, яке я знайшов навколо. Це вбиває будь-яке Altменю на 100%
Alt::
KeyWait, Alt
return
LAlt Up::
if (A_PriorKey = "Alt")
return
return
Якщо ви також віддаєте перевагу, ви також можете обмежити це рішення однією програмою:
#IfWinActive ahk_exe sublime_text.exe
Alt::
KeyWait, Alt
return
LAlt Up::
if (A_PriorKey = "Alt")
return
return
#IfWinActive