Послідовний номер в Excel у визначеному діапазоні

Я шукав макрос з минулого тижня, але не пощастило поки. Якщо ви прохання вивести мене з проблеми, з якою я зіткнувся, Я створив шаблон Excel (використовував його для кодування списку).

Я шукаю те, що:

У колонці B ми повинні помістити серійні номери (послідовні номери) в активній клітині на основі значення, зазначеного в двох клітинках (A1 = початок серійного від: 5) & amp; (A2 = Кінець серійного номера: 25) Те, що мені потрібно, знаходиться в колонці B, де активована клітина, а діапазон початку і кінця забезпечується мною (користувачем), і я натискаю кнопку макросу, що генерує серійний номер з передбаченим початковим і кінцевим діапазоном від activecell до вниз.

Сподіваюся, що ви отримали мою думку.

Якщо я розумію, що ви хочете, цей макрос повинен працювати для вас. Він перевіряє, щоб:

• користувач вибрав клітинку у стовпці B для нової серії
• кінцеве значення для серії, введеного користувачем, більше початкового значення
• існуючі значення в стовпці B були очищені, перш ніж вставити нову серію.

Якщо будь-яка з цих умов не виконується, макрос попереджає користувача та виходить без додавання нової серії до робочого аркуша.

Sub NewSeries2()
    Dim seriesRng As Range
    Dim stepSize As Double
    Dim stopValue As Double

    If Intersect(Selection, Range("B:B")) Is Nothing Then
        MsgBox "Please select a cell in column B to start the series."
        Exit Sub
    ElseIf Range("A2").Value <= Range("A1").Value Then
        MsgBox "Ending value of the series cell A2 must be greater then the starting value in cell A1."
        Exit Sub
    ElseIf WorksheetFunction.CountA(Range("B:B")) <> 0 Then
        MsgBox "Please delete the existing values in column B."
        Exit Sub
    Else
        stepSize = 1
        stopValue = Range("A2").Value
        Selection.Value = Range("A1").Value
        Selection.DataSeries Rowcol:=xlColumns, Type:=xlLinear, Date:=xlDay, _
            Step:=stepSize, Stop:=stopValue, Trend:=False
    End If
End Sub