Як я можу змінити мову всіх слайдів Powerpoint відразу?

Хоча ця нитка досить стара, Microsoft не запропонувала жодного рішення, про яке я знаю. Я пропоную інший підхід для користувачів Mac: відкрийте свою презентацію в Keynote, змініть мову написання і, можливо, відредагуйте всю свою презентацію, а потім експортуйте її в PowerPoint.

Щоб легко змінити мову всієї PowerPoint, відкрийте вкладку « Вид » та виберіть « Контур» .

Тепер натисніть

• Ctrl+ Aщоб вибрати всі.
• Інструменти → Мова → Виберіть мову для встановлення.

Так само, якщо у вас все вибране, ви можете змінювати інші речі, такі як шрифти, кольори тощо. Хоча, звичайно, у багатьох випадках це краще зробити шляхом зміни головного слайда, у презентації, у якій було багато редакторів, може бути багато "жорсткого" набору форматування, який відхиляється від основного майстра і потребує перезавантаження, щоб бути послідовним. Ви також можете скинути окремі слайди до майстер-стилю, але це може призвести до переміщення заповнювачів, що може бути небажаним у деяких ситуаціях.

PowerPoint 2013

• Перегляд → Контур → виберіть усі слайди (у лівому меню) через Ctrl+ A.
• Огляд → Мова → Встановити мову підтвердження ... → Виберіть мову для налаштування.

Щодо мене - потрібен був перезапуск PowerPoint . Можливо, тому, що я також змінив мову редагування :

• Огляд → Мова → Встановлення мови перевірки ... → Налаштування мови → Виберіть Редагування мов .

Використовуючи Powerpoint 2010, я відкрив контурне меню -

Вибрав увесь текст (Ctrl + A), відкрив меню мови та встановив мою мову коректури

І це спрацювало!

Мовне меню розміщене на вкладці "Огляд" (після вкладки "Показ слайдів" і не видно на скріншоті).

Існуючі відповіді працюють на текст, який присутній у конспекті. На жаль, у моєму випадку це не охоплювало значної частини тексту, включаючи фігури, таблиці тощо.

Цей макрос вирішив проблему для мене:

 Sub ChangeProofingLanguageToEnglish()
    Dim j, k, m, scount, fcount, gcount As Integer
    scount = ActivePresentation.Slides.Count
    For j = 1 To scount
        fcount = ActivePresentation.Slides(j).Shapes.Count
        For k = 1 To fcount
            If ActivePresentation.Slides(j).Shapes(k).HasTextFrame Then
                ActivePresentation.Slides(j).Shapes(k) _
                .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
            If ActivePresentation.Slides(j).Shapes(k).Type = msoGroup Then
                gcount = ActivePresentation.Slides(j).Shapes(k).GroupItems.Count
                For m = 1 To gcount
                    If ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m).HasTextFrame Then
                    ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m) _
                    .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
                Next m
            End If
        Next k
    Next j
End Sub

"MsoLanguageIDEnglishUS", який використовується у наведеному вище макросі, можна замінити будь-якою потрібною мовою. Повний список мов можна знайти в цій статті

(Заслуга Ганеш Кумара , який розмістив оригінальний макрос тут . Я додав підтримку першого рівня форми угруповання. Для подальшого поліпшення його макрос може бути рекурсивним шукати групи , які містять інші групи і т.д.)

Я покращив відповідь Ініго, щоб надати рекурсивну версію, яка змінює всі елементи на потрібну мову.

Ця версія буде рекурсивно досліджувати кожну фігуру, що є груповим типом. Деякі експерименти припускають, що це msoGroupта msoSmartArtтипи груп - сміливо додайте до цього списку, якщо ви знайдете інші типи фігур, які можуть містити текстові об’єкти.

Sub ChangeProofingLanguageToEnglish()
    Dim j As Long, k As Long
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Long

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

На основі відповідей Ініго, Дункана, Марії та ДомДева це працює для форм, таблиць, груп, SmartArt, зараз і в майбутньому:

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

Версія Duncan працює добре для всього, крім таблиць. Я знайшов ще один код, який, здається, також працює з таблицями: https://stackoverflow.com/questions/4735765/powerpoint-2007-set-language-on-tables-charts-etc-that-contains-text

Public Sub changeLanguage()
    On Error Resume Next
    Dim gi As GroupShapes '<-this was added. used below
    'lang = "English"
    lang = "Norwegian"
    'Determine language selected
    If lang = "English" Then
        lang = msoLanguageIDEnglishUK
    ElseIf lang = "Norwegian" Then
        lang = msoLanguageIDNorwegianBokmol
    End If
    'Set default language in application
    ActivePresentation.DefaultLanguageID = lang

    'Set language in each textbox in each slide
    For Each oSlide In ActivePresentation.Slides
        Dim oShape As Shape
        For Each oShape In oSlide.Shapes
            'Check first if it is a table
            If oShape.HasTable Then
                For r = 1 To oShape.Table.Rows.Count
                    For c = 1 To oShape.Table.Columns.Count
                    oShape.Table.Cell(r, c).Shape.TextFrame.TextRange.LanguageID = lang
                    Next
                Next
            Else
                Set gi = oShape.GroupItems
                'Check if it is a group of shapes
                If Not gi Is Nothing Then
                    If oShape.GroupItems.Count > 0 Then
                        For i = 0 To oShape.GroupItems.Count - 1
                            oShape.GroupItems(i).TextFrame.TextRange.LanguageID = lang
                        Next
                    End If
                'it's none of the above, it's just a simple shape, change the language ID
                Else
                    oShape.TextFrame.TextRange.LanguageID = lang
                End If
            End If
        Next
    Next End Sub

Окрім відповіді, наданої Mastergalen, та звернення до коментарів щодо тексту, щойно введений :

Якщо ви помітите, що мова автоматично змінюватиметься щоразу, коли ви почнете вводити новий текст (що дуже дратує), вам доведеться змінити поточну мову за замовчуванням для PowerPoint:

• переконайтесь, що вікно PowerPoint є активним
• у Windows Taskbar(так, насправді немає у PowerPoint), перевірте, чи Language barвидно,
  • якщо не піти Control Panel > Region and Language > Keyboards and Languages. Клацніть Change keybords..., перейдіть на Language barвкладку і перевірте Docked in the taskbarпараметр. (це від Win7, тому в інших версіях це може бути дещо іншим).
• тепер ключова дія - Language barна панелі завдань натисніть код мови та перейдіть до EN (якщо ви зараз бажаєте використовувати англійську мову в PowerPoint). Відтепер увесь новий текст у PowerPoint буде обраною мовою :-)
• якщо ви хочете писати мовою оригіналу, просто змініть його назад.

Я зробив надбудову ще в 2014 році для себе, яка все ще працює в PowerPoint 2016. https://github.com/wobba/officeaddin/releases/tag/v1.0.1

Він сканує використані мови та дозволяє змінити все відразу, перекинувшись.