Як я можу відправити HTTP POST-запит на сервер від Excel за допомогою VBA?

Який код VBA необхідний для виконання HTTP POST з електронної таблиці Excel?

Set objHTTP = CreateObject("MSXML2.ServerXMLHTTP")
URL = "http://www.somedomain.com"
objHTTP.Open "POST", URL, False
objHTTP.setRequestHeader "User-Agent", "Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.0)"
objHTTP.send("")

Крім того, для більшого контролю над HTTP-запитом, який ви можете використовувати WinHttp.WinHttpRequest.5.1замість MSXML2.ServerXMLHTTP.

Якщо він потрібен для роботи на Mac і Windows, ви можете використовувати QueryTables:

With ActiveSheet.QueryTables.Add(Connection:="URL;http://carbon.brighterplanet.com/flights.txt", Destination:=Range("A2"))
    .PostText = "origin_airport=MSN&destination_airport=ORD"
    .RefreshStyle = xlOverwriteCells
    .SaveData = True
    .Refresh
End With

Примітки:

• Щодо виводу ... Я не знаю, чи можна повернути результати в ту саму клітинку, яка називала функцію VBA. У наведеному вище прикладі результат записується в A2.
• Щодо введення даних ... Якщо ви хочете, щоб результати оновлювались при зміні певних комірок, переконайтеся, що ці клітини є аргументом вашої функції VBA.
• Це не буде працювати в Excel для Mac 2008, на якому немає VBA. Excel для Mac 2011 повернув VBA.

Для отримання більш детальної інформації ви можете побачити моє повне резюме про " використання веб-служб від Excel ".

Окрім прихильника Білла Ящера :

Більшість із загальних даних аналізують необроблені дані публікації. Наприклад, у PHP, у вас буде масив, $_POSTв якому будуть зберігатися окремі змінні в даних публікації. У цьому випадку вам потрібно використовувати додатковий заголовок "Content-type: application/x-www-form-urlencoded":

Set objHTTP = CreateObject("WinHttp.WinHttpRequest.5.1")
URL = "http://www.somedomain.com"
objHTTP.Open "POST", URL, False
objHTTP.setRequestHeader "User-Agent", "Mozilla/4.0 (compatible; MSIE 6.0; Windows NT 5.0)"
objHTTP.setRequestHeader "Content-type", "application/x-www-form-urlencoded"
objHTTP.send ("var1=value1&var2=value2&var3=value3")

Інакше вам доведеться читати необроблені дані публікації на змінній "$HTTP_RAW_POST_DATA".

Ви можете використовувати ServerXMLHTTPв проекті VBA, додавши посилання на MSXML.

1. Відкрийте редактор VBA (зазвичай, редагуючи макрос)
2. Перейдіть до списку доступних посилань
3. Перевірте Microsoft XML
4. Натисніть кнопку ОК.

(з посилань на MSXML в рамках VBA-проектів )

Документація ServerXMLHTTP MSDN має повну інформацію про всі властивості і методи ServerXMLHTTP.

Якщо коротко, це працює в основному так:

1. Виклик відкритого методу для підключення до віддаленого сервера
2. Надіслати дзвінок, щоб надіслати запит.
3. Прочитайте відповідь через responseXML , responseText , responseStream або responseBody

Щоб заповнити відповідь інших користувачів:

Для цього я створив об’єкт "WinHttp.WinHttpRequest.5.1" .

Надішліть запит на пошту з деякими даними від Excel за допомогою VBA:

Dim LoginRequest As Object
Set LoginRequest = CreateObject("WinHttp.WinHttpRequest.5.1")
LoginRequest.Open "POST", "http://...", False
LoginRequest.setRequestHeader "Content-type", "application/x-www-form-urlencoded"
LoginRequest.send ("key1=value1&key2=value2")

Надішліть запит на отримання аутентифікації маркера від Excel за допомогою VBA:

Dim TCRequestItem As Object
Set TCRequestItem = CreateObject("WinHttp.WinHttpRequest.5.1")
TCRequestItem.Open "GET", "http://...", False
TCRequestItem.setRequestHeader "Content-Type", "application/xml"
TCRequestItem.setRequestHeader "Accept", "application/xml"
TCRequestItem.setRequestHeader "Authorization", "Bearer " & token
TCRequestItem.send

Я робив це перед тим, як використовувати бібліотеку MSXML, а потім використовувати об’єкт XMLHttpRequest, дивіться тут .