Комбінації клавіш у неанглійській версії Microsoft Office

У мене велика проблема з португальською версією MS Office 2007 і 2010.

Змінено стандартні ярлики, які використовуються будь-якими загальними програмами.
Деякі ярлики, які не працюють: Ctrl+ s(зберегти), Ctrl+ f(знайти) і Ctrl+ a(виділити все).

Я хочу налаштувати його для використання ярликів англійської версії.

Існує опція, яка дозволяє окремо налаштовувати кожен ярлик. Крім того, я повинен налаштувати для кожного додатка, якщо я налаштувати в Word, мені доведеться налаштувати знову для Excel.

Як використовувати ярлики англійської версії MS Office незалежно від мови Office?

Дякую

Я майже впевнений, що немає вбудованого способу зміни клавіш у програмах MS Office.

Однак для цього можна скористатися функцією AutoHotkey .

Сценарій

^a::
^f::
^s::
    WinGet, Process, ProcessName, A
    if(RegExMatch(Process, "^(WINWORD|EXCEL)\.EXE$"))
    {
       if(A_ThisHotKey = "^a")
           SendPlay, ^e
       if(A_ThisHotKey = "^f")
           SendPlay, ^b
       if(A_ThisHotKey = "^s")
           SendPlay, ^g
    }
    else
        SendPlay, %A_ThisHotKey%
return

Як це працює

• ^a::, вказує одну з гарячих клавіш, які запускають скрипт перед returnоператором, де ^вказує Ctrlключ.

• WinGet, Process, ProcessName, Aзберігає ім'я процесу активного ( A) вікна в змінну Process.

• if(RegExMatch(Process, "^(WINWORD|EXCEL)\.EXE$")) {...} else ...перевіряє, чи Process відповідає регулярний вираз , тобто якщо він відповідає одному з рядків WINWORD.EXEабо EXCEL.EXE.

  • Якщо так, то перший блок виконується.

    • if(A_ThisHotKey = "^a")перевіряє, чи натиснута гаряча клавіша Ctrl+ A.

      Якщо це так, він імітує клавішу Ctrl+ E, що є португальською гарячою клавішею для вибору всіх ¹ .

  • В іншому випадку, SendPlay, %A_ThisHotKey%імітує комбінацію клавіш, яка спочатку була натиснута.

    Таким чином, інші програми все ще поводяться так, як повинні.

Як використовувати

1. Завантажте та встановіть останню версію AutoHotkey.

2. Збережіть вказаний вище сценарій ms-office.ahk, використовуючи улюблений текстовий редактор.

3. Двічі клацніть файл, щоб запустити скрипт.

4. Якщо бажаєте, скопіюйте скрипт (або посилання на нього) у Startupпапку.

5. Щоб додати додаткові програми MS Office, просто змініть регулярний вираз.

   Щоб додати PowerPoint, наприклад, замінити (WINWORD|EXCEL)на (WINWORD|EXCEL|POWERPNT).

6. Щоб додати ще гарячі клавіші, потрібно змінити дві частини сценарію.

   Щоб додати Ctrl+ O(Відкрити ...), наприклад, додайте рядок ^o::до списку на самому верху, додайте ці рядки всередині ifблоку:

   if(A_ThisHotKey = "^o")
       SendPlay, ^a
   

¹ Принаймні, я думаю, що це так. Я взяв гарячі клавіші з мого іспанського MS Office. Налаштуйте, якщо потрібно.

Виходячи з попередньої відповіді, ще кілька ярликів (можна додати до попередньої відповіді):

^a::
^f::
^s::
^w::
^n::
^u::
^d::
^r::
^b::
^i::
^k::
^g::
    WinGet, Process, ProcessName, A
    if(RegExMatch(Process, "^(EXCEL)\.EXE$"))
    {
       if(A_ThisHotKey = "^a") ;seleccionar rango
           SendPlay, ^e
       if(A_ThisHotKey = "^f") ;buscar
           SendPlay, ^b
       if(A_ThisHotKey = "^s") ;guardar
           SendPlay, ^g
       if(A_ThisHotKey = "^w") ;cerrar
           SendPlay, ^r
       if(A_ThisHotKey = "^n") ;nuevo libro
           SendPlay, ^u
       if(A_ThisHotKey = "^u") ;subrayar
           SendPlay, ^s
       if(A_ThisHotKey = "^b") ;negrita
           SendPlay, ^n
       if(A_ThisHotKey = "^i") ;cursiva
           SendPlay, ^k
       if(A_ThisHotKey = "^d") ;filldown
           SendPlay, ^j
       if(A_ThisHotKey = "^r") ;fill right
           SendPlay, ^d
       if(A_ThisHotKey = "^k") ;hyperlink
           SendPlay, ^!k
       if(A_ThisHotKey = "^g") ;goto
           SendPlay, ^i
    }
    else
        SendPlay, %A_ThisHotKey%
return