Як змінити деталізацію скасування у Vim?

У якийсь момент мій Вім скасував би ціле слово, коли я вдарив u.

[i]typing some words[C-c][u]

Це призведе до

typing some

Однак, схоже, деталізація скасування змінилася на вилучення однієї літери за один раз.

[i]typing some words[C-c][u]

Призводить до

typing some word

Я пам’ятаю, що читав щось про налаштування деталізації скасування в практичному Vim, але не можу пригадати, як це контролювати. Будь-яка допомога вдячна!

Ручне порушення послідовності скасування

Ви можете вручну порушити послідовність скасування в режимі Вставка за допомогою <C-G>u. З довідки :

CTRL-G u        break undo sequence, start new change

Приклад

iHello<C-G>u world!<Esc>u

Це залишить вас із текстом

Hello

Розбивка команд

i                           " Enter Insert mode
 Hello                      " Type 'Hello'
      <C-G>u                " Break the undo sequence
             world!         " Type ' world!'
                   <Esc>    " Return to Normal mode
                        u   " Undo

Автоматичне рішення

Більш дрібнозернистий контроль рівня

Ось невеликий фрагмент VimScript, який використовується <C-G>uдля створення скасування перерв під час видалення тексту, а також при повторному введенні тексту після видалення.

function! s:start_delete(key)
    let l:result = a:key
    if !s:deleting
        let l:result = "\<C-G>u".l:result
    endif
    let s:deleting = 1
    return l:result
endfunction

function! s:check_undo_break(char)
    if s:deleting
        let s:deleting = 0
        call feedkeys("\<BS>\<C-G>u".a:char, 'n')
    endif
endfunction

augroup smartundo
    autocmd!
    autocmd InsertEnter * let s:deleting = 0
    autocmd InsertCharPre * call s:check_undo_break(v:char)
augroup END

inoremap <expr> <BS> <SID>start_delete("\<BS>")
inoremap <expr> <C-W> <SID>start_delete("\<C-W>")
inoremap <expr> <C-U> <SID>start_delete("\<C-U>")

Примітки

Це буде працювати для <BS>, <C-W>(видалити слово), і <C-U>(видалення на початку рядка). Якщо в режимі вставки є більше способів видалення, їх можна підтримати, додавши додаткові inoremapдзвінки наприкінці.