Параметри "переміщення в папку" для Outlook 2007

В Outlook 2007 зміни параметрів папки змінюються залежно від того, до якої папки ви востаннє перемістили файл.

Чи можна зафіксувати ці параметри до списку папок на мій вибір.

Швидкі кроки - це Office 2010. У Office 2007 перехід до папки на панелі інструментів Inbox надає лише останню використану папку. Однак, відкривши повідомлення, ви можете натиснути на Повідомлення, щоб відкрити стрічку, де також є Переміщення до папки, яка дає останні останні використовувані папки. Ви можете натиснути правою кнопкою миші цю стрічку "Перемістити до папки" та вибрати її до панелі інструментів швидкого доступу. Ви можете швидко отримати доступ до цього клавіатури, натиснувши клавішу Alt, а потім номер, що відповідає "Переміщення до папки" на панелі інструментів швидкого доступу.

Як його Outlook 2007, я застосував наступний макрос, щоб визначити користувацькі кнопки переміщення до кнопок папок для папок, якими я користуюся найчастіше.

' This/These macro(s) implement the procedure for different folders
Sub MoveSelectedMessagesToArchive()
    MoveSelectedMessagesToFolder ("Archive")
End Sub

' This macro does the heavy lifting, and is only called from another VBA procedure
Sub MoveSelectedMessagesToFolder(FolderName As String)

'On Error Resume Next
    Dim objFolder As Outlook.MAPIFolder, objInbox As Outlook.MAPIFolder
    Dim objNS As Outlook.NameSpace, objItem As Outlook.MailItem

    Set objNS = Application.GetNamespace("MAPI")
    Set objInbox = objNS.GetDefaultFolder(olFolderInbox)
    Set objFolder = objInbox.Folders(FolderName)

'Assume this is a mail folder

    If objFolder Is Nothing Then
        MsgBox "This folder doesn't exist!", vbOKOnly + vbExclamation, "INVALID FOLDER"
    End If

    If Application.ActiveExplorer.Selection.Count = 0 Then
        'Require that this procedure be called only when a message is selected
        Exit Sub
    End If

    If Application.ActiveExplorer.Selection(1).Class = 43 Then
    ' 43 is the literal constant for a mail item
    ' sometimes a calendar item is in the inbox, in which case there is a type
    ' conflict with the objItem variable, which is declared as a mail item.

       For Each objItem In Application.ActiveExplorer.Selection
           If objFolder.DefaultItemType = olMailItem Then
               If objItem.Class = olMail Then
                    objItem.UnRead = False
                    objItem.Move objFolder
               End If
           End If
       Next
    Else
        MsgBox ("This is not a message; it may be a calendar request")
    End If

    Set objItem = Nothing
    Set objFolder = Nothing
    Set objInbox = Nothing
    Set objNS = Nothing

End Sub

Здається, як робота для швидких кроків.