Чи можливо використовувати два різних кольорових фони в одному буфері vim?

Я шукаю можливе рішення для застосування двох різних кольорів фону всередині одного буфера vim, залежно від контексту, як у цьому прикладі піднесеного тексту .

Один з випадків використання - це кольорові фрагменти коду всередині файлів розмітки по-різному, щоб вони виділялися більше.

Однак я ніколи не бачив приклад із подібними налаштуваннями.

Чи це взагалі можливо vim?

Оскільки мені було цікаво, наскільки добре це буде працювати, я щось разом зламав подібні твори.

Як зазначалося в коментарях до попередньої відповіді, єдиний спосіб зробити це - заповнити регіони пробілами; саме це ми і робимо; перед тим, як писати, ми видаляємо ці пробіли, тому ви не повинні заважати нікому іншим.

Зауважте, що цей приклад дуже специфічний для філейного типу розмітки!

Побічні ефекти :

• Копіювання тексту також скопіює багато пробілів
• Використання $та Endбільше не працює так, як очікувалося (це переходить у стовпець 80), а клавіші, такі як jі kтакож поводяться по-різному.
• Фон не відображається, коли 'list'ввімкнено
• Повністю порожні рядки не працюють, вам потрібно вручну додати вкладку або 4 пробіли
• ... Можливо, більше?

По-перше, вам потрібно додати це до свого ~/.vim/after/syntax/markdown.vim:

syn clear markdownCodeBlock                                                 
syn region markdownCodeBlock start="    \|\t" end="$"                       
hi def markdownCodeBlock ctermbg=230 guibg=lightyellow                      

Ви, звичайно, можете налаштувати кольори на свій смак ;-)

Потім додайте це до свого vimrc:

fun! MarkdownBlocks()                                                       
    fun! s:fill(line)                                                       
        " Remove all trailing whitespace                                    
        let l:line = substitute(a:line, " *$", "", "")                      

        " Add trailing whitespace up to 'textwidth' length                  
        return l:line . repeat(' ', (&tw > 0 ? &tw : 80) - strdisplaywidth(l:line))
    endfun                                                                  

    " Get all lines in a list                                               
    let l:lines = getline(1, line('$'))                                     

    " Map s:fill() to the lines that are a code block                       
    call map(l:lines, 'v:val[0] == "\t" || v:val[:3] == "    " ? s:fill(v:val) : v:val')

    " Reset the buffer to the lines                                         
    call setline(1, l:lines)                                                
endfun                                                                      

" Remove all the trailing spaces                                            
fun! MarkdownBlocksClean()                                                  
    let l:save_cursor = getpos(".")                                         
    silent %s/^\(    \|\t\)\(.\{-}\)\( *\)$/\1\2/e                          
    call setpos('.', l:save_cursor)                                         
endfun                                                                      
au BufWritePre *.markdown call MarkdownBlocksClean()                        

" Set spaces on loading the file, leaving insert mode, and after writing it 
au FileType markdown call MarkdownBlocks()                                  
au InsertLeave *.markdown call MarkdownBlocks()                             
au BufWritePost *.markdown call MarkdownBlocks()                            

Я не збираюся пояснювати код по черзі, коментарі повинні чітко пояснювати його ;-)

Звичайно, можна використовувати інший колір фону для елементів, виділених синтаксисом. Просто визначте guibgі ctermbgкольори у вашій hilightкоманді. Перший встановлює колір фону для GUI Vim, а другий для терміналу Vim.

Однак це має важливе обмеження, що він може встановлювати лише кольори фону для символів, які фактично існують у файлі.

Результатом цього є те, що колір фону не може поширюватися на кінець тексту на рядку до краю вікна, тому забарвлення блоків коду, показаних у вашому прикладі, неможливо:

Ви також можете змінити колір фону для цілих рядків за допомогою функції Sign. (Див. linehlВ :help sign.txt)

Однак зауважте, що:

1. Для цього потрібно писати код, щоб розміщувати знаки на кожному рядку, які потрібно пофарбувати, і оновлювати їх у міру зміни вмісту файлу,

2. За замовчуванням при розміщенні знаку стовпчик знаків відображатиметься зліва від вікна. Можна змінити забарвлення стовпчика знаків за допомогою SignColumnгрупи виділення, а в більш пізніх версіях Vim її можна повністю видалити. (Див :help 'signcolumn'.)

Наприклад, щоб адаптувати рішення Carpetsmoker для використання (більш надійного) механізму знаків, ви можете зробити наступне:

" Define a highlight group and a sign that uses it
highlight default markdownCodeBlock ctermbg=230 guibg=lightyellow
sign define codeblock linehl=markdownCodeBlock

" Use signs to highlight code blocks
function! MarkdownBlocks()
    function! s:applySign(idx, val)
        if a:val[0] == "\t" || a:val[:3] == "    "
            let l = a:idx + 1
            execute "sign place " . l . " line=" . l . " name=codeblock file=" . expand("%:p")
        endif
    endfunction

    " Remove old signs
    execute "sign unplace * file=" . expand("%:p")

    " Get all lines in a list
    let l:lines = getline(1, line('$'))
    " Add new signs
    call map(l:lines, function('s:applySign'))
endfunction

" Set signs on loading the file, leaving insert mode, and after writing it
au FileType markdown call MarkdownBlocks()
au InsertLeave *.markdown call MarkdownBlocks()
au BufWritePost *.markdown call MarkdownBlocks()

Це дещо спрощує код і має менше застережень, ніж версія Carpetsmoker.

@ChristianBrabandt «s DynamicSigns плагін робить з допомогою функції Sign для цієї мети простіше: він описує , як використовувати його , щоб зробити це в цій відповіді .