завершення вкладки zsh на порожньому рядку

Мені б хотілося, що я не зміг знайти: в порожньому рядку без вмісту я хочу натиснути клавішу вкладки і побачити еквівалент ls. Тобто я хочу, щоб я хотів

$ <tab>

робити щось інше, ніж давати мені \ t. Я знайшов фантастичні ресурси для завершення команди, але не для цього базового випадку. Будь-яка допомога щодо цього була б чудовою! Спасибі.

# expand-or-complete-or-list-files
function expand-or-complete-or-list-files() {
    if [[ $#BUFFER == 0 ]]; then
        BUFFER="ls "
        CURSOR=3
        zle list-choices
        zle backward-kill-word
    else
        zle expand-or-complete
    fi
}
zle -N expand-or-complete-or-list-files
# bind to tab
bindkey '^I' expand-or-complete-or-list-files

Поведінка Tabна початку рядка контролюється стилем . Однак існують лише дві підтримувані форми поведінки:insert-tab

• завершення, як завжди, під zstyle ':completion:*' insert-tab false
• вставити вкладку, під zstyle ':completion:*' insert-tab true
• або один, або інший під zstyle ':completion:*' insert-tab pending[=N]

Якщо ви просто хочете виконати команди в цій позиції, zstyle ':completion:*' insert-tab trueзробіть це. Якщо ви хочете щось інше, наприклад перелік файлів у поточному каталозі, вам потрібно буде змінити _main_complete.

Недавній потік в списку ЗШ-працівників обговорили insert-tab.

Ось повна реалізація авторизації tcsh в zsh, коли ви натискаєте вкладку на порожньому рядку

% <TAB>

Ось:

# list dir with TAB, when there are only spaces/no text before cursor,
# or complete words, that are before cursor only (like in tcsh)
tcsh_autolist() { if [[ -z ${LBUFFER// } ]]
    then BUFFER="ls " CURSOR=3 zle list-choices
    else zle expand-or-complete-prefix; fi }
zle -N tcsh_autolist
bindkey '^I' tcsh_autolist

Якщо ви хочете ближче наслідувати tcsh, також додайте це до свого .zshrc:

unsetopt always_last_prompt       # print completion suggestions above prompt

Я написав цей віджет zsh, який розширює використання TAB не тільки в порожньому рядку, але і під час введення команди.

• Він перелічить файли у порожньому командному рядку та посередині будь-якої команди.
• Він буде містити список каталогів у порожньому командному рядку.
• Він буде перелічити виконувані файли у порожньому командному рядку.

Він може бути налаштований на додавання "cd" або "./" у тих випадках із глобальною змінною.

export TAB_LIST_FILES_PREFIX

# List files in zsh with <TAB>
#
# Copyleft 2017 by Ignacio Nunez Hernanz <nacho _a_t_ ownyourbits _d_o_t_ com>
# GPL licensed (see end of file) * Use at your own risk!
#
# Usage:
#   In the middle of the command line:
#     (command being typed)<TAB>(resume typing)
#
#   At the beginning of the command line:
#     <SPACE><TAB>
#     <SPACE><SPACE><TAB>
#
# Notes:
#   This does not affect other completions
#   If you want 'cd ' or './' to be prepended, write in your .zshrc 'export TAB_LIST_FILES_PREFIX'
#   I recommend to complement this with push-line-or edit (bindkey '^q' push-line-or-edit)
function tab_list_files
{
  if [[ $#BUFFER == 0 ]]; then
    BUFFER="ls "
    CURSOR=3
    zle list-choices
    zle backward-kill-word
  elif [[ $BUFFER =~ ^[[:space:]][[:space:]].*$ ]]; then
    BUFFER="./"
    CURSOR=2
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER="  " CURSOR=2
  elif [[ $BUFFER =~ ^[[:space:]]*$ ]]; then
    BUFFER="cd "
    CURSOR=3
    zle list-choices
    [ -z ${TAB_LIST_FILES_PREFIX+x} ] && BUFFER=" " CURSOR=1
  else
    BUFFER_=$BUFFER
    CURSOR_=$CURSOR
    zle expand-or-complete || zle expand-or-complete || {
      BUFFER="ls "
      CURSOR=3
      zle list-choices
      BUFFER=$BUFFER_
      CURSOR=$CURSOR_
    }
  fi
}
zle -N tab_list_files
bindkey '^I' tab_list_files

# uncomment the following line to prefix 'cd ' and './' 
# when listing dirs and executables respectively
#export TAB_LIST_FILES_PREFIX

# these two lines are usually included by oh-my-zsh, but just in case
autoload -Uz compinit
compinit

# uncomment the following line to complement tab_list_files with ^q
#bindkey '^q' push-line-or-edit

# License
#
# This script is free software; you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This script is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this script; if not, write to the
# Free Software Foundation, Inc., 59 Temple Place, Suite 330,
# Boston, MA  02111-1307  USA