zsh справа-виправдання в ps1

Мені б хотілося, щоб рядковий zsh-рядок з правою вкладеною частиною виглядав приблизно так:

2.nate@host:/current/dir                                               16:00
->

Я знаю про RPROMPT в zsh, але це правильне вирівнювання напроти вашої звичайної підказки, яке знаходиться в тому ж рядку тексту, що і ваш текст.

Чи існує спосіб вирівняти праву частину до першого рядка багаторядкового командного рядка? Я шукаю або директиву в змінній PS1, яка говорить "правильне вирівнювання зараз", або змінну, яка призначена для PS1, що таке RPROMPT для PROMPT.

Дякую!

Ви знайдете детальну відповідь та приклад тут . Ідея полягає в тому, щоб записати рядок перед PS1 за допомогою precmdзворотного дзвінка, використання $COLUMNSта трохи математики для обчислення положення тексту в правій частині екрана. Знання послідовностей втечі також допоможе вам у розташуванні та розфарбуванні курсору.

Іншим рішенням може бути використання теми з Oh My ZSH .

Я теж це шукав. Для мене той факт, що precmd()намальовані лінії не перемальовуються за розміром або коли ^Lвикористовується для очищення екрану, було щось, що в мене не зудило свербіння. Що я зараз роблю, - це використання послідовностей аварійних відбітків ANSI, щоб трохи перемістити курсор. Хоча я підозрюю, що існує більш елегантний спосіб їх видачі, для мене це працює:

_newline=$'\n'
_lineup=$'\e[1A'
_linedown=$'\e[1B'

PROMPT=...whatever...${_newline}...whatever...
RPROMPT=%{${_lineup}%}...whatever...%{${_linedown}%}

Майте на увазі, що керівництво zsh зазначає, що% {...%} призначено для буквальних послідовностей втечі , які не переміщують курсор . Незважаючи на це, я їх використовую, оскільки вони дозволяють ігнорувати довжину вмісту (не вдалося зрозуміти, як випустити вхід, який переміщує курсор, використовуючи їх)

Ось як я зараз налаштував цю річ. Цей підхід не вимагає жодних маніпуляцій послідовності евакуації, але змусить у вас мати дві різні змінні для первинного підказки: PS1з розфарбуванням і NPS1без.

# Here NPS1 stands for "naked PS1" and isn't a built-in shell variable. I've
# defined it myself for PS1-PS2 alignment to operate properly.
PS1='%S%F{red}[%l]%f%s %F{green}%n@%m%f %B%#%b '
NPS1='[%l] %n@%m # '
RPS1='%B%F{green}(%~)%f%b'

# Hook function which gets executed right before shell prints prompt.
function precmd() {
    local expandedPrompt="$(print -P "$NPS1")"
    local promptLength="${#expandedPrompt}"
    PS2="> "
    PS2="$(printf "%${promptLength}s" "$PS2")"
}

Зверніть увагу на використання print -Pдля оперативного розширення, ${#variable}для отримання довжини рядка, що зберігається в змінній, і printf "%Nd"для лівої підкладки з Nпробілами. Обидва printі printfє вбудованими командами, тому не повинно бути результатів.

Давайте визначимо підказку за допомогою цього макета:

top_left              top_right
bottom_left        bottom_right

Для цього нам знадобиться функція, яка повідомляє нам, скільки символів займає даний рядок під час друку.

# Usage: prompt-length TEXT [COLUMNS]
#
# If you run `print -P TEXT`, how many characters will be printed
# on the last line?
#
# Or, equivalently, if you set PROMPT=TEXT with prompt_subst
# option unset, on which column will the cursor be?
#
# The second argument specifies terminal width. Defaults to the
# real terminal width.
#
# Assumes that `%{%}` and `%G` don't lie.
#
# Examples:
#
#   prompt-length ''            => 0
#   prompt-length 'abc'         => 3
#   prompt-length $'abc\nxy'    => 2
#   prompt-length '❎'          => 2
#   prompt-length $'\t'         => 8
#   prompt-length $'\u274E'     => 2
#   prompt-length '%F{red}abc'  => 3
#   prompt-length $'%{a\b%Gb%}' => 1
#   prompt-length '%D'          => 8
#   prompt-length '%1(l..ab)'   => 2
#   prompt-length '%(!.a.)'     => 1 if root, 0 if not
function prompt-length() {
  emulate -L zsh
  local COLUMNS=${2:-$COLUMNS}
  local -i x y=$#1 m
  if (( y )); then
    while (( ${${(%):-$1%$y(l.1.0)}[-1]} )); do
      x=y
      (( y *= 2 ));
    done
    local xy
    while (( y > x + 1 )); do
      m=$(( x + (y - x) / 2 ))
      typeset ${${(%):-$1%$m(l.x.y)}[-1]}=$m
    done
  fi
  echo $x
}

Нам знадобиться ще одна функція, яка бере два аргументи і друкує повний штраф із цими аргументами на протилежних сторонах екрана.

# Usage: fill-line LEFT RIGHT
#
# Prints LEFT<spaces>RIGHT with enough spaces in the middle
# to fill a terminal line.
function fill-line() {
  emulate -L zsh
  local left_len=$(prompt-length $1)
  local right_len=$(prompt-length $2 9999)
  local pad_len=$((COLUMNS - left_len - right_len - ${ZLE_RPROMPT_INDENT:-1}))
  if (( pad_len < 1 )); then
    # Not enough space for the right part. Drop it.
    echo -E - ${1}
  else
    local pad=${(pl.$pad_len.. .)}  # pad_len spaces
    echo -E - ${1}${pad}${2}
  fi
}

Нарешті, ми можемо визначити функцію, яка встановлює PROMPTта RPROMPT, доручити ZSH викликати її перед кожним запитом та встановити правильні параметри розширення підказки:

# Sets PROMPT and RPROMPT.
#
# Requires: prompt_percent and no_prompt_subst.
function set-prompt() {
  emulate -L zsh
  local git_branch="$(git rev-parse --abbrev-ref HEAD 2>/dev/null)"
  git_branch=${${git_branch//\%/%%}/\\/\\\\\\}  # escape '%' and '\'

  local top_left='%F{blue}%~%f'
  local top_right="%F{green}${git_branch}%f"
  local bottom_left='%B%F{%(?.green.red)}%#%f%b '
  local bottom_right='%F{yellow}%T%f'

  PROMPT="$(fill-line "$top_left" "$top_right")"$'\n'$bottom_left
  RPROMPT=$bottom_right
}

autoload -Uz add-zsh-hook
add-zsh-hook precmd set-prompt
setopt noprompt{bang,subst} prompt{cr,percent,sp}

Це створює таку підказку:

~/foo/bar                     master
% █                            10:51

• Зліва вгорі: синій поточний каталог.
• Справа вгорі: гілка Green Git.
• Знизу зліва: #якщо корінь, %якщо ні; зелений на успіх, червоний на помилку.
• Знизу справа: жовтий поточний час.

Додаткову інформацію ви можете знайти в рядковому рядку: Відсутній інгредієнт та повний код у цій суті .