Команда «затримка» AppleScript не працює з моменту переходу на Yosemite

Примітка . Проблема з delayвиправлена ​​в OS X 10.11 El Capitan.

З моменту переходу на Yosemite, Applescripts, які використовують затримки, перестали працювати. Як я можу це виправити?

Ось найпростіший у світі Applescript заради простого прикладу:

set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0

На це знадобиться 30 секунд. Якщо я запускаю його в редакторі сценаріїв (раніше редактор Applescript), на це потрібно 30 секунд. Але якщо я збережу цей скрипт як додаток, тоді, коли я запускаю програму, затримки ігноруються, і на додаток потрібно частку секунди.

Як змусити Applescript затриматись на певний час, перш ніж перейти до наступного кроку? Це глюк Yosemite? Чи є надійне рішення?

Примітка . Проблема з delayвиправлена ​​в OS X 10.11 El Capitan.

@ 2oh1, ви маєте правильну основну думку у своїй відповіді, але ось повна і правильна відповідь:

Єдиний розумний спосіб подолати це - викликати "затримку" в циклі, що забезпечує бажану тривалість, перш ніж продовжувати. Найкращий спосіб зробити це - замінити "затримку" за допомогою спеціального обробника:

on delay duration
  set endTime to (current date) + duration
  repeat while (current date) is less than endTime
    tell AppleScript to delay endTime - (current date)
  end repeat
end delay

Це дозволяє залишити решту сценарію незмінною, і ви можете використовувати "затримку" нормально, наприклад,

delay 5
display alert "I like cake!"

[ПРИМІТКА: Зазвичай користувальницький обробник використовує "продовжити тривалість затримки", щоб викликати вбудовану "затримку", але я виявив, що, хоча це працює в редакторі сценаріїв, він повертає помилку, коли використовується в аплеті ("Можна" t продовжуйте затримку. (-1708) ”). Я вирішив цю проблему, прямо сказавши AppleScript обробляти команду затримки, а не використовувати "продовжити", щоб дістатися туди.]

Проблема полягає в тому, що delayобробляє введення користувача під час паузи сценарію, тож ви все одно можете натискати на меню чи вікна, відображені аплетом, і є помилка (зафіксовано в 10.11), коли введення користувача змушує delayне чекати повну тривалість до відновлення виконання сценарію. . Якщо ви не взаємодієте з аплетом, delayпрацює правильно.

Під час боротьби з цією ж проблемою я натрапив на цю відповідь на не дуже пов’язане з цим питання і вирішив спробувати його, і, здається, це працює для мене.

Просто замініть delay 5з do shell script "/bin/sleep 5"і отримати той же результат.

Я не кажу, що це найкраще рішення, але, здається, воно вирішило мою проблему. Замість того, щоб використовувати просту затримку, яку ігнорують з незрозумілих мені причин, я перейшов до отримання часу та циклічного циклу до досягнення нового часу (він все ще використовує затримку, але не має значення, якщо вона ігнорується затримка, оскільки сценарій не триває до досягнення часу).

# Pause for five minutes
set GetTheTime to current date
set NewTime to GetTheTime + (5 * minutes)
repeat while (current date) is less than NewTime
    delay 60
end repeat

Я все ще вмираю, щоб знати, чому затримку ігнорують (або кардинально прискорили?! ??), але це робить роботу, незграбну, як це є.

Я знайшов обхід у німецькому дописі на форумі . Додайте ці рядки до початку сценарію:

use framework "Foundation"
use scripting additions
current application's NSThread's sleepForTimeInterval:1

carzyj мав те, що я вважаю найкращою відповіддю, але в поєднанні з методом Кріса Пейджа ви отримуєте:

on delay duration
  do shell script "/bin/sleep " & duration
end delay

Ви можете прокоментувати "затримку" через "кінець затримки", щоб повернутися до початкової затримки.

це модифікація рішення на сторінці @ chris

Здається, це баланс між чуйністю та точною фіксацією затримки.

on delay duration
    set endTime to (current date) + duration
    repeat while (current date) is less than endTime
        set delta to duration / 100
        if duration < 0.2 then
            set delta to 0.2
        end if
        tell AppleScript to delay delta
    end repeat
end delay

Але замість того, щоб сказати Applescript затримати загальну тривалість, ми просто скажемо йому затриматись на дробовий період тривалості. якщо період менший, ніж дозволяє яблуко (1/60 секунди), то давайте просто встановимо його на цю дельту. Що ми можемо зберігати деяку чуйність, але все одно залишаємось точними. підозра в тому, що іноді затримка не працює, тому повтор, поки цикл буде тримати заблоковану нитку, але в сценаріях успіху ми хочемо, щоб дельта затримки була короткою, щоб процес все-таки був перерваний

Таким чином, я вважаю, що Кріс це означає:

on delay duration
   set endTime to (current date) + duration
   repeat while (current date) is less than endTime
      tell AppleScript to delay endTime - (current date)
   end repeat
end delay