Чи існує спосіб перегляду нагадуючих нагадувань у Outlook2010?

Чи можливо в Outlook 2010 скласти список предметів, які наразі відкладені? Наприклад, скажімо, що за два тижні я встановив нагадування, щоби з'явитися у п’ятницю на важливу зустріч по обіду наступного понеділка (мені подобається нагадати про завдання в понеділок перед вихідними). Коли нагадування спливе в п’ятницю, я відкладаю його протягом трьох днів, щоб воно знову вискочило прямо перед обідом у понеділок. Потім понеділок котиться навколо, і моя пам’ять нечітка, і я трохи параноїчний, що випадково відхилив нагадування в п’ятницю, а не правильно відклавши його. Я все ще бачу оригінальну зустріч у своєму календарі, але мені потрібно переконатися, що в мене дійсно з’явиться нагадування, коли я очікую цього, щоб я не пропустив свою зустріч.

Чи можливо в Outlook 2010 скласти список нагадувань, які наразі відкладено? Це також було б корисно для тих випадків, коли я виконую завдання, нагадування якого я відклав до пізніше, і тепер я хочу витягнути відкладене нагадування і скасувати його.

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

Якщо ви не знайомі з VBA, перегляньте сторінку пояснень Slipstick . Ви знайдете інформацію про:

• параметри безпеки макросу;
• куди поставити код (Ви можете використовувати звичайний модуль із Insert | Module); і
• як створити кнопку.

Відповідно до цього пункту "Перегляд відкладених елементів" на форумі, неможливо побачити список відкладених елементів. У публікації випливає, що ви можете побачити обмежену кількість корисної інформації, створивши спеціальний перегляд, який відображає деякі поля нагадування.

Спробуйте перейти на вкладку Календар, виберіть Переглянути та змінити перегляд. Потім виберіть Список. На екрані відображається список усіх нагадувань.