Чи існує формула Excel для ідентифікації спеціальних символів у комірці?

У нас є близько 3500 документів, назви файлів яких потрібно вручну очистити, щоб видалити спеціальні символи, такі як дужки, колонки, крапки з комою, коми тощо.

У мене є текстовий файл, який я скинув у excel, і я намагаюся створити стовпець, який позначає ім'я файлу для модифікації, якщо він містить спеціальні символи. Формула псевдокоду була б

=IF (cellname contains [^a-zA-z_-0-9], then "1", else "0")

позначити рядок, якщо він містить будь-які символи, крім AZ, 0-9, - або _, незалежно від регістру.

Хтось знає про щось, що може працювати для мене? Я вагаюся з кодуванням та масовими ifзаявами, якщо є щось швидке та легке.

Немає коду? Але це так коротко, легко і красиво і ... :(

Ваш шаблон RegEx [^A-Za-z0-9_-]використовується для видалення всіх спеціальних символів з усіх комірок.

Sub RegExReplace()

    Dim RegEx As Object
    Set RegEx = CreateObject("VBScript.RegExp")
    RegEx.Global = True

    RegEx.Pattern = "[^A-Za-z0-9_-]"
    For Each objCell In ActiveSheet.UsedRange.Cells
        objCell.Value = RegEx.Replace(objCell.Value, "")
    Next

End Sub

Редагувати

Це так близько, як я можу підійти до вашого оригінального питання.

Другий код - визначена користувачем функція =RegExCheck(A1,"[^A-Za-z0-9_-]")з 2 аргументами. Перший - це клітинка для перевірки. Другий - це шаблон RegEx для перевірки. Якщо шаблон відповідає будь-якому з символів у вашій комірці, він поверне 1, інакше 0.

Ви можете використовувати його, як і будь-яку іншу звичайну формулу Excel, якщо спочатку відкриєте редактор VBA за допомогою ALT+ F11, вставите новий модуль (!) Та вставте код нижче.

Function RegExCheck(objCell As Range, strPattern As String)

    Dim RegEx As Object
    Set RegEx = CreateObject("VBScript.RegExp")
    RegEx.Global = True
    RegEx.Pattern = strPattern

    If RegEx.Replace(objCell.Value, "") = objCell.Value Then
        RegExCheck = 0
    Else
        RegExCheck = 1
    End If

End Function

Для нових користувачів RegEx я поясню ваш шаблон: [^A-Za-z0-9_-]

[] stands for a group of expressions
^ is a logical NOT
[^ ] Combine them to get a group of signs which should not be included
A-Z matches every character from A to Z (upper case)
a-z matches every character from a to z (lower case)
0-9 matches every digit
_ matches a _
- matches a - (This sign breaks your pattern if it's at the wrong position)

Використовуючи щось подібне до коду nixda, ось визначена користувачем функція, яка поверне 1, якщо комірка має спеціальні символи.

Public Function IsSpecial(s As String) As Long
    Dim L As Long, LL As Long
    Dim sCh As String
    IsSpecial = 0
    For L = 1 To Len(s)
        sCh = Mid(s, L, 1)
        If sCh Like "[0-9a-zA-Z]" Or sCh = "_" Then
        Else
            IsSpecial = 1
            Exit Function
        End If
    Next L
End Function

Функції, визначені користувачем (UDF), дуже прості в установці та використанні:

1. ALT-F11 відкриває вікно VBE
2. ALT-I ALT-M відкриває новий модуль
3. вставити матеріал і закрити вікно VBE

Якщо ви збережете робочу книжку, UDF буде збережено разом з нею. Якщо ви використовуєте версію Excel пізніше 2003 року, ви повинні зберегти файл як .xlsm, а не .xlsx

Щоб видалити UDF:

1. піднести вікно VBE, як вище
2. очистити код
3. закрити вікно VBE

Щоб використовувати UDF від Excel:

= Спеціальний (A1)

Щоб дізнатися більше про макроси в цілому, див:

http://www.mvps.org/dmcritchie/excel/getstarted.htm

і

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

і

http://www.cpearson.com/excel/WritingFunctionsInVBA.aspx

для конкретики щодо АДС

Макроси повинні бути включені, щоб це працювало !

Ось умовне рішення форматування, яке позначить записи спеціальними символами.

Просто застосуйте нове правило умовного форматування до своїх даних, яке використовує (надзвичайно довгу) формулу нижче, де A1є перший запис у стовпці імен файлів:

=SUMPRODUCT((CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))<48)*(CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))<>45))+SUMPRODUCT((CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))>57)*(CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))<65))+SUMPRODUCT((CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))>90)*(CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))<97)*(CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))<>95))+SUMPRODUCT((CODE(MID(A1,ROW(INDIRECT("1:"&LEN(A1))),1))>122)*1)

Ця формула перевіряє кожен символ кожного імені файлу і визначає, чи знаходиться його код ASCII поза допустимими значеннями символів. На жаль, допустимі коди символів не всі суміжні, тому для формули доводиться використовувати суми SUMPRODUCTs. Формула повертає кількість там поганих символів. Будь-які комірки, які повертають значення більше 0, позначені прапором.

Приклад:

Я використовував інший підхід для пошуку спеціальних персонажів. Я створив нові стовпці для кожного з дозволених символів, а потім використав формулу на зразок цієї, щоб підрахувати, скільки разів цей дозволений символ був у кожному рядку (Z2):

AA2=LEN($Z2)-LEN(SUBSTITUTE($Z2,AA$1,""))
AB2=LEN($Z2)-LEN(SUBSTITUTE($Z2,AB$1,""))
...

Потім я підсумував кількість дозволених символів у кожному рядку, а потім порівняв її із загальною довжиною запису рядка.

BE2=LEN(Z2)
BF2=SUM(AA2:BC2)-BE2

І нарешті, я відсортував останній стовпчик (BF2), щоб знайти негативні значення, що призвело мене до стовпців, які потребували корекції.