Як можна "розділити" файл Excel (.xlsx), який містить кілька аркушів, на окремий аркуш [n] .xlsx?

Я думаю, що в заголовку сказано все, що стосується цього питання, але трохи докладніше:

У мене є .xlsx файл, який містить кілька десятків аркушів. Я хочу вивести всі ці аркуші як окремі .xlsx файли. Автоматичне називання їх не потрібно. Чи має excel функція експорту листів в окремий файл?

Це не вбудована функція.

Однак якщо запустити цей код, він повинен виконати роботу.

Sub SaveSheets()
    Dim strPath As String
    Dim ws As Worksheet

    Application.ScreenUpdating = False

    strPath = ActiveWorkbook.Path & "\"
    For Each ws In ThisWorkbook.Sheets
        ws.Copy
        'Use this line if you want to break any links:
        BreakLinks Workbooks(Workbooks.Count)
        Workbooks(Workbooks.Count).Close True, strPath & ws.Name & ".xlsx"
    Next

    Application.ScreenUpdating = True
End Sub

Sub BreakLinks(wb As Workbook)
    Dim lnk As Variant
    For Each lnk In wb.LinkSources(xlExcelLinks)
        wb.BreakLink lnk, xlLinkTypeExcelLinks
    Next
End Sub

Щоб запустити код, виконайте наступне:

1. Відкрити редактор VBA ( Alt+ F11)
2. У дереві у верхньому лівому куті правою кнопкою миші клацніть на робочій книжці та вставте новий модуль
3. Скопіюйте вищевказаний код у цей модуль
4. Закрийте редактор VBA
5. У Excel натисніть Alt+, F8щоб запустити макроси та виберітьSaveSheets

або див. Як додати VBA у MS Office?

1. Клацнувши правою кнопкою миші на вкладці аркуша Excel, ви можете вибрати Перемістити або Скопіювати ...

   

2. У діалоговому вікні, що виходить, можна вибрати цільову робочу книжку. Виберіть (нова книга) .

   

3. Натисніть кнопку ОК . Ваш аркуш знаходиться всередині нового документа.

Я спробував рішення Пітера Альберта, і це не спрацювало для мене, тому я знайшов рішення в цій публікації ("Excel - збережіть робочі аркуші як окремі файли") в Щоденнику комп'ютерного видовища .

Це чудово працює. Вам слід перейменувати аркуші, що містять крапки, щоб отримати правильно названі файли з .xlsрозширеннями.

Sub CreateNewWBS()
Dim wbThis As Workbook
Dim wbNew As Workbook
Dim ws As Worksheet
Dim strFilename As String

    Set wbThis = ThisWorkbook
    For Each ws In wbThis.Worksheets
        strFilename = wbThis.Path & "/" & ws.Name
        ws.Copy
        Set wbNew = ActiveWorkbook
        wbNew.SaveAs strFilename
        wbNew.Close
    Next ws
End Sub

Використовуйте інструкції, щоб створити та запустити цей макрос з поста Пітера Альберта або з розділу Як додати VBA в MS Office?