Об’єднайте блоки переплетенням ліній

Чи є спеціальний спосіб об'єднати два блоки тексту переплетенням рядків, як-от перехід від цього:

a1
a2
a3
a4
  b1
  b2
  b3
  b4

до цього:

a1
  b1
a2
  b2
a3
  b3
a4
  b4

за декілька команд?

EDIT : Мені дуже подобається рішення Сато Кацури , ось як я його реалізував:

function! Interleave()
    " retrieve last selected area position and size
    let start = line(".")
    execute "normal! gvo\<esc>"
    let end = line(".")
    let [start, end] = sort([start, end], "n")
    let size = (end - start + 1) / 2
    " and interleave!
    for i in range(size - 1)
        execute (start + size + i). 'm' .(start + 2 * i)
    endfor
endfunction

" Select your two contiguous, same-sized blocks, and use it to Interleave ;)
vnoremap <pickYourMap> <esc>:call Interleave()<CR>

Немає спеціального способу зробити це (наскільки я знаю), але так, це можна зробити за допомогою декількох команд:

function! Interleave(start, end, where)
    if a:start < a:where
        for i in range(0, a:end - a:start)
            execute a:start . 'm' . (a:where + i)
        endfor
    else
        for i in range(a:end - a:start, 0, -1)
            execute a:end . 'm' . (a:where + i)
        endfor
    endif
endfunction

Ви можете запустити його :call Interleave(5, 8, 1). Перший параметр - перший рядок, який потрібно перемістити, другий - останній рядок, а третій - куди їх перемістити. Можливо, ви хочете ввімкнути номери рядків, щоб побачити, що ви робите ( :set number).

Це передбачає, що блоки не перетинаються. Подивіться :help :moveта :help range()зрозумійте, як функціонує функція.

Можливо, є кращі способи підібрати два блоки. Навколо плаває плагін, який повинен дозволяти вам поміняти два блоки. Я не можу згадати ім'я плагіна, але автор (можливо, знаменитий доктор Чіп?) Більше вдумався у пошук інтерфейсу, ніж я. :)

Ось ще одна альтернатива:

:g/^a/+4t .
:+,+5d 

Спочатку скопіюйте рядки, які на 4 рядки нижче, у поточний рядок ( :h :t), а потім видаліть послідовні b рядки ( :h :d)

Ще краще ця команда:

 :g/^a//^\s*b/m .

Що означає, що для кожного рядка, починаючи з знаходження наступного рядка, починаючи з 'b', і переміщуємо його нижче поточного рядка.

Якщо ви хочете трохи розважитися макросами та позначками, ви можете спробувати щось подібне:

• Спочатку поставте позначку (тут a) на рядку, що містить a1сma

• Перейдіть до рядка, що містить b1і позначте йогоmb

• Почніть записувати макрос у потрібному реєстрі (тут реєстр q)qq

• Вставте наступне в свій макрос: ddmb'apjma'b

• Зупиніть записувати макрос за допомогою q

• Відіграйте його стільки разів, скільки потрібно, X@qде Xкількість часу, щоб грати.

Щоб деталізувати макрос:

dd mb 'a p j ma 'b
 |  |  | | |    |
 |  |  | | |    go back to line marked `b`
 |  |  | | |
 |  |  | | move of one line and replace the mark `a`
 |  |  | insert the deleted line under the line marked `a`
 |  |  go to line marked `a`
 |  mark the future line to move with `b`
 delete the line to move

Редагувати Як згадував lago-lito у коментарях, цей метод замінить позначки та буфери.

• Щодо знаків, я не думаю, що це справжня проблема: я рідко використовую всі 26 марок у буфері і думаю, що більшість часу знайдуться 2 вільних позначки.

• Для буфера можна зберегти його у тимчасовій змінній: Перед записом використання макросу :let saveReg=getreg('"')збережіть регістр, і як тільки буде виконана дія, використовуйте :call setreg('"', saveReg)для повернення реєстру до його попереднього стану.

У будь-якому разі я повинен визнати, що це рішення - це просто швидке вирішення та не є оптимальним: на мою думку , відповідь Крістана найкраща, і її слід прийняти, оскільки вона не псується з буферами та позначками, не змушує користувача створювати функція і показує силу глобальної команди.

Я щойно бачив ще одне подібне питання, і рішення складається з:

Перейти до середини плюс один:

Mj

І біжіть:

:,$g/./exe 'm' 2*line('.')-line('$')-1