Як налаштувати Firefox за допомогою сценарію?

Я хочу налаштувати наступні налаштування Firefox за допомогою сценарію (VBS або пакетної)

• домашня сторінка за замовчуванням
• пошукова система за замовчуванням
• вимкнути автоматичне оновлення

Чи можливо це?

Це можна зробити, створивши або маніпулюючи файлами уподобань Mozilla за допомогою потрібної мови сценаріїв.

Перелік налаштувань, які можна встановити за допомогою цих файлів, див. У розділі Mozilla Preferences та документація about: config , хоча ті, що відповідають вашому списку, виглядають так: -

• browser.startup.homepage (домашня сторінка за замовчуванням)
• browser.search.defaultenginename (пошукова система за замовчуванням)
• app.update.auto (увімкнути / вимкнути автоматичне оновлення)

Однак, залежно від вашого оточення, вам може бути краще натиснути налаштування за допомогою спеціального додатку (див. Коментарі XPI у Короткому посібнику Mozilla Preferences ) або через GPO з FirefoxADM чи подібними.

Ви можете змінити параметри приватного браузера у файлі user.js у папці профілів користувачів. Я часто використовую це, щоб перекрити деякі варіанти, наприклад, конвеєр. Firefox потрібно перезапустити після оновлення user.js. Якщо файл user.js не існує, його потрібно створити.

буквально скопіювати / вставити ту частину відповіді, яку я шукав (win env.)

'C:\Users\User\AppData\Roaming\Mozilla\Firefox\Profiles\#####.default\prefs.js'

додати

user_pref("browser.startup.homepage", "http://www.URL");

мої спроби скопіювати на віддалені машини за допомогою шляху Get-Content / cat string.txt / "String" >>, що закінчилося тим, що сміття вставляється у prefs.jsфайл через символи втечі в рядку.

cd /D "%APPDATA%\Mozilla\Firefox\Profiles\*.default"

set ffile=%cd%

echo user_pref("browser.startup.homepage", "http://superuser.com");>>"%ffile%\prefs.js"
echo user_pref("browser.search.defaultenginename", "Google");>>"%ffile%\prefs.js"
echo user_pref("app.update.auto", false);>>"%ffile%\prefs.js"
set ffile=

cd %windir%

Нитка є старою літтю, але я все одно хочу поділитися своїм рішенням. Сподіваюся, що це комусь допоможе. У нас була схожа проблема і хотіли додати сертифікати з магазину Windows у firefox. Тому я створив сценарій для цього. У будь-якому випадку, ви можете змінити це відповідно до своїх потреб: Просто додайте або видаліть рядки за адресою :: create cfg_file_name.cfg [...] та вставте те, що вам потрібно, наприклад, для запуску домашньої сторінки тощо. Не забудьте встановити ^ перед останнім), інакше це не вийде! echo pref("browser.startup.homepage", "http://superuser.com"^);

З версії 49 ви можете це зробити так:

@echo off
setlocal enabledelayedexpansion
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: MAIN INFORMATION
:: Title: Change about:config entries in Mozilla Firefox
:: Author: I-GaLaXy-I
:: Version: 1.1
:: Last Modified: 10.01.2018
:: Last Modified by: I-GaLaXy-I
::------------------------------------------------------------------------------
:: This script will add two files, which will change about:config parameters of
:: Mozilla Firefox. You can change the name of these two files and remove or add
:: parameters according to your needs. Renaming the files could be essential, if
:: a user creates own files and you don't want to overwrite them.
:: 
:: If the two files already exist and the script is run, the complete content
:: of both files will be overwritten!
::
:: Note: You may have to run it with administrative privileges!
::
:: More information: https://developer.mozilla.org/en-US/Firefox/Enterprise_deployment
:: http://kb.mozillazine.org/Locking_preferences
::------------------------------------------------------------------------------
:: Subtitle: Import CAs from Windows certificate store
:: More information: https://serverfault.com/questions/722563/how-to-make-firefox-trust-system-ca-certificates
::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

:: Set the name of the .cfg file
set cfg_file_name=add_win_certstore_cas

:: Set the name of the .js file
set js_file_name=add_win_certstore_cas

:: Registry keys to check for the installation path of Mozilla Firefox
set regkey1="HKEY_LOCAL_MACHINE\SOFTWARE\MICROSOFT\Windows\CurrentVersion\App Paths\firefox.exe" /v "Path"
set regkey2="HKEY_LOCAL_MACHINE\SOFTWARE\Clients\StartMenuInternet\FIREFOX.EXE\shell\open\command" /ve

:: Get installation path of Mozilla Firefox (if not found exit script):
reg query %regkey1%
if %errorlevel%==0 (
    :: First key found, getting path
    for /f "tokens=2* delims=    " %%a in ('reg query %regkey1%') do set path_firefox=%%b
) else (
    :: If first key not found, try another one:
    reg query %regkey2%
    if !errorlevel!==0 (
        for /f "tokens=2* delims=    " %%a in ('reg query %regkey2%') do set path_firefox=%%b
        set path_firefox=!path_firefox:\firefox.exe=!
        for /f "useback tokens=*" %%a in ('!path_firefox!') do set path_firefox=%%~a
) else (
    :: No key found, exit script
    exit
))

:: Create cfg_file_name.cfg if it doesn't exist and input the following lines.
:: Caution! If cfg_file_name.cfg already exists, all lines will be overwritten!
:: Add more lines as needed with the following syntax: 
::echo pref("<name_of_config_entry>", <value>^);
(
    echo //Firefox Settings rolled out via KACE from Systec
    echo //Do not manually edit this file because it will be overwritten!
    echo //Import CAs that have been added to the Windows certificate store by an user or administrator.
    echo pref("security.enterprise_roots.enabled", true^);
) > "%path_firefox%\%cfg_file_name%.cfg"

:: Create js_file_name.js if it doesn't exist and input the following lines.
:: Caution! If js_file_name.js already exists, all lines will be overwritten!
(
    echo /* Firefox Settings rolled out via KACE from Systec
    echo Do not manually edit this file because it will be overwritten! */
    echo pref("general.config.obscure_value", 0^);
    echo pref("general.config.filename", "%cfg_file_name%.cfg"^);
) > "%path_firefox%\defaults\pref\%js_file_name%.js"

:: Files created, exit
exit