Скажімо, на D:диску є якась папка :

D:\Air
D:\Abonden
D:\All
D:\Whatever

Я хочу видалити всі папки, починаючи з "A" (включаючи всі папки та файли). Я спробував цю команду:

rmdir D:\A* /s /q

Однак я отримую помилку :(

Ім'я файлу, ім'я каталогу або синтаксис мітки тома неправильно.

delКоманда працює з *, але мені потрібно видаляти папки , а також.
Чи є спосіб досягти цього за допомогою rmdirкоманди?

cd c:\temp
for /f %i in ('dir /a:d /s /b A*') do rd /s /q %i

Використовуйте це для тестування:

for /f %i in ('dir /a:d /s /b A*') do echo rd /s /q %i

Це видасть команди, які потрібно запустити в командний рядок, і дозволить вам побачити, що відбувається.

Майте на увазі, що це також буде шукати підпапки, такі як "C: \ temp \ jjj \ aaa", і видалить папку aaa. Якщо ви хочете, щоб він просто подивився на папки верхнього рівня "C: \ temp \ aaa", тоді видаліть "/s"команду.

Ключовим фактором цього є A *, де ви б помістили рядок пошуку. Це дозволить приймати символи, такі як aaa*, aaa*і *aaa*якщо ви цього хочете.

Видалення папок за допомогою підстановок

Сама команда rmdir/ rdне підтримує символи підстановки (тобто *і ?). Ви можете подолати це обмеження, загорнувши його в forпетлю.

Приклад використання

for /d %G in ("X:\A*") do rd /s /q "%~G"

Примітка. Коли ви видаляєте файли та папки, ви, можливо, захочете замінити rdкоманду echoпершою. Таким чином ви можете забезпечити все, що насправді не слід видаляти.

Кілька візерунків

Для того, щоб видалити кілька папок, що відповідають різним шаблонам, синтаксис не надто відрізняється. Як правильно вказав @dbenham, достатньо однорядкової команди. Ви також можете вказати різні шляхи:

for /d %G in ("X:\A*","Y:\Whatever\B*","Z:\C?D") do rd /s /q "%~G"

Бонус - перевірка наявності папки

Якщо ви хочете перевірити, чи існують конкретні папки, ви можете скористатися такою командою:

dir /b /a:d "X:\A*" >nul 2>&1 && echo Folders exist. || echo No folders found.

Подальше читання

• for / d - прокручування каталогу
• Умовне виконання
• Довідник командного рядка

Як ще ніхто не розповів ОП про форфіли ?!

forfiles /P D:\ /M A* /C "cmd /c if @isdir==TRUE rmdir /s /q @file"

/ P - ім'я шляху - звідки починається пошук
/ M - це маска пошуку, шукає файли, які починаються з A
/ C - команда для виконання
/ S - рекурсивні вкладені папки (тут не вказано, тому що оп не запитував)

відповідь adn31415 правильна, але вона порушується, якщо ви помістите це в пакетний або cmd-скрипт. Я стукав головою годинами, поки не зрозумів, що ти цим користуєшся.

У вікні команд DOS:

for /d %G in ("X:\A*") do rd /s /q "%~G"

У пакетному або cmd-скрипті:

for /d %%G in ("X:\A*") do rd /s /q "%%~G"

Якщо ви хочете помістити його у файл ".bat" або ".cmd", вам потрібно подвоїти символи "%".