Як витягнути повний список типів розширень в каталозі?

Всередині каталогу та рекурсивно в його підкаталогах, тобто кожен каталог у каталозі обробляється, як я складаю повний список унікальних розширень всередині каталогу?

ОС - це Windows XP з усіма поточними оновленнями, але я добре працюю із сценарієм, якщо я можу сказати, що це робить, хоча я вважаю за краще не встановлювати dot-net, оскільки мені це дуже не подобається.

Цей пакетний сценарій це зробить.

@echo off

set target=%~1
if "%target%"=="" set target=%cd%

setlocal EnableDelayedExpansion

set LF=^


rem Previous two lines deliberately left blank for LF to work.

for /f "tokens=*" %%i in ('dir /b /s /a:-d "%target%"') do (
    set ext=%%~xi
    if "!ext!"=="" set ext=FileWithNoExtension
    echo !extlist! | find "!ext!:" > nul
    if not !ERRORLEVEL! == 0 set extlist=!extlist!!ext!:
)

echo %extlist::=!LF!%

endlocal

Збережіть його як будь-який .batфайл та запустіть його командою batchfile(замініть те, що ви його назвали), щоб перелічити поточний каталог або вказати шлях batchfile "path". Він буде шукати всі підкаталоги.

Якщо ви хочете експортувати у файл, використовуйте batchfile >filename.txt(або batchfile "path" >filename.txt).

Пояснення

Все перед for /f...рядком просто налаштовує речі: він отримує цільовий каталог для пошуку, дозволяє затримати розширення, що дозволяє мені оновлювати змінні в циклі і визначає новий рядок ( LF), який я можу використовувати для більш чіткого виводу. О, і %~1означає "отримати перший аргумент, видаляючи лапки", що перешкоджає подвоєнню лапок - див for /?.

Цикл використовує цю dir /b /s /a:-d "%target%"команду, захоплюючи список усіх файлів у всіх підкаталогах під ціллю.

%%~xiвитягує розширення з повних шляхів, що dirповертається командою.

Порожнє розширення замінено на "FileWithNoExtension", тож ви знаєте, що є такий файл - якщо я замість цього додав порожній рядок, це не так очевидно.

Весь поточний список, якщо він надсилається через findкоманду, для забезпечення унікальності. Текстовий висновок команди пошуку посилається до nul, по суті, чорної діри - ми цього не хочемо. Оскільки ми завжди додаємо а :в кінці списку, ми також повинні переконатися, що пошуковий запит закінчується :так, щоб він не відповідав частковим результатам - дивіться коментарі.

% ERRORLEVEL% встановлюється findкомандою, значення 0 вказує на відповідність. Тож якщо це не 0, поточне розширення наразі відсутнє у списку, і його слід додати.

Лінія відлуння в основному виводить, і я також замінюю свої заповнювачі ( :) новими рядками, щоб це виглядало приємно.

Хоча строго не відповідає вимозі пакетного сценарію, я використовував однорядковий сценарій оболонки:

Get-Childitem C:\MyDirectory -Recurse | WHERE { -NOT $_.PSIsContainer } | Group Extension -NoElement | Sort Count -Desc > FileExtensions.txt

Ви потенційно можете запустити його з командного рядка / пакетного файлу:

Powershell -Command "& Get-Childitem C:\MyDirectory -Recurse | WHERE { -NOT $_.PSIsContainer } | Group Extension -NoElement | Sort Count -Desc > FileExtensions.txt"

Я не претендую на це, але, звичайно, вам знадобиться встановити Powershell. У нових версіях Windows цього не обійти.

Якщо ви C:\MyDirectoryйого видалите, він виконається в поточному каталозі.

Наприкінці він створить файл FileExtensions.txt, що містить щось на зразок наступного:

+-------+------+
| Count | Name |
+-------+------+
| ----- | ---- |
| 8216  | .xml |
| 4854  | .png |
| 4378  | .dll |
| 3565  | .htm |
| ...   | ...  |
+-------+------+

Залежно від структури вашої папки, ви можете час від часу отримувати помилки, сповіщаючи про те, що у вас довгий шлях.

Get-ChildItem : The specified path, file name, or both are too long. The fully qualified file name must be less than 260 characters, and the directory name must be less than 248 characters.

Будь-які підкаталоги там також не будуть проаналізовані, але результати для всього іншого все одно покажуть.

Ось детальна відповідь за допомогою PowerShell (для Windows XP вам доведеться встановити PowerShell):

Гей, хлопцеві сценарії! Як я можу використовувати Windows PowerShell для вибору унікальних розширень файлів, що використовуються у колекції файлів?

Щоб перерахувати всі унікальні розширення від cmd під шляхом, який ви використовуєте:

Powershell -Command "Get-ChildItem . -Include *.* -Recurse | Select-Object Extension | Sort-Object -Property Extension -Unique"

Мені здалося корисним змінити

if "!ext!"=="" set ext=FileWithNoExtension

до

if "!ext!"=="" set ext=.FileWithNoExtension

і змінити

echo %extlist::=!LF!%

до

echo %extlist::=!LF!% > ext-list.txt

Згенерований файл містив (без рядкових каналів, але не важливо) .bat.pdf.skp.ai.png.jpg.tif.pcp.txt.lst.ttf.dfont.psd.indd.docx.PDF.JPG.gif.jpeg .dwg.exr.FileWithNoExtension.vrlmap.sat.bak.ctb

яку я тоді міг використати для свого проекту.