Ярлик або макрос для зміни типу шрифту в Microsoft Outlook

Чи є комбінація клавіш для зміни шрифту в Outlook в Windows? Мені доводиться постійно чергувати Calibri з Courier з технічних причин і натискання діалогового вікна шрифту кожного разу стає дуже стомлюючим. Я знаю, що я можу використовувати Ctrl + Space, щоб змінити будь-який шрифт за замовчуванням (Calibri).

Якщо ярлика немає, може хтось допомогти мені створити макрос для перемикання шрифтів? Я думаю, я можу призначити будь-який ярлик макросу?

(Відповідь techie007 не працювала для мене в Outlook 2010)

Цей макрос (адаптований з http://www.slipstick.com/developer/word-macro-apply-formatting-outlook-email/ ) виконує:

Sub SetCodeFont()
    Dim objItem As Object
    Dim objInsp As Outlook.Inspector

    Dim objWord As Word.Application
    Dim objDoc As Word.Document
    Dim objSel As Word.Selection
    On Error Resume Next

    Set objItem = Application.ActiveInspector.CurrentItem
    If Not objItem Is Nothing Then
        If objItem.Class = olMail Then
            Set objInsp = objItem.GetInspector
            If objInsp.EditorType = olEditorWord Then
                Set objDoc = objInsp.WordEditor
                Set objWord = objDoc.Application
                Set objSel = objWord.Selection
                objSel.Font.Name = "Consolas"
            End If
        End If
    End If

    Set objItem = Nothing
    Set objWord = Nothing
    Set objSel = Nothing
    Set objInsp = Nothing
End Sub

Далі в редакторі VBA перейдіть до Tools > Referencesта виберіть Microsoft Word 14.0 Object Library.

Тепер, щоб створити ярлик клавіатури для макросу, додайте його на панель інструментів швидкого доступу таким чином:

1. Відкрийте нове поштове повідомлення
2. Клацніть на невелику стрілку вниз на панелі інструментів швидкого доступу (зазвичай розташовується у верхній частині вікна) та виберіть "Додаткові команди ..."

3. Відкриється діалогове вікно параметрів Outlook, після чого виберіть "Макроси" зі спадного меню "Вибрати команди з:"

4. Виберіть зі списку макрос SetCodeFont і натисніть "Додати >>"
5. Тепер кнопка макроса з’явиться на панелі інструментів швидкого доступу

Щоб запустити макрос, виділіть деякий текст у своєму електронному листі та натисніть, Alt + <Num>де <Num>знаходиться макрос на панелі інструментів швидкого доступу. Наприклад, якщо макрос є першою кнопкою на панелі інструментів, використовуйте, Alt + 1щоб викликати його.

Просто FYI, це послідовність клавіш , щоб сфокусувати селектор шрифту: Alt, H, F,F