Чи можу я перезавантажити бібліотеку та мати значення defvar повторно призначити?

Я розробляю бібліотеку і хотів би перезавантажити її після редагування, не виходячи з Emacs (припустимо, що вона включена load-path):

(load-library "myname")

Коли я це роблю, Emacs не збирає зміни defvarзмінних -bound.

Я не хочу телефонувати eval-defun( C-M-x) вручну на кожній формі верхнього рівня. Чи M-x eval-bufferповажає defvar/ defcustom?

(progn (unload-feature 'your-lib) (load-library "your-lib"))

Це буде працювати до тих пір , як ви завантажили перший defvars шляхом завантаження бібліотеки через Emacs, а не з допомогою eval-defun, і eval-bufferт.д.

При використанні require, і load-libraryт.д. Emacs буде відслідковувати , які змінні і функції є частиною бібліотеки, і видалити їх повністю для вас , коли ви використовуєте unload-feature.

Під час написання пакетів я вважаю, що використання коду вище - це краще рішення, ніж запуск, eval-defunколи ви пишете новий код, щоб ви не потрапляли в проміжні стани.

defvarне перепризначає значення змінної так само, як, скажімо, setqабо setf. Коли змінна має значення, defvar її не торкнеться.

З defvar's docstring:

(defvar SYMBOL &optional INITVALUE DOCSTRING)

Визначте SYMBOL як змінну та поверніть SYMBOL.

...

Необов'язковий аргумент INITVALUE оцінюється та використовується для встановлення SYMBOL, лише якщо значення SYMBOL недійсне . Якщо SYMBOL буферно-локальний, його значенням за замовчуванням є те, що встановлено; локальні значення буфера не впливають. Якщо INITVALUE відсутня, значення SYMBOL не встановлено.

...

Оскільки ви, ймовірно, defvarредагували вказані змінні, щоб надати їм значення під час першого завантаження бібліотеки, повторна завантаження бібліотеки не змінить значення.

Дивіться також вузол посібника elisp щодо визначення глобальних змінних .

Замість того, щоб покладатися на це defvar, ви завжди можете перепризначити значення за допомогою setq. Як альтернатива, незграбний варіант, ви можете uninternвикористовувати символи, щоб defvars не знайшов їх при перезавантаженні:

(defvar test-1 "test this")
(defvar test-2 "test this one, too")

test-1                                  ; => "test this"
test-2                                  ; => "test this one, too"

(defvar test-1 "trying to redefine")
(defvar test-2 "trying to redefine, too")

test-1                                  ; => "test this"
test-2                                  ; => "test this one, too"

(mapc #'unintern '(test-1 test-2))

test-1                                  ; => error!
test-2                                  ; => error!

(defvar test-1 "trying to redefine")
(defvar test-2 "trying to redefine, too")

test-1                                  ; => "trying to redefine"
test-2                                  ; => "trying to redefine, too"

Спробуйте це:

(defun foo ()
  "(Re-)evaluate all `defvar's in the buffer (or its restriction)."
  (interactive)
  (save-excursion
    (goto-char (point-min))
    (while (not (eobp))
      (when (re-search-forward "\\s-*(defvar \\([^ \t\n(\"]+\\)[ \t\n]+[^)]" nil 'MOVE)
        (let ((old-value (make-symbol "t"))
              new-value value)
          (let ((debug-on-error old-value))
            (setq value (eval-defun-2))
            (setq new-value debug-on-error))
          (unless (eq old-value new-value)
            (setq debug-on-error new-value))
          value)))))

Він просто використовує той самий код, який eval-defunвикористовується для defvar. Він обходить буфер (або його обмеження звуженням), зупиняючись на кожному defvarі використовуючи eval-defunкод на ньому.

Після того як я почув, що не існує зручного рішення для переоцінки буфера з перепризначенням defvars, я зробив просту функцію, яка ретранслюється на eval-defun:

(defun my/eval-buffer ()
  "Evaluate entire buffer with re-assigning values to `defvar' / `defcustom'.
Useful during package development."
  (interactive)
  (save-excursion
    (beginning-of-buffer)
    (while (not (eobp))
      (eval-defun nil)
      (end-of-defun))))

Структура коду, натхненна eval-defun-2реалізацією. Це схоже на Як змусити переоцінити дефавар? рішення.

Спочатку я хочу, щоб функція високого рівня переоцінила бібліотеку, яка перевстановлена ​​через сценарій збірки, щоб:

(defun my/load-library (library)
  "Evaluate entire library with re-assigning values to `defvar' / `defcustom'.
Useful during package development."
  (interactive
   (list (completing-read "Load library: "
                          (apply-partially 'locate-file-completion-table
                                           load-path
                                           '("" ".el")))))
  (with-temp-buffer
    (insert-file-contents (locate-file library load-path '("" ".el")))
    (my/eval-buffer)))

Рішення Drew працює навіть на вкладених, defvarале код важко повністю зрозуміти.

Я також думаю про uninternвсі символи на основі префіксу / регексу символів (як запропонував Ден ), але я лінивий щоразу вводити префікс ... Див. Як я можу відв'язати всі визначення символів певним префіксом?