GLSL Shader - зміна відтінку / насиченості / яскравості

Я намагаюся змінити відтінок зображення за допомогою шейдера фрагмента GLSL. Я хочу досягти чогось подібного до шару Photoshop Hue / Saturation Adjustment.

На наступному зображенні ви можете побачити, що у мене поки що. Я хочу змінити відтінок зеленого квадрата, щоб він виглядав як червоний квадрат праворуч, але за допомогою цього шейдера я отримую половину червоного половини рожевого квадрата (квадрат посередині).

Те, що я роблю в шейдері фрагмента, - це перетворення кольору текстури в HSV, потім я додаю до неї колір HSV, який я отримую з вершинного шейдера, і перетворюю колір назад у RGB.
Що я роблю неправильно?

Фрагмент шейдер:

precision mediump float;
varying vec2 vTextureCoord;
varying vec3 vHSV;
uniform sampler2D sTexture;

vec3 convertRGBtoHSV(vec3 rgbColor) {
    float r = rgbColor[0];
    float g = rgbColor[1];
    float b = rgbColor[2];
    float colorMax = max(max(r,g), b);
    float colorMin = min(min(r,g), b);
    float delta = colorMax - colorMin;
    float h = 0.0;
    float s = 0.0;
    float v = colorMax;
    vec3 hsv = vec3(0.0);
    if (colorMax != 0.0) {
      s = (colorMax - colorMin ) / colorMax;
    }
    if (delta != 0.0) {
        if (r == colorMax) {
            h = (g - b) / delta;
        } else if (g == colorMax) {        
            h = 2.0 + (b - r) / delta;
        } else {    
            h = 4.0 + (r - g) / delta;
        }
        h *= 60.0;
        if (h < 0.0) {
            h += 360.0;
        }
    }
    hsv[0] = h;
    hsv[1] = s;
    hsv[2] = v;
    return hsv;
}
vec3 convertHSVtoRGB(vec3 hsvColor) {
    float h = hsvColor.x;
    float s = hsvColor.y;
    float v = hsvColor.z;
    if (s == 0.0) {
        return vec3(v, v, v);
    }
    if (h == 360.0) {
        h = 0.0;
    }
    int hi = int(h);
    float f = h - float(hi);
    float p = v * (1.0 - s);
    float q = v * (1.0 - (s * f));
    float t = v * (1.0 - (s * (1.0 - f)));
    vec3 rgb;
    if (hi == 0) {
        rgb = vec3(v, t, p);
    } else if (hi == 1) {
        rgb = vec3(q, v, p);
    } else if (hi == 2) {
        rgb = vec3(p, v, t);
    } if(hi == 3) {
        rgb = vec3(p, q, v);
    } else if (hi == 4) {
        rgb = vec3(t, p, v);
    } else {
        rgb = vec3(v, p, q);
    }
    return rgb;
}
void main() {
    vec4 textureColor = texture2D(sTexture, vTextureCoord);
    vec3 fragRGB = textureColor.rgb;
    vec3 fragHSV = convertRGBtoHSV(fragRGB);
    fragHSV += vHSV;
    fragHSV.x = mod(fragHSV.x, 360.0);
    fragHSV.y = mod(fragHSV.y, 1.0);
    fragHSV.z = mod(fragHSV.z, 1.0);
    fragRGB = convertHSVtoRGB(fragHSV);
    gl_FragColor = vec4(convertHSVtoRGB(fragHSV), textureColor.w);
}

EDIT: Використовуючи функції, які Сем Хочевар надав у своїй відповіді, проблема з рожевими смугами вирішена, але я можу досягти лише половини кольорового спектру. Я можу змінити відтінок з червоного на зелений, але не можу змінити його на синій або рожевий.

У фрагменті шейдера я зараз це роблю:

void main() {
    vec4 textureColor = texture2D(sTexture, vTextureCoord);
    vec3 fragRGB = textureColor.rgb;
    vec3 fragHSV = rgb2hsv(fragRGB);
    float h = vHSV.x / 360.0;
    fragHSV.x *= h;
    fragHSV.yz *= vHSV.yz;
    fragHSV.x = mod(fragHSV.x, 1.0);
    fragHSV.y = mod(fragHSV.y, 1.0);
    fragHSV.z = mod(fragHSV.z, 1.0);
    fragRGB = hsv2rgb(fragHSV);
    gl_FragColor = vec4(hsv2rgb(fragHSV), textureColor.w);
}

Ці функції будуть виконувати дуже погано. Я пропоную використовувати функції, написані з урахуванням GPU. Ось мої:

vec3 rgb2hsv(vec3 c)
{
    vec4 K = vec4(0.0, -1.0 / 3.0, 2.0 / 3.0, -1.0);
    vec4 p = mix(vec4(c.bg, K.wz), vec4(c.gb, K.xy), step(c.b, c.g));
    vec4 q = mix(vec4(p.xyw, c.r), vec4(c.r, p.yzx), step(p.x, c.r));

    float d = q.x - min(q.w, q.y);
    float e = 1.0e-10;
    return vec3(abs(q.z + (q.w - q.y) / (6.0 * d + e)), d / (q.x + e), q.x);
}

vec3 hsv2rgb(vec3 c)
{
    vec4 K = vec4(1.0, 2.0 / 3.0, 1.0 / 3.0, 3.0);
    vec3 p = abs(fract(c.xxx + K.xyz) * 6.0 - K.www);
    return c.z * mix(K.xxx, clamp(p - K.xxx, 0.0, 1.0), c.y);
}

Зауважте, що для цих функцій діапазон для Hстановить [0… 1] замість [0… 360], тому вам доведеться адаптувати свій вхід.

Джерело: http://lolengine.net/blog/2013/07/27/rgb-to-hsv-in-glsl

Як Нікол Болас запропонував у коментарях до оригінального повідомлення, я вирішую свою проблему окремою відповіддю.

Перший випуск полягав у тому, що зображення відображалося рожевими смугами, як видно із зображення в оригінальній публікації. Я зафіксував це за допомогою функцій, які Сем Хочевар надав у своїй відповіді ( /gamedev//a/59808/22302 ).

Друге питання полягало в тому, що я помножував відтінок пікселя текстури на значення, яке я надсилав шейдеру, що означало зміщення від піксельного відтінку текстур, тому мені довелося виконувати додавання замість множення.
Я все ще виконую множення на насиченість і яскравість, тому що в іншому випадку я отримую дивну поведінку, і мені не дуже потрібно нарощувати їх далі, ніж насиченість або яскравість оригінальної текстури на даний момент.

Це основний () метод шейдера, який я зараз використовую. Завдяки цьому я можу змінити відтінок від 0º до 360º, знебарвити зображення та зменшити яскравість.

void main() {
    vec4 textureColor = texture2D(sTexture, vTextureCoord);
    vec3 fragRGB = textureColor.rgb;
    vec3 fragHSV = rgb2hsv(fragRGB).xyz;
    fragHSV.x += vHSV.x / 360.0;
    fragHSV.yz *= vHSV.yz;
    fragHSV.xyz = mod(fragHSV.xyz, 1.0);
    fragRGB = hsv2rgb(fragHSV);
    gl_FragColor = vec4(fragRGB, textureColor.w);
}