Випадкове число hlsl

Як ви генеруєте випадкове число в HLSL?

Я запитую, бо хочу спробувати трасування gpu-променів . Вам потрібно генерувати випадкові напрямки в піксельній шейдері. Тому я хочу randFloat(), де результатом є випадкове число від -1 до +1.

Крім того, яка угода з інструкцією щодо шуму hlsl ? Документи кажуть, що він був видалений з HLSL 2.0 і вище. Чому ?

Я читав про підхід, коли ви заповнюєте текстуру випадковими значеннями, а потім маєте координату текстури у кожній вершині, яка має індекс на цю текстуру. Але це за вершиною , мені потрібна інструкція, яку я можу викликати в піксельному шейдері. Крім того, цей підхід вимагає "повторного перезавантаження" текстових рядків на вершину, якщо ви хочете, щоб кожен кадр відрізнявся значеннями, а для цього потрібен оновлення вершинного буфера для кожного кадру (що може бути дорого!)

Докладно, як можна дешево генерувати випадкове число на GPU?

Псевдо випадкових чисел у піксельній шейдері отримати непросто. Генератор псевдовипадкових чисел у процесорі матиме певний стан, з якого він читає і записує під час кожного виклику функції. Ви не можете цього зробити в піксельній шейдері.

Ось кілька варіантів:

1. Використовуйте обчислювальний шейдер замість піксельного шейдера - вони підтримують доступ для читання-запису до буфера, тому ви можете реалізувати будь-який стандартний PRNG.

2. Вибірка з однієї або декількох текстур, що містять випадкові дані, на основі такого параметра, як положення на екрані. Ви також можете зробити деякі математичні позиції перед тим, як використовувати його для пошуку текстури, що дозволяє дозволити повторному використанню текстури, якщо математика передбачає постійну шейдерну константу на креслення дзвінка.

3. Знайдіть певну математичну функцію положення простору екрану, яка дає результати, які є "досить випадковими".

Швидкий пошук Google знайшов цю сторінку з цими функціями:

float rand_1_05(in float2 uv)
{
    float2 noise = (frac(sin(dot(uv ,float2(12.9898,78.233)*2.0)) * 43758.5453));
    return abs(noise.x + noise.y) * 0.5;
}

float2 rand_2_10(in float2 uv) {
    float noiseX = (frac(sin(dot(uv, float2(12.9898,78.233) * 2.0)) * 43758.5453));
    float noiseY = sqrt(1 - noiseX * noiseX);
    return float2(noiseX, noiseY);
}

float2 rand_2_0004(in float2 uv)
{
    float noiseX = (frac(sin(dot(uv, float2(12.9898,78.233)      )) * 43758.5453));
    float noiseY = (frac(sin(dot(uv, float2(12.9898,78.233) * 2.0)) * 43758.5453));
    return float2(noiseX, noiseY) * 0.004;
}

Ось як я генерую псевдо випадкові числа для ефектів частинок за допомогою обчислювального шейдера. Не впевнений, наскільки справжньо випадковий цей код, але він працює досить добре для моїх цілей.

Ключовим фактором для надання ядра кожного GPU є власна випадкова послідовність - подача обчислювального шейдера початковим випадковим насінням із процесора. Кожне ядро ​​потім використовує це насіння для циклу генератора чисел, використовуючи його ідентифікатор потоку як кількість. Звідси кожна нитка повинна мати власне унікальне насіння для створення унікальних значень.

// Source
// http://www.gamedev.net/topic/592001-random-number-generation-based-on-time-in-hlsl/
// Supposebly from the NVidia Direct3D10 SDK
// Slightly modified for my purposes
#define RANDOM_IA 16807
#define RANDOM_IM 2147483647
#define RANDOM_AM (1.0f/float(RANDOM_IM))
#define RANDOM_IQ 127773u
#define RANDOM_IR 2836
#define RANDOM_MASK 123459876

struct NumberGenerator {
    int seed; // Used to generate values.

    // Returns the current random float.
    float GetCurrentFloat() {
        Cycle();
        return RANDOM_AM * seed;
    }

    // Returns the current random int.
    int GetCurrentInt() {
        Cycle();
        return seed;
    }

    // Generates the next number in the sequence.
    void Cycle() {  
        seed ^= RANDOM_MASK;
        int k = seed / RANDOM_IQ;
        seed = RANDOM_IA * (seed - k * RANDOM_IQ ) - RANDOM_IR * k;

        if (seed < 0 ) 
            seed += RANDOM_IM;

        seed ^= RANDOM_MASK;
    }

    // Cycles the generator based on the input count. Useful for generating a thread unique seed.
    // PERFORMANCE - O(N)
    void Cycle(const uint _count) {
        for (uint i = 0; i < _count; ++i)
            Cycle();
    }

    // Returns a random float within the input range.
    float GetRandomFloat(const float low, const float high) {
        float v = GetCurrentFloat();
        return low * ( 1.0f - v ) + high * v;
    }

    // Sets the seed
    void SetSeed(const uint value) {
        seed = int(value);
        Cycle();
    }
};