Як отримати остаточні дані архіву gzip?

У мене є gzip-архів із записом даних. Якщо я розпаковую його за допомогою gzip -dцього, він мені каже: " декомпресія в порядку, відмінне сміття ігнорується " (те саме стосується того, gzip -tякий можна використовувати як метод виявлення наявності таких даних).

Зараз я хотів би познайомитися з цим сміттям, але як не дивно, я не міг знайти жодного способу його видобути. gzip -l --verboseговорить мені, що "стиснутий" розмір архіву - це розмір файлу (тобто, з останніми даними), це неправильно і не корисно. fileтакож не допомагає, і що я можу зробити?

Тепер з’ясували, як отримати дані про те,

Я створив сценарій Perl, який створює файл із кінцевими даними, він базується на https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=604617#10 :

#!/usr/bin/perl
use strict;
use warnings; 

use IO::Uncompress::Gunzip qw(:all);
use IO::File;

unshift(@ARGV, '-') unless -t STDIN;

my $input_file_name = shift;
my $output_file_name = shift;

if (! defined $input_file_name) {
  die <<END;
Usage:

  $0 ( GZIP_FILE | - ) [OUTPUT_FILE]

  ... | $0 [OUTPUT_FILE]

Extracts the trailing data of a gzip archive.
Outputs to stdout if no OUTPUT_FILE is given.
- as input file file causes it to read from stdin.

Examples:

  $0 archive.tgz trailing.bin

  cat archive.tgz | $0

END
}

my $in = new IO::File "<$input_file_name" or die "Couldn't open gzip file.\n";
gunzip $in => "/dev/null",
  TrailingData => my $trailing;
undef $in;

if (! defined $output_file_name) {
  print $trailing;
} else {
  open(my $fh, ">", $output_file_name) or die "Couldn't open output file.\n";
  print $fh $trailing;
  close $fh;
  print "Output file written.\n";
}