Приховані особливості Perl?

Які є справді корисні, але езотеричні особливості мови в Perl, які ви насправді змогли використати для виконання корисної роботи?

Правила:

• Спробуйте обмежити відповіді ядром Perl, а не CPAN
• Наведіть приклад та короткий опис

Приховані функції, які також можна знайти в інших прихованих функціях інших мов:

(Це все з відповіді Коріона )

• С
  • Пристрій Даффа
  • Переносність та стандартність
• C #
  • Котирування списків та рядків з розділеним пробілом
  • Простіри імен
• Java
  • Статичні ініталізатори
• JavaScript
  • Функції - громадяни першого класу
  • Блокування та закриття блоку
  • Методи виклику та доступу до них непрямим шляхом через змінну
• Рубін
  • Визначення методів за допомогою коду
• PHP
  • Повсюдна онлайн-документація
  • Магічні методи
  • Символічні посилання
• Пітон
  • Зміна значень однієї лінії
  • Можливість замінити навіть основні функції власним функціоналом

Інші приховані функції:

Оператори:

• Квазіоператор bool
• Оператор відкидання
  • Також використовується для побудови списку
• В ++і унарні -оператори працюють на струнах
• Оператор повторення
• Оператор космічного корабля
• || operator (і // operator), щоб вибрати з набору варіантів
• Діамантовий оператор
• Особливі випадки m//оператора
• "Оператор" тильда-тильди

Цитуючи конструкції:

• Оператор qw
• Букви можна використовувати як роздільники цитат у q {} - подібних конструкціях
• Механізми цитування

Синтаксис та імена:

• Після сигіли може бути пробіл
• Можна надати підрядним числовим іменам символічні посилання
• Юридичні затримки
• Згруповані цілі літерали
• скибочки хешу
• Популяція ключів хешу з масиву

Модулі, прагми та параметри командного рядка:

• використовувати суворі та використовувати попередження
• Перевірка тантів
• Езотеричне використання -n та -p
• CPAN
• overload::constant
• IO :: Модуль ручки
• Безпечні відсіки
• Атрибути

Змінні:

• Автовівіфікація
• $[змінна
• краватку
• Динамічне оцінювання
• Змінна заміна одним оператором

Петлі та контроль потоку:

• Чарівний гото
• for на одній змінній
• продовжити пункт
• Режим відчаю

Регулярні вирази:

• \Gякір
• (?{}) і '(?? {}) `у регулярних виразах

Інші особливості:

• Налагоджувач
• Спеціальні блоки коду, такі як BEGIN, CHECK і END
• DATAблок
• Нові операції з блоком
• Джерельні фільтри
• Сигнальні гачки
• карта ( двічі )
• Обтікання вбудованими функціями
• eofфункція
• dbmopenфункція
• Перетворення попереджень у помилки

Інші хитрощі та метавідповіді:

• файли котів, при необхідності розпаковуючи gzips
• Поради Perl

Дивитися також:

• Приховані особливості С
• Приховані функції C #
• Приховані особливості C ++
• Приховані особливості Java
• Приховані функції JavaScript
• Приховані риси Рубі
• Приховані особливості PHP
• Приховані особливості Python
• Приховані риси Clojure

Оператор відкидання корисний для пропускання першої ітерації під час перегляду записів (зазвичай рядків), повернутих файловою ручкою, без використання змінної прапора:

while(<$fh>)
{
  next if 1..1; # skip first record
  ...
}

Запустіть perldoc perlopі знайдіть "flip-flop" для отримання додаткової інформації та прикладів.

У Perl є багато неочевидних особливостей.

Наприклад, чи знали ви, що після сигіли може бути пробіл?

 $ perl -wle 'my $x = 3; print $ x'
 3

Або що ви можете вводити числові імена підрозділів, якщо використовуєте символічні посилання?

$ perl -lwe '*4 = sub { print "yes" }; 4->()' 
yes

Також є квазіоператор "bool", який повертає 1 для справжніх виразів і порожній рядок для помилкових:

$ perl -wle 'print !!4'
1
$ perl -wle 'print !!"0 but true"'
1
$ perl -wle 'print !!0'
(empty line)

Інші цікаві речі: use overloadви можете перевантажувати рядкові букви та числа (і, наприклад, робити їх BigInts чи будь-що інше).

Багато з цих речей фактично десь задокументовані або логічно випливають із задокументованих особливостей, але, тим не менш, деякі не дуже відомі.

Оновлення : Ще одна приємна. Нижче q{...}згадуються конструкції цитування, але чи знали ви, що ви можете використовувати літери як роздільники?

$ perl -Mstrict  -wle 'print q bJet another perl hacker.b'
Jet another perl hacker.

Так само ви можете писати регулярні вирази:

m xabcx
# same as m/abc/

Додайте підтримку стислих файлів за допомогою магічного ARGV :

s{ 
    ^            # make sure to get whole filename
    ( 
      [^'] +     # at least one non-quote
      \.         # extension dot
      (?:        # now either suffix
          gz
        | Z 
       )
    )
    \z           # through the end
}{gzcat '$1' |}xs for @ARGV;

(лапки навколо $ _, необхідні для обробки імен файлів з метахарактерами оболонки в)

Тепер <>функція розпакує всі @ARGVфайли, які закінчуються на ".gz" або ".Z":

while (<>) {
    print;
}

Однією з моїх улюблених функцій в Perl є використання булевого ||оператора для вибору між набором варіантів.

 $x = $a || $b;

 # $x = $a, if $a is true.
 # $x = $b, otherwise

Це означає, що можна написати:

 $x = $a || $b || $c || 0;

посісти перше справжнє значення з $a, $bі $c, або значення по замовчуванням в 0іншому випадку.

У Perl 5.10 також є //оператор, який повертає ліву частину, якщо вона визначена, а праву частину в іншому випадку. Наступні вибирає перший визначається значення з $a, $b, $c, або в 0іншому випадку:

$ x = $ a // $ b // $ c // 0;

Вони також можуть бути використані з їх короткими формами, які дуже корисні для надання за замовчуванням:

$ x || = 0; # Якщо $ x було помилковим, то тепер воно має значення 0.

$ x // = 0; # Якщо $ x не було визначено, тепер воно має значення нуля.

Cheerio,

Пол

Оператори ++ та unry - працюють не тільки на числах, але й на рядках.

my $_ = "a"
print -$_

відбитки -а

print ++$_

відбитки b

$_ = 'z'
print ++$_

друкує аа

Оскільки Perl має майже всі "езотеричні" частини з інших списків, я скажу вам одне, що Perl не може:

Єдине, що Perl не може зробити - це оголити довільні URL-адреси у вашому коді, оскільки //оператор використовується для регулярних виразів.

На випадок, якщо вам не було очевидно, які функції пропонує Perl, ось вибірковий список можливо не зовсім очевидних записів:

Пристрій Даффа - в Perl

Переносність та стандартність - ймовірно, що більше комп'ютерів з Perl, ніж у компілятора C

Клас маніпулювання файлом / контуром - File :: Find працює навіть у більшій кількості операційних систем, ніж у .Net

Котирування списків та рядків з розділеним пробілом - Perl дозволяє вибирати майже довільні лапки для списку та роздільників рядків

Поширені простори імен - Perl має це через глобальні призначення:

*My::Namespace:: = \%Your::Namespace

Статичні ініціалізатори - Perl може запускати код практично на будь-якій фазі компіляції та інстанціюванні об'єктів, від BEGIN(розбору коду) до CHECK(після розбору коду) до import(при імпорті модуля) до new(інстанції об'єкта) до DESTROY(знищення об'єкта) до END(виходу з програми)

Функції - громадяни першого класу - як і в Perl

Область блокування та закриття - Perl має і те, і інше

Способи виклику та доступу до нього непрямим способом через змінну - Perl робить це також:

my $method = 'foo';
my $obj = My::Class->new();
$obj->$method( 'baz' ); # calls $obj->foo( 'baz' )

Визначення методів за допомогою коду - Perl дозволяє також :

*foo = sub { print "Hello world" };

Повсюдна онлайн-документація - Документація Perl є в Інтернеті, імовірно, і у вашій системі

Магічні методи, які викликаються щоразу, коли ви викликаєте функцію "неіснуюча" - Perl реалізує цю функцію у функції AUTOLOAD

Символічні посилання - вам рекомендується триматися подалі від них. Вони будуть їсти ваших дітей. Але звичайно, Perl дозволяє запропонувати своїм дітям кровожерливих демонів.

Зміна значення одного рядка - Perl дозволяє призначити список

Можливість замінити навіть основні функції власним функціоналом

use subs 'unlink'; 
sub unlink { print 'No.' }

або

BEGIN{
    *CORE::GLOBAL::unlink = sub {print 'no'}
};

unlink($_) for @ARGV

Автовівіфікація . AFAIK жодної іншої мови не має .

Процитувати майже будь-який дивний рядок у Perl просто.

my $url = q{http://my.url.com/any/arbitrary/path/in/the/url.html};

Насправді різні механізми цитування в Perl є досить цікавими. Механізми котирування, схожі на регулярний вираз Perl, дозволяють вам цитувати що завгодно, вказуючи роздільники. Ви можете використовувати майже будь-який спеціальний символ, наприклад, #, / або відкрити / закрити символи, такі як (), [] або {}. Приклади:

my $var  = q#some string where the pound is the final escape.#;
my $var2 = q{A more pleasant way of escaping.};
my $var3 = q(Others prefer parens as the quote mechanism.);

Механізми цитування:

q: буквальна цитата; єдиний символ, якого потрібно уникнути, - це символ кінця. qq: інтерпретована цитата; обробляє змінні та бігти символи. Чудово підходить для рядків, які вам потрібно цитувати:

my $var4 = qq{This "$mechanism" is broken.  Please inform "$user" at "$email" about it.};

qx: працює як qq, але потім виконує його як системну команду, не інтерактивно. Повертає весь текст, сформований із стандартного. (Перенаправлення, якщо воно підтримується в ОС, також виходить) Також робиться із зворотними лапками (символ `).

my $output  = qx{type "$path"};      # get just the output
my $moreout = qx{type "$path" 2>&1}; # get stuff on stderr too

qr: Інтерпретується як qq, але потім компілює його як регулярний вираз. Працює і з різними варіантами на регулярному вираженні. Тепер ви можете передавати регулярний вираз як змінну:

sub MyRegexCheck {
    my ($string, $regex) = @_;
    if ($string)
    {
       return ($string =~ $regex);
    }
    return; # returns 'null' or 'empty' in every context
}

my $regex = qr{http://[\w]\.com/([\w]+/)+};
@results = MyRegexCheck(q{http://myurl.com/subpath1/subpath2/}, $regex);

qw: Дуже, дуже корисний оператор котирування. Перетворює цитований набір розділених пробілами слів у список. Відмінно підходить для заповнення даних в одиничному тесті.

   my @allowed = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z { });
   my @badwords = qw(WORD1 word2 word3 word4);
   my @numbers = qw(one two three four 5 six seven); # works with numbers too
   my @list = ('string with space', qw(eight nine), "a $var"); # works in other lists
   my $arrayref = [ qw(and it works in arrays too) ]; 

Вони чудово використовують їх, коли це робить речі зрозумілішими. Для qx, qq і q я, швидше за все, використовую оператори {}. Найчастіша звичка людей, які використовують qw, зазвичай є () оператором, але іноді ви також бачите qw //.

Насправді не приховано, але багато кожного дня програмісти Perl не знають про CPAN . Особливо це стосується людей, які не є штатними програмістами або не програмують на Perl повний робочий день.

Оператор "для" може бути використаний так само, як "з" використовується в Pascal:

for ($item)
{
    s/&‎nbsp;/ /g;
    s/<.*?>/ /g;
    $_ = join(" ", split(" ", $_));
}

Ви можете застосувати послідовність s /// операцій тощо до тієї ж змінної без повторення імені змінної.

ПРИМІТКА: нерозривний пробіл вгорі (& nbsp;) приховав у ньому Unicode, щоб обійти відмітку. Не копіюйте це вставити :)

Оператор лапок - одна з моїх улюблених речей. Порівняйте:

my @list = ('abc', 'def', 'ghi', 'jkl');

і

my @list = qw(abc def ghi jkl);

Набагато менше шуму, легше на око. Ще одна справді приємна річ щодо Perl, яку дійсно не вистачає при написанні SQL, - це те, що кома в кінці є законною:

print 1, 2, 3, ;

Це виглядає дивно, але це не так, якщо ви відрізаєте код іншим способом:

print
    results_of_foo(),
    results_of_xyzzy(),
    results_of_quux(),
    ;

Додавання додаткового аргументу до виклику функції не вимагає, щоб ви ковталися з комами в попередніх або кінцевих рядках. Зміна однієї лінії не впливає на навколишні її лінії.

Це робить дуже приємним працювати з різноманітними функціями. Це, мабуть, одна з найбільш занижених особливостей Perl.

Можливість аналізу даних безпосередньо вставляється в блок DATA . Не потрібно зберігати тестовий файл, який потрібно відкрити в програмі чи подібному. Наприклад:

my @lines = <DATA>;
for (@lines) {
    print if /bad/;
}

__DATA__
some good data
some bad data
more good data 
more good data 

Нові операції з блоком

Я б сказав, що можливість розширити мову, створюючи операції псевдоблоку - це одне.

1. Ви оголошуєте прототип для підзаголовка, що вказує, що спочатку він посилається на код:

   sub do_stuff_with_a_hash (&\%) {
       my ( $block_of_code, $hash_ref ) = @_;
       while ( my ( $k, $v ) = each %$hash_ref ) { 
           $block_of_code->( $k, $v );
       }
   }

2. Потім можна так називати його в організмі

   use Data::Dumper;
   
   do_stuff_with_a_hash {
       local $Data::Dumper::Terse = 1;
       my ( $k, $v ) = @_;
       say qq(Hey, the key   is "$k"!);
       say sprintf qq(Hey, the value is "%v"!), Dumper( $v );
   
   } %stuff_for
   ;

( Data::Dumper::Dumperце ще один напівприхований самоцвіт.) Зауважте, як вам не потрібно subключове слово перед блоком або кома перед хешем. Це все виглядає так, як:map { } @list

Джерельні фільтри

Також є джерельні фільтри. Де Perl передасть вам код, щоб ви могли ним маніпулювати. І це, і операції з блоком - це майже все, що не потрібно випробовувати.

Я зробив кілька акуратних речей із вихідними фільтрами, наприклад, як створити дуже просту мову, щоб перевірити час, що дозволяє короткі Perl-вкладиші Perl для певного прийняття рішень:

perl -MLib::DB -MLib::TL -e 'run_expensive_database_delete() if $hour_of_day < AM_7';

Lib::TL просто сканував би як "змінні", так і константи, створив би їх і замінив за потребою.

Знову ж таки, джерельні фільтри можуть бути безладним, але є потужними. Але вони можуть зіпсувати налагодження чогось жахливого - і навіть попередження можуть бути надруковані з неправильними номерами рядків. Я перестав користуватися перемикачем Даміана тому що налагоджувач втратив усі можливості сказати мені, де я насправді. Але я виявив, що ви можете мінімізувати шкоду, змінюючи невеликі розділи коду, зберігаючи їх у тому ж рядку.

Сигнальні гачки

Це досить часто робиться, але це не все так очевидно. Ось вантажник, що підбирає спинку на старому.

my $old_die_handler = $SIG{__DIE__};
$SIG{__DIE__}       
    = sub { say q(Hey! I'm DYIN' over here!); goto &$old_die_handler; }
    ;

Це означає, що коли-небудь інший модуль у коді хоче померти, вони повинні прийти до вас (якщо хтось інший не може деструктивно перезаписати $SIG{__DIE__} ). І вас можуть повідомити, що хтось щось щось є помилкою.

Звичайно, для достатньої кількості речей ви можете просто використовувати END { }блок, якщо все, що ви хочете зробити, - це прибрати.

overload::constant

Ви можете перевірити літерали певного типу в пакунках, що містять ваш модуль. Наприклад, якщо ви користуєтеся цим у своєму importпідрозділі:

overload::constant 
    integer => sub { 
        my $lit = shift;
        return $lit > 2_000_000_000 ? Math::BigInt->new( $lit ) : $lit 
    };

це означатиме, що кожне ціле число, що перевищує 2 мільярди в викликових пакетах, буде змінено на Math::BigIntоб'єкт. (Див. Перевантаження :: постійні ).

Згруповані цілі літерали

Поки ми в цьому. Perl дозволяє розбити великі числа на групи з трьох цифр і все одно отримати з нього проривне ціле число. Зверніть увагу 2_000_000_000вище на 2 мільярди.

Двійковий "x" є оператором повторення :

print '-' x 80;     # print row of dashes

Він також працює зі списками:

print for (1, 4, 9) x 3; # print 149149149

Перевірка тантів. Якщо увімкнено перевірку танти, Perl загине (або попередить, разом із)-t ), якщо ви спробуєте передати загрожуючі дані (грубо кажучи, дані за межами програми) в небезпечну функцію (відкриття файлу, виконання зовнішньої команди тощо). Це дуже корисно при написанні встановлених сценаріїв або CGI або будь-чого, де сценарій має більші привілеї, ніж людина, яка його подає.

Чарівний гото. goto &subробить оптимізований виклик хвоста.

Налагоджувач.

use strictі use warnings. Це може врятувати вас від купу помилок.

Виходячи з способу реалізації "-n"та "-p"перемикачів у Perl 5, ви можете написати, здавалося б, неправильну програму, включаючи }{:

ls |perl -lne 'print $_; }{ print "$. Files"'

який внутрішньо перетворюється в цей код:

LINE: while (defined($_ = <ARGV>)) {
    print $_; }{ print "$. Files";
}

Почнемо легко з Оператора космічного корабля .

$a = 5 <=> 7;  # $a is set to -1
$a = 7 <=> 5;  # $a is set to 1
$a = 6 <=> 6;  # $a is set to 0

Це метавідповідь, але поради Perl архіви містять всілякі цікаві хитрощі, які можна виконати за допомогою Perl. Архів попередніх порад є он-лайн для перегляду, і його можна підписати через список розсилки або канал атомів.

Деякі з моїх улюблених порад включають створення виконавчих файлів за допомогою PAR , використання автоматичної автоматичної передачі винятків та використання конструкцій перемикача та смарт-відповідника в Perl 5.10.

Розкриття інформації: Я один з авторів і підтримуючих Perl Tips, тому я, очевидно, дуже високо їх вважаю. ;)

map - не тільки тому, що робить свій код більш виразним, а й тому, що це дало мені імпульс прочитати трохи більше про це "функціональне програмування".

Продовжуйте пропозицію про петлі. Він буде виконуватися внизу кожної петлі, навіть тих, що наступні.

while( <> ){
  print "top of loop\n";
  chomp;

  next if /next/i;
  last if /last/i;

  print "bottom of loop\n";
}continue{
  print "continue\n";
}

Я голосував би за групи (? {}) Та (?? {}) у регулярних висловах Perl. Перший виконує код Perl, ігноруючи повернене значення, другий виконує код, використовуючи повернене значення як регулярний вираз.

while(/\G(\b\w*\b)/g) {
     print "$1\n";
}

\ G якір. Це спекотно .

The m//Оператор має деякі маловідомі окремі випадки:

• Якщо ви використовуєте ? як роздільник, він відповідає лише один раз, якщо ви не телефонуєте reset.
• Якщо ви використовуєте 'як роздільник, візерунок не інтерполюється.
• Якщо шаблон порожній, він використовує шаблон з останнього успішного збігу.

Оператор алмазів з нульовим файловим інструментом <>має своє місце в побудові інструментів командного рядка. Це діє, як <FH>читати з ручки, за винятком того, що він магічно вибирає те, що було знайдено першим: назви файлів командного рядка або STDIN. Взято з перлопа:

while (<>) {
...         # code for each line
}

Спеціальні блоки коду , такі як BEGIN, CHECKіEND . Вони родом з Awk, але працюють по-різному в Perl, тому що це не рекордно.

BEGINБлок може бути використаний для вказівки код для фази синтаксичного аналізу; він також виконується під час перевірки синтаксису та змінної perl -c. Наприклад, для завантаження змінних конфігурації:

BEGIN {
    eval {
        require 'config.local.pl';
    };
    if ($@) {
        require 'config.default.pl';
    }
}

rename("$_.part", $_) for "data.txt";

перейменовує data.txt.part у data.txt, не повторюючи себе.

Трохи незрозумілим є "оператор" тильда-тильди, який змушує скалярний контекст.

print ~~ localtime;

те саме, що

print scalar localtime;

і відрізняється від

print localtime;

краватка, змінний інтерфейс зв’язування.

"Режим відчаю" конструктів циклу управління Perl, який змушує їх шукати стек, щоб знайти відповідну мітку, дозволяє деякі цікаві поведінки, якими Test :: More скористається, для кращого чи гіршого.

SKIP: {
    skip() if $something;

    print "Never printed";
}

sub skip {
    no warnings "exiting";
    last SKIP;
}

Там маловідомий файл .pmc. "використовувати Foo" шукатиме Foo.pmc в @INC перед Foo.pm. Це покликане було спершу завантажувати складений байтовий код, але Module :: Compile використовує це для кешування модулів, відфільтрованих джерелом, для більш швидкого завантаження та спрощення налагодження.

Можливість перетворювати попередження в помилки.

local $SIG{__WARN__} = sub { die @_ };
$num = "two";
$sum = 1 + $num;
print "Never reached";

Ось що я можу придумати, не згадуючи верхньої частини голови.

Оператор козлів *:

$_ = "foo bar";
my $count =()= /[aeiou]/g; #3

або

sub foo {
    return @_;
}

$count =()= foo(qw/a b c d/); #4

Це працює тому, що присвоєння списку в скалярному контексті дає кількість елементів у списку, що присвоюється.

* Зауважте, насправді не оператор