Як я можу змінити розмір шрифту в gVim?

Чи є спосіб змінити розмір шрифту в gVim, використовуючи нативні команди?

А якщо ні, то який сценарій можна використовувати для цього швидко?

Встановіть guifontпараметр у своєму .gvimrc. Дивіться :help guifontі :help setting-guifont.

Зокрема, ви можете зробити щось на кшталт: set guifont=Consolas:h11використовувати 11-точкові консолі в gvim для Windows. Є кілька інших варіантів, які ви можете використовувати (кожен розділений знаком a :), наприклад, :bдля жирних, хоча деякі з них доступні лише на певних платформах.

:hМожливість встановити розмір шрифту , як це демонструється, мабуть, найкорисніший, і один безпосередньо пов'язані зі зміною розміру шрифту, як ви просили.

Якщо ви хочете просто змінити розмір шрифту в запущеному екземплярі GVim, введіть:

:set guifont=*

З'явиться вікно, яке дозволяє встановлювати розмір шрифту, а також вибирати новий шрифт за бажанням. Потім ви можете попросити Vim надрукувати рядок, який потрібно було б додати до свого, ~/.gvimrcщоб зміни були постійними:

:set guifont?

У рядку стану створюється щось на зразок наступного:

guifont=Hasklig-Light:h16

Додамо , що з приставкою setдо ваших ~/.gvimrcупиратися.

У моєму .vimrc є таке, щоб швидко змінити розмір шрифту, не змінюючи шрифт. Працює під Windows та GTK. Я не перевіряв інших графічних інтерфейсів. Я впевнений, що спочатку скопіював його від когось іншого, але він був у моєму файлі rc так довго, що я не пам’ятаю, звідки він взявся.

if has("unix")
    function! FontSizePlus ()
      let l:gf_size_whole = matchstr(&guifont, '\( \)\@<=\d\+$')
      let l:gf_size_whole = l:gf_size_whole + 1
      let l:new_font_size = ' '.l:gf_size_whole
      let &guifont = substitute(&guifont, ' \d\+$', l:new_font_size, '')
    endfunction

    function! FontSizeMinus ()
      let l:gf_size_whole = matchstr(&guifont, '\( \)\@<=\d\+$')
      let l:gf_size_whole = l:gf_size_whole - 1
      let l:new_font_size = ' '.l:gf_size_whole
      let &guifont = substitute(&guifont, ' \d\+$', l:new_font_size, '')
    endfunction
else
    function! FontSizePlus ()
      let l:gf_size_whole = matchstr(&guifont, '\(:h\)\@<=\d\+$')
      let l:gf_size_whole = l:gf_size_whole + 1
      let l:new_font_size = ':h'.l:gf_size_whole
      let &guifont = substitute(&guifont, ':h\d\+$', l:new_font_size, '')
    endfunction

    function! FontSizeMinus ()
      let l:gf_size_whole = matchstr(&guifont, '\(:h\)\@<=\d\+$')
      let l:gf_size_whole = l:gf_size_whole - 1
      let l:new_font_size = ':h'.l:gf_size_whole
      let &guifont = substitute(&guifont, ':h\d\+$', l:new_font_size, '')
    endfunction
endif


if has("gui_running")
    nmap <S-F12> :call FontSizeMinus()<CR>
    nmap <F12> :call FontSizePlus()<CR>
endif

Мабуть, спосіб написання налаштувань шрифту залежить від платформи. Що для мене працювало (gvim в MX Linux 17, дистрибутив на базі Debian з робочим столом XFCE):

• Визначте поточні параметри шрифту у відкритому екземплярі gvim, використовуючи : set guifont?

Приклад: guifont=DejaVu Sans Mono 12

• Використовуйте цю інформацію для запису параметрів (змінюючи розмір за бажанням) у ~/.gvimrcфайл, уникаючи пробілів із зворотним нахилом , а також не використовуючи :розмір .

Приклад: set guifont=DejaVu\ Sans\ Mono\ 18

• Після збереження ~/.gvimrcфайлу нові екземпляри gvim повинні використовувати новий потрібний розмір.

Ці дві відповіді допомогли мені:

• https://askubuntu.com/a/3532/129295
• https://stackoverflow.com/a/21894257/1878788

А також коментарі до цього:

• https://vi.stackexchange.com/a/3094/13481

На основі відповіді Дрю ця установка працювала краще для мене.

Він збільшує або зменшує розмір шрифту, використовуючи \+або \-(якщо вважати, що \це ваш лідер), і переходить за допомогою попередньо визначених шрифтів, використовуючи cot. Я часто обмінююсь цими шрифтами залежно від того, працюю з вихідним кодом чи текстом.

let g:fnt_types = ['SourceCode\ Pro', 'monofur' ]
let g:fnt_sizes = [ 10, 13 ]


let g:fnt_index = 0
let g:fnt_size  = g:fnt_sizes[g:fnt_index]

function! CycleFont()
  let g:fnt_index = (g:fnt_index + 1) % len(g:fnt_types)
  let g:fnt_size  = g:fnt_sizes[g:fnt_index]
  call ResetFont()
endfunction

function! ResetFont ()
  if has('gui_running')
    exe ':set guifont=' . g:fnt_types[g:fnt_index] . '\ ' . string(g:fnt_size)
  endif
endfunction

call ResetFont()

function! FontSizePlus ()
  let g:fnt_size = g:fnt_size + 0.5
  call ResetFont()
endfunction

function! FontSizeMinus ()
  let g:fnt_size = g:fnt_size - 0.5
  call ResetFont()
endfunction

nnoremap <leader>+ :call FontSizePlus()<cr>
nnoremap <leader>- :call FontSizeMinus()<cr>
nnoremap cot :call CycleFont()<cr>

Ви можете спробувати цей плагін: vim-fontzoom .

map <m-o> :Fontzoom!<cr>
map <m--> <Plug>(fontzoom-smaller)
map <m-=> <Plug>(fontzoom-larger)