Розділити текст на стовпці в Excel

У мене є електронна таблиця Excel з рядками даних, як показано нижче. Існує код з назвою продукту і потім номером.

QA32 Product One (Large) 23
AZ63 Product Two 96
PR65 Product Three 149

Як розділити кожне поле на стовпець?

Я спробував "розділити текст на стовпці" на excel, використовуючи розділений варіант і розділяючи пробіли, але той факт, що деякі назви продуктів мали більше, ніж одне слово викликало деякі числа в неправильній колонці. Наприклад,

Code     Name       Number       
QA32    Product      One       (Large)    23
AZ63    Product      Two         96
PR65    Product      Three       149

Це бажаний результат:

Code        Name                Number
QA32    Product One (Large)       23
AZ63    Product Two               96
PR65    Product Three             149

Допомога оцінена!

Використовуйте FIND-function для визначення положення вашого першого і останнього простору. Після цього використовуйте MID-function розділити дані на три частини. Якщо ви знаєте положення вашого простору, розщеплення легко. Знаходження першого простору також тривіально FIND йде зліва направо. На жаль, не можна сказати Excel, що шукатиметься справа наліво.

Отже, важка частина - визначити останній простір! Тут ми використовуємо формулу масиву.
Щоб ввести формулу масиву, вставте формулу в клітинку і не натискаєте Enter .
Замість цього натисніть Ctrl + Shift + Enter .

{=MAX((MID(A2,ROW(A:A),1)=" ")*ROW(A:A))}

Якщо виконано успішно, Excel додасть початкову та кінцеву фігурні дужки.

Вставте всі формули у вказані комірки та використовуйте їх autofill down

A2: Ваші дані надходять тут
B2: =FIND(" ",A2,1)
C2: =MAX((MID(A2,ROW(A:A),1)=" ")*ROW(A:A)) & lt; -магнітна формула!
D2: =MID(A2,1,B2-1)
E2: =MID(A2,B2+1,C2-B2-1)
F2: =MID(A2,C2+1,LEN(A2))

_{Екран результатів}

Якщо підходить відповідний алгоритм:

• Код = Перше слово
• Product = Все між першим і останнім словом
• Число = останнє слово

Потім повинні працювати наступні формули.

Припустимо, що ваші дані в A1:

Code:     =LEFT(TRIM(A1),FIND(" ",TRIM(A1))-1)
Product:  =TRIM(MID(SUBSTITUTE(TRIM(A1)," ",REPT(" ",99)),100,LEN(SUBSTITUTE(TRIM(A1)," ",REPT(" ",99)))-198))
Number:   =TRIM(RIGHT(SUBSTITUTE(TRIM(A1)," ",REPT(" ",99)),99))