Зміна ваги рядків даних у графіку Excel (багато одразу)

Чи є спосіб змінити вагу всіх рядків одразу на лінійній діаграмі Excel?

У мене є графік з приблизно 50 серіями даних на ньому, і це занадто багато, щоб пройти всі їх і змінити ваги окремо, і важко зрозуміти дані, якби лінії були тоншими, це було б трохи простіше). Я не бачу способу їх багаторазового вибору, що здається трохи жахливим.

Редагувати: я врешті-решт отримав це з наступним кодом (після вивчення трохи VB). Я, здається, не дуже допомагає читати графік! Кріс допоміг мені розібратися, тож я дам йому галочку.

Sub onepxlines()
        With Selection
            MsgBox ("Selection: " & TypeName(Selection))
            If TypeName(Selection) = "ChartArea" Then
                Dim area As ChartArea
                Set area = Selection

                MsgBox ("Area parent: " & TypeName(area.Parent))

                If TypeName(area.Parent) = "Chart" Then
                    Dim chart As chart
                    Set chart = area.Parent
                    Dim srs As Series

                    For Each srs In chart.SeriesCollection
                        srs.Format.Line.Weight = 1.5
                    Next
                End If
            End If
        End With
End Sub

Напевно, найпростіше написати швидкий макрос, якийсь подібний

Sub SetWeights()
    Dim srs As Series
    For Each srs In ActiveSheet.ChartObjects("Chart 1").Chart.SeriesCollection
        srs.Format.Line.Weight = 0.75
    Next
End Sub

Це більш сумісна версія копії та вставки, відповідь Кріса:

Sub SetWeights()
    Dim srs As Series
    For Each srs In ActiveChart.SeriesCollection
        srs.Format.Line.Weight = 0.25
    Next
End Sub

Просто виберіть діаграму і запустіть макрос.

Вдосконалення: створіть змінну VB (LineWT), яка вказує на комірку електронної таблиці. Потім замість "Format.Line.Weight = 0,25" змініть 0,25 на LineWT. Потім ви можете змінити вагу рядка, змінивши його на електронній таблиці та натиснувши кнопку макросу. Ви можете використовувати аналогічний код для встановлення імен X / Y Axes із вказівниками до таблиці.

Це прекрасно працювало для мене. Я використовував цей код, щоб він редагував усі рядки у всіх діаграмах на всіх аркушах робочої книги

Sub ChangeLineType()

'This macro will print all embedded charts in the active workbook
'
    Application.ScreenUpdating = False
    Dim Sht As Object
    Dim Cht As ChartObject
    For Each Sht In ActiveWorkbook.Sheets
        For Each Cht In Sht.ChartObjects
            Cht.Activate
            ActiveChart.ChartArea.Select
            'ActiveWindow.SelectedSheets.PrintOut
                Dim srs As Series
                For Each srs In ActiveChart.SeriesCollection
                srs.Format.Line.Weight = 0.25
                Next
        Next
    Next
End Sub

Я не думаю, що ви можете багаторазово вибирати рядки. Найпростіший спосіб - це, мабуть, змінити його, а потім вибрати кожен по черзі, використовуючи Ctrl-Y, щоб пройти та повторно змінити вагу лінії.

Цей код змінює ширину рядка всіх діаграм в активній таблиці, включаючи аркуші діаграм :

' Sets the line thickness for all charts in the active spreadsheet.
Sub ChangeLineType()
    Dim Cht As Chart
    Dim Chts As New Collection
    Dim Sht As Object   ' Can be Chart or WorkSheet

    For Each Sht In ActiveWorkbook.Sheets
        If TypeName(Sht) = "Chart" Then
            Chts.Add Sht
        Else
            For Each Cht In Sht.ChartObjects
                Chts.Add Cht
            Next
        End If
    Next

    Application.ScreenUpdating = False
    For Each Cht In Chts
        Dim Srs As Series
        For Each Srs In Cht.SeriesCollection
            Srs.Format.Line.Weight = 0.25
        Next Srs
    Next Cht
End Sub

(Адаптовано з відповіді Девіда Маркмана.)

На вкладці «Головна», у розділі «Шрифт», виберіть спадне меню «Межі». Виберіть потрібний стиль або колір лінії. З'явиться олівець. Замість використання олівця для натискання на кожен рядок, який ви хочете змінити, перейдіть до кута сітки комірок, які ви хочете змінити, і утримуйте клавішу CNTRL. Перетягніть олівець по необхідній сітці комірок, і все зміниться у вибраному вами стилі чи кольорі.