Хтось має сценарій Mac Terminal для видалення прихованих файлів?

Мій автомобільний стереосистем може відтворювати музику з флеш-накопичувачів USB, тому я запитав про копіювання MP3-файлів із списку відтворення iTunes . Це працювало чудово, але мій стерео не відтворював MP3-файли. Зрештою я поставив флешку в робочий комп'ютер під управлінням Windows 7, і знайшов проблему: ._[filename].mp3також було завантажено купу прихованих файлів у форматі .

Я знаю, що в Windows ви можете видаляти файли на основі атрибутів, і мені було цікаво, чи можете ви зробити те ж саме в Терміналі? Можливо, зі скриптом, який я можу запустити з томом як параметр?

Ці файли приховані в OS X, тому що вони починаються з, .а тому не відображаються у Finder за замовчуванням. У цих файлах немає спеціального атрибуту, окрім цього.

Дуже спрощеним підходом було б видалення всіх файлів, які починаються з крапки і підкреслення:

find /Volumes/<your-volume-name> -name '._*' -type f -delete

Примітка безпеки: Запустіть це без того, -deleteщоб побачити, які файли буде видалено. І ніколи цього не робіть на всьому Mac HD, лише на USB-накопичувачі.

Для отримання додаткової інформації: Ці файли називаються "Forks Forks" і іноді містять інформацію, яку ви не хочете видаляти. У вашому випадку використання, але це повинно бути добре. Ви можете назавжди відключити створення цих файлів за допомогою BlueHarvest . Також є додаток, який претендує на очищення об'ємів, але я не пробував це, і це бета-версія, тому використовуйте з обережністю: Hidden Cleaner .

Ще одне рішення, яке працювало для мене (MacOS 10.6.8) у термінальному типі:

dot_clean "/Volumes/<your-volume-name>"

У мене була та сама проблема з моїм автомобільним стерео, 1 файл / 2 не підлягає програванню, тому що програвач вважає, що точковий файл, створений MAC OS, є музичним файлом ... Тоді я вважав цю публікацію дуже корисною, дякую.

Тому я повертаюся зараз із покращеним та безкоштовним рішенням для Mavericks:

1. Створіть додаток Automator для запуску сценарію AppleScript

2. Скористайтеся цим сценарієм:

   on run {input, parameters}
       try
           tell application "Finder" to set allDrives to the name of every disk whose local volume is true and startup is false
           set driveName to {choose from list allDrives with title "DiskCleaner" with prompt "Disk to Clean and Eject:" OK button name "Clean and Eject" cancel button name "Abort"} as text
           set getDriveIdentifier to "diskutil info " & quoted form of driveName & " | grep Ident | awk '{print $3}'"
           set driveIdentifier to do shell script getDriveIdentifier
           try
               do shell script "find /Volumes/" & quoted form of driveName & " -name '.DS_Store' -type f -delete"
               do shell script "find /Volumes/" & quoted form of driveName & " -name '.FBC*' -type f -delete"
               do shell script "find /Volumes/" & quoted form of driveName & " -name '._*' -type f -delete"
               do shell script "rm -rf /Volumes/" & quoted form of driveName & "/.{,_.}{fseventsd,Spotlight-V*,Trashes}"
               display notification "Disk Cleaned"
           on error
               try
                   do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '.DS_Store' -type f -delete" with administrator privileges
                   do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '.FBC*' -type f -delete" with administrator privileges
                   do shell script "sudo find /Volumes/" & quoted form of driveName & " -name '._*' -type f -delete" with administrator privileges
                   do shell script "sudo rm -rf /Volumes/" & quoted form of driveName & "/.{,_.}{fseventsd,Spotlight-V*,Trashes}" with administrator privileges
                   display notification "Disk Cleaned"
               on error
                   display notification "Can't Clean, Permission Denied"
               end try
           end try
           delay 1
           try
               do shell script "diskutil eject " & driveIdentifier
               display notification "Disk Ejected"
           on error
               display notification "Can't Eject, Disk in Use"
           end try
       on error
           display notification "No Disk to Clean and Eject"
       end try
   end run
   

3. Збережіть програму, наприклад, DiskCleaner.app

Цей скрипт попросить обрати USB-диск для очищення та вилучення. Тоді він очистить USB-диск (намагається з адміністраторськими обліковими записами, якщо вони не вдалися до поточних), а потім видалити, якщо можливо.

Звичайно, є ще дещо для вдосконалення, я робив цей сценарій для себе!

Також у вас є можливість додавати кодові рядки для очищення більшої кількості файлів.

Насолоджуйтесь!

Ви також можете використовувати Automator, щоб виконати те саме, якщо термінал вас налякав:

Цей скрипт використовується для видалення прихованих файлів або каталогів на USB-накопичувачах. https://github.com/ulasyurtsever/delete-hidden-files-or-directories