Як використовувати сортування в команді awk print?

У мене є кілька команд у awk-скрипті, про який я пишу:

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2}

Які виходи:

Here are some players and their numbers, sorted by last name
Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55

Як я можу використовувати sortкоманду в моєму скрипті awk, щоб сортувати лише гравців та їх кількість?

ви можете додати | sort -k2до своєї команди. Це буде сортувати за алфавітом на основі другого стовпця.

Приклад:

$ echo "Lebron James 23
Kevin Durant 35
Kobe Bryant 24
Blake Griffin 32
Dikembe Mutumbo 55" | sort -k2

призводить до

Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

Хоча я б не рекомендував це (зважаючи на відносну простоту передачі результату за допомогою зовнішньої sortкоманди), ви можете це зробити принаймні з останніми версіями GNU awk (принаймні 4,0 IIRC), як описано в сортуванні значень масиву та індексів з gawk

Ось як ви могли це реалізувати, якщо припустити, що у вас є дані в асоціативному масиві, в якому знаходиться індекс Firstname Lastname. Спочатку потрібно визначити функцію порівняння, яка розбиває індекс, порівнює спочатку Lastnameпотім (як вимикач краватки), Firstnameнаприклад

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

Тепер ви можете використовувати PROCINFO["sorted_in"]метод сортування масиву, згаданий у коментарях @zwets

PROCINFO["sorted_in"] = "mycmp";
for(i in a) print i, a[i];

Збираючи його разом

#!/usr/bin/gawk -f

function mycmp(ia, va, ib, vb, sa, sb) {
  if(split(toupper(ia), sa) && split(toupper(ib), sb)) {
    if(sa[2] < sb[2]) return -1;
    else if (sa[2] > sb[2]) return 1;
    else {
      # compare first names
      if(sa[1] < sb[1]) return -1;
      else if (sa[1] > sb[1]) return 1;
      else return 0;
    }
  }
  else return 0;
}

{
  a[$1" "$2] = $3;
}

END {
  PROCINFO["sorted_in"] = "mycmp";
  for(i in a) print i, a[i];
}

Тестування:

$ ./namesort.awk yourfile
Kobe Bryant 24
Kevin Durant 35
Blake Griffin 32
Lebron James 23
Dikembe Mutumbo 55

У менших або старих версіях awk найкраще може зберігати дані, проіндексовані Lastname Firstnameнатомість, сортувати зі звичайним asorti, потім розділяти та міняти поля індексів під час проходження масиву для його друку:

awk '
  {a[$2" "$1]=$3} 
  END {
    n=asorti(a,b); for (i=1;i<=n;i++) {split(b[i],s); print s[2], s[1], a[b[i]]}
}' yourfile

Щоб sortлише друге поле, відокремлене пробілом, використовуйте клавішу -k2,2:

... | sort -k2,2

за замовчуванням sortсортування проводиться лексикографічно.

Зауважте, що якщо ви не згадаєте останнє поле для клавіші сортування, тобто якщо ви просто використовуєте, -k2можливо, ви не отримаєте бажаного результату, оскільки це буде sortвідповідно до всіх полів, починаючи з секунди.

Також перевірте man sort.

Спробуйте

awk -f myscript.awk | sort -k2

Де myscript.awk містить чисто awk команди.

Якщо ваш фактичний сценарій - це сценарій оболонки, у вас є кілька варіантів, включаючи

• Вихід труби через сортування. ./myscript.bash | sort -k2

• Перезапишіть код як функцію всередині сценарію
  Замість

  $ cat t1
  #!/bin/bash
  for i in 2 4 3 1 5;
  do
    echo $i
  done
  
  $ ./t1
  2
  4
  3
  1
  5
  

  Зробіть

  $ cat t2
  #!/bin/bash
  function foo {
    for i in 2 4 3 1 5;
    do
      echo $i
    done
  }
  foo | sort
  
  $ ./t2
  1
  2
  3
  4
  5
  

Але зауважте, ви також можете застосувати сортування до do ... done структури, а не для функції.

    do
       echo $i
    done | sort

Щоб сортувати ваші дані для друку:

• Припустимо, ви хочете надрукувати друге поле (пробіл розділений), використовуйте це:

  awk '{print $2}' data.txt | sort
  

  наприклад:

  $cat>data.txt
  1 Kedar 20
  2 Amit 30
  3 Rahul 21
  ^C
  
  $awk '{print $2}' | sort
  Amit
  Kedar
  Rahul
  

• Якщо ви хочете роздрукувати всю свою, data.txtале відсортовану в стовпці 2, то:

  $awk '{print}'|sort -k2
  2 Amit 30
  1 Kedar 20
  3 Rahul 21
  

Використовуйте цю логіку (і) у своїх вимогах.

Ви можете використовувати man sortдля більш цікавих функцій sort.

про що нижче:

 awk 'BEGIN{str="1\n2\n3\n4"; system("echo -e \""str"\" | sort -r")}'

він працює, коли я перевірений.

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2"}

Щоб сортувати вихід у файл:

print "Here are some players and their numbers, sorted by last name"
if(sum[x] > 500) {print x, $2 | "sort -k2,2 > sortedFile"}