Примітка . Зараз я підтримую lsofобгортку, що поєднує в собі обидва описані тут підходи, а також додає інформацію для однорангових зворотних TCP-з'єднань за адресою https://github.com/stephane-chazelas/misc-scripts/blob/master/lsofc
Linux-3.3 та вище.
У Linux, так як ядра версії 3.3 (і при умови , що UNIX_DIAGфункція вбудована в ядро), рівноправний даного домену Сокет (включає в себе socketpairs) можуть бути отримані з використанням нового NETLINK API на основі.
lsof оскільки версія 4.89 може використовувати цей API:
lsof +E -aUc Xorg
Буде перераховано всі сокети домену Unix, які мають процес, ім'я якого починається з Xorgобох кінців у форматі, подібному до:
Xorg 2777 root 56u unix 0xffff8802419a7c00 0t0 34036 @/tmp/.X11-unix/X0 type=STREAM ->INO=33273 4120,xterm,3u
Якщо ваша версія lsofзанадто стара, є ще кілька варіантів.
ssУтиліта (від iproute2) використовує той же API для отримання і відображення інформації про список доменних сокетів UNIX на системі , включаючи інформацію експертною.
Розетки ідентифікуються за їх номером inode . Зауважте, що це не пов’язано з inode файлової системи файлу socket.
Наприклад у:
$ ss -x
[...]
u_str ESTAB 0 0 @/tmp/.X11-unix/X0 3435997 * 3435996
в ньому йдеться про те, що сокет 3435997 (який був прив’язаний до гнізда ABSTRACT /tmp/.X11-unix/X0) пов'язаний з сокетом 3435996. -pОпція може вказати, для яких процесів відкритий цей сокет. Він робить це, роблячи деякі readlinkS на /proc/$pid/fd/*, так що це може зробити тільки те , що на процеси , які ви володієте (якщо ви не root). Наприклад, тут:
$ sudo ss -xp
[...]
u_str ESTAB 0 0 @/tmp/.X11-unix/X0 3435997 * 3435996 users:(("Xorg",pid=3080,fd=83))
[...]
$ sudo ls -l /proc/3080/fd/23
lrwx------ 1 root root 64 Mar 12 16:34 /proc/3080/fd/83 -> socket:[3435997]
Щоб дізнатися, який процес (и) має 3435996, ви можете знайти власний запис у висновку ss -xp:
$ ss -xp | awk '$6 == 3435996'
u_str ESTAB 0 0 * 3435996 * 3435997 users:(("xterm",pid=29215,fd=3))
Ви також можете використовувати цей скрипт як обгортку, lsofщоб легко показати відповідну інформацію там:
#! /usr/bin/perl
# lsof wrapper to add peer information for unix domain socket.
# Needs Linux 3.3 or above and CONFIG_UNIX_DIAG enabled.
# retrieve peer and direction information from ss
my (%peer, %dir);
open SS, '-|', 'ss', '-nexa';
while (<SS>) {
if (/\s(\d+)\s+\*\s+(\d+) ([<-]-[->])$/) {
$peer{$1} = $2;
$dir{$1} = $3;
}
}
close SS;
# Now get info about processes tied to sockets using lsof
my (%fields, %proc);
open LSOF, '-|', 'lsof', '-nPUFpcfin';
while (<LSOF>) {
if (/(.)(.*)/) {
$fields{$1} = $2;
if ($1 eq 'n') {
$proc{$fields{i}}->{"$fields{c},$fields{p}" .
($fields{n} =~ m{^([@/].*?)( type=\w+)?$} ? ",$1" : "")} = "";
}
}
}
close LSOF;
# and finally process the lsof output
open LSOF, '-|', 'lsof', @ARGV;
while (<LSOF>) {
chomp;
if (/\sunix\s+\S+\s+\S+\s+(\d+)\s/) {
my $peer = $peer{$1};
if (defined($peer)) {
$_ .= $peer ?
" ${dir{$1}} $peer\[" . (join("|", keys%{$proc{$peer}})||"?") . "]" :
"[LISTENING]";
}
}
print "$_\n";
}
close LSOF or exit(1);
Наприклад:
$ sudo that-lsof-обгортка -ad3 -p 29215
ВИМОГА ПІДПРИЄМНИКА ПІДПРИЄМЦЯ FD ТИП ПРИЛАДУ ВИДАЛЕННЯ / ВИКЛ
xterm 29215 stephane 3u unix 0xffff8800a07da4c0 0t0 3435996 тип = STREAM <-> 3435997 [Xorg, 3080, @ / tmp / .X11-unix / X0]
До linux-3.3
Старий Linux API для отримання інформації про сокет Unix здійснюється через /proc/net/unixтекстовий файл. У ньому перераховані всі розетки домену Unix (включаючи socketpairs). Перше поле там (якщо воно не приховане для неперевірених користувачів з kernel.kptr_restrictпараметром sysctl), як уже пояснило @Totor, містить адресу ядра unix_sockструктури структури, яка містить peerполе, що вказує на відповідного однорангового unix_sock . Це також lsofвихідні дані для DEVICEстовпця на сокет Unix.
Тепер отримати значення цього peerполя означає вміти читати пам'ять ядра та знати зміщення цього peerполя стосовно unix_sockадреси.
Уже дано декілька рішень на gdbбазі та на systemtapбазі, але вони вимагають gdb/ systemtapта Linux-символів налагодження ядра для встановленого запущеного ядра, що, як правило, не відбувається у виробничих системах.
Жорстке кодування зміщення насправді не є варіантом, оскільки це залежить від версії ядра.
Тепер ми можемо використовувати евристичний підхід при визначенні зміщення: запропонуйте нашому інструменту створити манекен socketpair(тоді ми знаємо адресу обох однолітків), а також шукати адресу однорангової пам’яті на іншому кінці для визначення зміщення.
Ось сценарій із підтвердженням концепції, який робить саме це за допомогою perl(успішно протестований з ядром 2.4.27 та 2.6.32 на i386 та 3.13 та 3.16 на amd64). Як і вище, він працює як обгортка навколо lsof:
Наприклад:
$ that-lsof-wrapper -aUc nm-аплет
ВИМОГА ПІДПРИЄМНИКА ПІДПРИЄМЦЯ FD ТИП ПРИЛАДУ ВИДАЛЕННЯ / ВИКЛ
нм-аплет 4183 Stephane 4u UNIX 0xffff8800a055eb40 0t0 36888 Тип = ПОТІК -> 0xffff8800a055e7c0 [DBus-демон, 4190, @ / TMP / DBus-AiBCXOnuP6]
нм-аплет 4183 Stephane 7u UNIX 0xffff8800a055e440 0t0 36890 Тип = ПОТІК -> 0xffff8800a055e0c0 [Xorg, 3080, @ / tmp / .X11-unix / X0]
nm-applet 4183 stephane 8u unix 0xffff8800a05c1040 0t0 36201 type = STREAM -> 0xffff8800a05c13c0 [dbus-daemon, 4118, @ / tmp / dbus-yxxNr1NhaYu
11pnm 11p) UNIX 0xffff8800a055d080 0t0 36219 Тип = ПОТІК -> 0xffff8800a055d400 [DBus-демон, 4118, @ / TMP / DBus-yxxNr1NkYC]
нм-аплет 4183 Stephane 12u Unix 0xffff88022e0dfb80 0t0 36221 типу = STREAM -> 0xffff88022e0df800 [DBus-демон, 2268, / вар / run / dbus / system_bus_socket]
nm-applet 4183 stephane 13u unix 0xffff88022e0f80c0 0t0 37025 тип = STREAM -> 0xffff88022e29ec00 [dbus-daemon, 2268, / var / run / dbus / system_bus_socket]
Ось сценарій:
#! /usr/bin/perl
# wrapper around lsof to add peer information for Unix
# domain sockets. needs lsof, and superuser privileges.
# Copyright Stephane Chazelas 2015, public domain.
# example: sudo this-lsof-wrapper -aUc Xorg
use Socket;
open K, "<", "/proc/kcore" or die "open kcore: $!";
read K, $h, 8192 # should be more than enough
or die "read kcore: $!";
# parse ELF header
my ($t,$o,$n) = unpack("x4Cx[C19L!]L!x[L!C8]S", $h);
$t = $t == 1 ? "L3x4Lx12" : "Lx4QQx8Qx16"; # program header ELF32 or ELF64
my @headers = unpack("x$o($t)$n",$h);
# read data from kcore at given address (obtaining file offset from ELF
# @headers)
sub readaddr {
my @h = @headers;
my ($addr, $length) = @_;
my $offset;
while (my ($t, $o, $v, $s) = splice @h, 0, 4) {
if ($addr >= $v && $addr < $v + $s) {
$offset = $o + $addr - $v;
if ($addr + $length - $v > $s) {
$length = $s - ($addr - $v);
}
last;
}
}
return undef unless defined($offset);
seek K, $offset, 0 or die "seek kcore: $!";
my $ret;
read K, $ret, $length or die "read($length) kcore \@$offset: $!";
return $ret;
}
# create a dummy socketpair to try find the offset in the
# kernel structure
socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC)
or die "socketpair: $!";
$r = readlink("/proc/self/fd/" . fileno(Rdr)) or die "readlink Rdr: $!";
$r =~ /\[(\d+)/; $r = $1;
$w = readlink("/proc/self/fd/" . fileno(Wtr)) or die "readlink Wtr: $!";
$w =~ /\[(\d+)/; $w = $1;
# now $r and $w contain the socket inodes of both ends of the socketpair
die "Can't determine peer offset" unless $r && $w;
# get the inode->address mapping
open U, "<", "/proc/net/unix" or die "open unix: $!";
while (<U>) {
if (/^([0-9a-f]+):(?:\s+\S+){5}\s+(\d+)/) {
$addr{$2} = hex $1;
}
}
close U;
die "Can't determine peer offset" unless $addr{$r} && $addr{$w};
# read 2048 bytes starting at the address of Rdr and hope to find
# the address of Wtr referenced somewhere in there.
$around = readaddr $addr{$r}, 2048;
my $offset = 0;
my $ptr_size = length(pack("L!",0));
my $found;
for (unpack("L!*", $around)) {
if ($_ == $addr{$w}) {
$found = 1;
last;
}
$offset += $ptr_size;
}
die "Can't determine peer offset" unless $found;
my %peer;
# now retrieve peer for each socket
for my $inode (keys %addr) {
$peer{$addr{$inode}} = unpack("L!", readaddr($addr{$inode}+$offset,$ptr_size));
}
close K;
# Now get info about processes tied to sockets using lsof
my (%fields, %proc);
open LSOF, '-|', 'lsof', '-nPUFpcfdn';
while (<LSOF>) {
if (/(.)(.*)/) {
$fields{$1} = $2;
if ($1 eq 'n') {
$proc{hex($fields{d})}->{"$fields{c},$fields{p}" .
($fields{n} =~ m{^([@/].*?)( type=\w+)?$} ? ",$1" : "")} = "";
}
}
}
close LSOF;
# and finally process the lsof output
open LSOF, '-|', 'lsof', @ARGV;
while (<LSOF>) {
chomp;
for my $addr (/0x[0-9a-f]+/g) {
$addr = hex $addr;
my $peer = $peer{$addr};
if (defined($peer)) {
$_ .= $peer ?
sprintf(" -> 0x%x[", $peer) . join("|", keys%{$proc{$peer}}) . "]" :
"[LISTENING]";
last;
}
}
print "$_\n";
}
close LSOF or exit(1);