Перетворення DWG / DXF в CSV або Excel

Я використовую ZWcad, і мені потрібно отримати координати сотень блоків в аркуші Excel або .CSV-файлі, щоб я міг імпортувати це в апаратне забезпечення GPS. Я знаю, що є багато інструментів для автокади, я, мабуть, навіть можу написати сам, але, наскільки ZWcad йде, я, здається, не в змозі.

Однак ZWcad також економить на DWG та експортує на всі інші знайомі розширення CAD. Тож мені було цікаво, чи я просто збережу блоки, які мені потрібно експортувати до певного файлу, можливо, буде інструмент / програма для перетворення цього безпосередньо у .CSV.

Нижче представлена ​​проста програма AutoLISP, яка демонструє, як витягнути координати точки вставки WCS для вибору посилань блоку на CSV-файл, розміщений комами.

(defun c:blk2csv ( / e f i p s )
    (if (and (setq s (ssget '((0 . "INSERT"))))
             (setq f (getfiled "" "" "csv" 1))
             (setq f (open f "w"))
        )
        (progn
            (repeat (setq i (sslength s))
                (setq i (1- i)
                      e (ssname s i)
                      p (trans (cdr (assoc 10 (entget e))) e 0)
                )
                (write-line (apply 'strcat (mapcar 'strcat (mapcar 'rtos p) '("," "," ""))) f)
            )
            (close f)
        )
    )
    (princ)
)